_GUICtrlMenu_Recent() - Create a recent menu to add previously opened files or other text items to.

[guinness]

I have updated the example by removing the use of magic numbers as well as placing variables in the lowest scope possible. See the first post for details.

Edited September 15, 2013 by guinness

[guinness]

I updated the UDF and example by adding my new signature coding style. Enjoy!

[guinness]

This is proof I have changed over the last 2 years...

I just looked back through the svn logs and discovered the first version I have record of.

WARNING: May cause damage to your eyes for being poorly coded.

expandcollapse popup

#include-once

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
; #INDEX# =======================================================================================================================
; Title .........: _GUICtrlMenu_Recent
; AutoIt Version : v3.2.2.0 or higher
; Language ......: English
; Description ...: Create a recent menu to add previously opened files or other text items to.
; Note ..........: This has been tested with AutoIt x32 & can only be used with the AutoIt native menu functions.
; Author(s) .....: guinness
; Remarks .......:
; ===============================================================================================================================

; #INCLUDES# =========================================================================================================
#include <WinAPI.au3>
#include <WindowsConstants.au3>

; #GLOBAL VARIABLES# =================================================================================================
Global $__RecentMenu_Array[1][7] = [[0, 7, 1, 1, 10, -1, -1]]

; #CURRENT# =====================================================================================================================
; _GUICtrlMenu_RecentAdd: Add an item to the recent menu that was created with _GUICtrlMenu_RecentCreate().
; _GUICtrlMenu_RecentCreate: Create a recent menu that is added to an existing menu created with GUICtrlCreateMenu().
; ===============================================================================================================================

; #INTERNAL_USE_ONLY#============================================================================================================
; __GUICtrlMenu_RecentDelete ......; Deletes an item from the internal array.
; __GUICtrlMenu_RecentReDim ......; Efficiently resize the internal array when required.
; __GUICtrlMenu_RecentReduce ......; Remove reduant entries from the internal array when required.
; __GUICtrlMenu_RecentWM_COMMAND ......; Detect when a recent menu item is selected.
; ===============================================================================================================================

; #FUNCTION# =========================================================================================================
; Name...........: _GUICtrlMenu_RecentAdd()
; Description ...: Add an item to the recent menu that was created with _GUICtrlMenu_RecentCreate().
; Syntax.........: _GUICtrlMenu_RecentAdd($sText)
; Parameters ....: $sText - Text to be added to the recent menu.
; Requirement(s).: v3.2.2.0 or higher
; Return values .: Success - ControlID from GUICtrlCreateMenuItem()
;                  Failure - Returns text & sets @error = 1
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _GUICtrlMenu_RecentAdd($sText)
    Local $iControlID, $iMenu = $__RecentMenu_Array[0][5]
    If $iMenu = -1 Then
        Return SetError(1, 0, $sText)
    EndIf
    $iControlID = GUICtrlCreateMenuItem($sText, $iMenu)
    If $__RecentMenu_Array[0][2] > $__RecentMenu_Array[0][4] Then
        __GUICtrlMenu_RecentDelete(1) ; If exceeded the total number then delete the first entry and reduce the internal array.
        __GUICtrlMenu_RecentReduce($__RecentMenu_Array)
    EndIf
    __GUICtrlMenu_RecentReDim($__RecentMenu_Array, $__RecentMenu_Array[0][3]) ; Check if the internal array needs to be re-sized.
    $__RecentMenu_Array[0][0] += 1
    $__RecentMenu_Array[$__RecentMenu_Array[0][2]][0] = $iControlID
    $__RecentMenu_Array[$__RecentMenu_Array[0][2]][1] = $sText
    $__RecentMenu_Array[$__RecentMenu_Array[0][2]][2] = $iControlID
    $__RecentMenu_Array[0][2] += 1
    Return $iControlID
EndFunc   ;==>_GUICtrlMenu_RecentAdd

; #FUNCTION# =========================================================================================================
; Name...........: _GUICtrlMenu_RecentCreate()
; Description ...: Create a recent menu that is added to an existing menu created with GUICtrlCreateMenu().
; Syntax.........: _GUICtrlMenu_RecentCreate($iTotal, $iMenu, $sTitle, [$iMenuEntry = -1])
; Parameters ....: $iTotal - Maximum total number of recent menu items to be displayed. If this is exceeded then old values will be overwritten.
;                  $iMenu - Existing menu id created with GUICtrlCreateMenu().
;                  $sTitle - Title of the recent menu.
;                  $iMenuEntry - [Optional] Allows you to define the entry number to be created. The entries are numbered starting at 0. [Defaault = -1 - append to the last entry.]
; Requirement(s).: v3.2.2.0 or higher
; Return values .: Success - ControlID of recent menu.
;                  Failure - none
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _GUICtrlMenu_RecentCreate($iTotal, $iMenu, $sTitle, $iMenuEntry = -1)
    If $iTotal > 0 Then
        $__RecentMenu_Array[0][4] = $iTotal
    EndIf
    If $iMenuEntry > -1 Then
        $iMenu = GUICtrlCreateMenu($sTitle, $iMenu, $iMenuEntry)
    EndIf
    $iMenu = GUICtrlCreateMenu($sTitle, $iMenu)
    $__RecentMenu_Array[0][5] = $iMenu
    $__RecentMenu_Array[0][6] = GUICtrlCreateDummy()
    GUIRegisterMsg($WM_COMMAND, "__GUICtrlMenu_RecentWM_COMMAND")
    Return $__RecentMenu_Array[0][6] ; Technical: This isn't the menu id but a dummy value that is used for the function __GUICtrlMenu_RecentWM_COMMAND(), it then means the user can capture when the menu id is selected and read the menu text, which isn't possible the traditional way.
EndFunc   ;==>_GUICtrlMenu_RecentCreate

; #INTERNAL_USE_ONLY#============================================================================================================
Func __GUICtrlMenu_RecentDelete($iIndex)
    GUICtrlDelete($__RecentMenu_Array[$iIndex][0])
    $__RecentMenu_Array[0][2] = $iIndex
    $__RecentMenu_Array[$iIndex][0] = -1
    $__RecentMenu_Array[$iIndex][1] = -1
    $__RecentMenu_Array[$iIndex][2] = -1
    Return $iIndex
EndFunc   ;==>__GUICtrlMenu_RecentDelete

Func __GUICtrlMenu_RecentReDim(ByRef $aArray, ByRef $iDimension)
    If ($aArray[0][0] + 1) >= $iDimension Then
        $iDimension = ($aArray[0][0] + 1) * 2
        ReDim $aArray[$iDimension][$aArray[0][1]]
        Return 1
    EndIf
    Return 0
EndFunc   ;==>__GUICtrlMenu_RecentReDim

Func __GUICtrlMenu_RecentReduce(ByRef $aArray)
    Local $aReturn[$aArray[0][3]][$aArray[0][1]] = [[0, $aArray[0][1], 0, $aArray[0][3]]]
    For $A = 1 To $aArray[0][0]
        If $aArray[$A][0] = -1 Then
            ContinueLoop
        EndIf
        $aReturn[0][0] += 1
        For $B = 0 To $aArray[0][1] - 1
            $aReturn[$aReturn[0][0]][$B] = $aArray[$A][$B]
        Next
    Next
    $aReturn[0][2] = $aReturn[0][0] + 1
    $aArray = $aReturn
    Return $aReturn
EndFunc   ;==>__GUICtrlMenu_RecentReduce

Func __GUICtrlMenu_RecentWM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam
    Local $iControlID = _WinAPI_LoWord($iwParam), $sFile
    For $A = 1 To $__RecentMenu_Array[0][0]
        If $iControlID = $__RecentMenu_Array[$A][2] Then
            $sFile = $__RecentMenu_Array[$A][1]
            GUICtrlSendToDummy($__RecentMenu_Array[0][6], $sFile)
            __GUICtrlMenu_RecentDelete($A)
            ExitLoop
        EndIf
    Next
    Return $GUI_RUNDEFMSG
EndFunc   ;==>__GUICtrlMenu_RecentWM_COMMAND

[guinness]

Another update. I have changed _GUICtrlMenu_RecentTotal() to _GUICtrlMenu_RecentCapacity() and added _GUICtrlMenu_RecentDestroy(), as I forgeot to add a function to destroy the controls created by the UDF (though AutoIt takes care of this internally). I added a couple of minor tweaks here and there for improved readability as well. Enjoy!

Edited June 21, 2014 by guinness

[jrsofsd]

Hi Guiness

Thanks for the UDF - it saved me the coding and debugging!

BTW, why is the array returned from _GUICtrlMenu_RecentCreate() called a handle rather than an array?

I know it doesn't make any difference, but I'm curious re the coding (naming) style.

Thanks.

[guinness]

 

BTW, why is the array returned from _GUICtrlMenu_RecentCreate() called a handle rather than an array?

I know it doesn't make any difference, but I'm curious re the coding (naming) style.

Because I could change the internal data structure to a string or an associative array and it still wouldn't break your code. I mentioned this today in the MVP Forum that this is the correct approach to coding UDFs, because it makes no difference to you (the UDF user) what the "handle" is, all your concern should be is to pass to the appropriate functions and expect that it works. So yes it's an array, but I have (hopefully) masked this from you.

See Stack(), Queue(), Resource Update and more in my signature for this OO-like approach to coding.

[guinness]

PS. Good question though, I enjoy these types of conversations the most. So you have my attention if you want to learn more.

[jrsofsd]

Hi Guiness

Thanks for the compliment re the question

I suspected the function return datatype was abstracted, but the use of a handle had me wondering.

If the variable was named "$v" (Variant) instead of $h (Handle) the datatype abstraction would have been clear to me.

However, now that I've done some research, "handle" is entirely appropriate:

Win32 API

Inside the kernel, Windows maintains a table of all the different objects that the kernel is responsible for. Windows, buttons, icons, mouse pointers, menus, and so on, all get an entry in the table, and each entry is assigned a unique identifier known as a HANDLE.

- WIKIBOOKS, "Windows Programming/Handles and Data Types"

Computing

In computer programming, a handle is an abstract reference to a resource.

...a handle is an abstraction of a reference which is managed externally...

- WIKIPEDIA, "Handle (computing)"

 

Until I did the research I was going to suggest a new datatype: $u (UDF abstract return value).

Now that my old school beliefs about handles have been, uh, updated, I'm on board.

BTW, it takes a special programmer to rewrite code, especially "working" code.. We all learn and get better

but it's the special mind that revisits old code when there's SO much new code to write! Kudos.

P.S.

Yes, I'm interested in following the discussion.

[guinness]

I am glad you learnt something.

[VenusProject2]

Hi Guinness, you should know this awesome UDF is still being appreciated, thank you. I did implement it for a recent file & am now wanting to implement it in the same GUI for an additional recent "folders" the folders are used as dB's of the recent files if that makes sense.

Was wondering if you could point me in the right direction to be able to have 2 instances of this "recent files" in a single GUI.

I noticed a $RECENTMENU_GUID I'm thinking that this is  the clue...

Edited July 25, 2015 by VenusProject2

[VenusProject2]

Ok I think I solved this, I'll use GUICtrlCreateMenuItem & use GUICtrlCreateMenu to create a menu in the Menu Item for the recent files, and use your UDF for the DB folders because it doesn't replicate entries & is easy to cap the number of DB's.

Again thanks for this UDF

[guinness]

I have updated the UDF. No bug fixes, just style only.

About your issue, you can create two instance by creating two handles e.g.

Local $hRecentMenu_1 = _GUICtrlMenu_RecentCreate(5, $iFileMenu_1, 'Recent Files')
Local $hRecentMenu_2 = _GUICtrlMenu_RecentCreate(5, $iFileMenu_2, 'Recent Files')

Glad you like it though =)

[VenusProject2]

Thanks guinness, did try that with some strange results, anyway, I'll revisit it & work on a smaller proof of concept script.

[guinness]

Please do. Something that is small and easy to understand.

[VenusProject2]

Keeping it simple with 2 instances of "Recent Files/Folders" in a GUI

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include '_GUICtrlMenu_Recent.au3'
Example()

Func Example()
    Local $hGUI = GUICreate("GUI 2xRecent Menu", 300, 100)

    Local $idFileMenu = GUICtrlCreateMenu("&File")
    Local $idFileMenuItem = GUICtrlCreateMenuItem("Open File", $idFileMenu)
    GUICtrlCreateMenuItem("", $idFilemenu) ; create a separator line
    Local $hFileRecentMenuItem = _GUICtrlMenu_RecentCreate(5, $idFileMenu, "Recent Files")

    Local $idDBMenu = GUICtrlCreateMenu("&Database")
    Local $idDBMenuItem = GUICtrlCreateMenuItem("Open DB Folder", $idDBMenu)
    GUICtrlCreateMenuItem("", $idDBmenu) ; create a separator line
    Local $hDBRecentMenuItem = _GUICtrlMenu_RecentCreate(5, $idDBmenu, "Recent Databases")
    GUISetState(@SW_SHOW)


    Local $sFile
    Local $sFolder
    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $idFileMenuitem
                $sFile = FileOpenDialog("Choose file...", @TempDir, "All (*.*)")
                _GUICtrlMenu_RecentAdd($hFileRecentMenuItem, $sFile)


            Case $idDBMenuitem
                $sFolder = FileSelectFolder("Choose folder...", @TempDir)
                _GUICtrlMenu_RecentAdd($hDBRecentMenuItem, $sFolder)


            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    GUIDelete()

EndFunc   ;==>Example

 

[guinness]

I don't see any issue with my UDF (thankfully)

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include '_GUICtrlMenu_Recent.au3'

Example()

Func Example()
    Local $hGUI = GUICreate('GUI 2xRecent Menu', 300, 100)

    Local $idFileMenu = GUICtrlCreateMenu('&File')
    Local $idFileMenuItem = GUICtrlCreateMenuItem('Open File', $idFileMenu)
    GUICtrlCreateMenuItem('', $idFileMenu) ; Seperator Line.
    Local $hFileRecentMenuItem = _GUICtrlMenu_RecentCreate(5, $idFileMenu, 'Recent Files')

    Local $idDBMenu = GUICtrlCreateMenu('&Database')
    Local $idDBMenuItem = GUICtrlCreateMenuItem('Open DB Folder', $idDBMenu)
    GUICtrlCreateMenuItem('', $idDBMenu) ; Seperator Line.
    Local $hDBRecentMenuItem = _GUICtrlMenu_RecentCreate(5, $idDBMenu, 'Recent Databases')

    GUISetState(@SW_SHOW, $hGUI)

    Local $iMsg = 0, _
            $sFilePath = ''

    ; Loop until the user exits.
    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $idFileMenuItem
                $sFilePath = FileOpenDialog('Choose file...', @TempDir, 'All (*.*)')
                _GUICtrlMenu_RecentAdd($hFileRecentMenuItem, $sFilePath)

            Case $idDBMenuItem
                $sFilePath = FileSelectFolder('Choose folder...', @TempDir)
                _GUICtrlMenu_RecentAdd($hDBRecentMenuItem, $sFilePath)

            ; This is important!
            Case Else
                ; Check if the message id returned by GUIGetMsg() is present in the recent menu list.
                $sFilePath = _GUICtrlMenu_RecentSelected($hFileRecentMenuItem, $iMsg)
                If Not @error Then
                    MsgBox($MB_SYSTEMMODAL, '', 'The recent menu was selected and the following item was chosen' & @CRLF & _
                            @CRLF & _
                            $sFilePath, 0, $hGUI)

                    ; So as not to fall through to the next if statement.
                    ContinueLoop
                EndIf

                ; Check if the message id returned by GUIGetMsg() is present in the recent menu list.
                $sFilePath = _GUICtrlMenu_RecentSelected($hDBRecentMenuItem, $iMsg)
                If Not @error Then
                    MsgBox($MB_SYSTEMMODAL, '', 'The recent menu was selected and the following item was chosen' & @CRLF & _
                            @CRLF & _
                            $sFilePath, 0, $hGUI)

                    ; So as not to fall through to the next if statement.
                    ContinueLoop
                EndIf

        EndSwitch
    WEnd

    ; Destroy the recent menu.
    _GUICtrlMenu_RecentDestroy($hFileRecentMenuItem)
    _GUICtrlMenu_RecentDestroy($hDBRecentMenuItem)
    GUIDelete($hGUI)

EndFunc   ;==>Example

 

[VenusProject2]

Excellent guinness, certainly more complete

[guinness]

You get the part that was missing from your code? It was monitoring $iMsg for any other click event id.

[VenusProject2]

Yes I got it thanks, I'm also working on making recent files data persistent between 'closing' the GUI & 'launching' it, just using a INI file..

Edited July 26, 2015 by VenusProject2

[guinness]

I have Settings INI in my signature if you would like that? As you understand my style of creating a handle, this shouldn't be too difficult to grasp.