image to binary

[iamtheky]

takes an image and turns it into an autoit usable binary representation, and shellexecutes the au3 (because im set to bring it up in Scite, suppose it will not play nicely if you are set to execute au3s)

As always please turn this into something shiny and even more useful, so i can use that. Sorry if there already scripts in abundance that do this.

expandcollapse popup

#include <array.au3>
#include <file.au3>

Global $fixarray

$pic = fileopen ("C:\Program Files\AutoIt3\Examples\GUI\merlin.gif" , 16)

$read = fileread($pic)

fileclose ($pic)

$write = fileopen (@ScriptDir & "\binaryPic.txt" , 2)

filewrite ($write , string($read))

fileclose ($write)

$readfile = fileread (@ScriptDir & "\binaryPic.txt")

$readarray = StringSplit ($readfile, "" , 2)


$testwrite = fileopen (@ScriptDir &  "\BinaryPic.au3" , 2)

Filewrite ($testwrite , "Global $Pic_2_Binary = ")


for $L = 0 to ubound ($readarray) - 1 step 121


    If $L + 120 > ubound ($readarray) - 1 Then
        Filewrite ($testwrite , '"')
    for $i = $L to ubound ($readarray) - 1
    Filewrite ($testwrite , $readarray[$i])
  Next
Filewrite ($testwrite , '"')

  Else
      Filewrite ($testwrite , '"')
    for $i = $L to $L + 120
        Filewrite ($testwrite , $readarray[$i])
    next
    Filewrite ($testwrite , '"')
  Endif


 FileWrite ($testwrite , @CRLF & "$Pic_2_Binary &= ")

  Next

fileclose ($testwrite)

_FileReadToArray (@ScriptDir & "\BinaryPic.au3" , $fixarray)

_ArrayDelete ($fixarray, $fixarray[0])
_ArrayDelete ($fixarray, 0)

_FileWriteFromArray (@ScriptDir & "\BinaryPic.au3" , $fixarray)

filedelete (@ScriptDir &  "\BinaryPic.txt")

ShellExecute (@ScriptDir & "\BinaryPic.au3")

Edited June 14, 2011 by iamtheky

[guinness]

There are Examples floating around e..g

This Example was found on the Forum (initially I saw by UEZ) and then modified it myself.

Functions:

expandcollapse popup

Func _FileToAU3Binary($sFile, $sVariable, $sFunction)
    Local $iLength = 160, $sData, $sFileRead, $sFunctionData

    $sData = __GetFile($sFile, 16)

    $sFunctionData = 'Func ' & $sFunction & '()' & @CRLF & @TAB & 'Local $' & $sVariable & ' = "' & StringLeft($sData, $iLength) & '"' & @CRLF
    $sData = StringTrimLeft($sData, $iLength)

    While StringLen($sData) > $iLength
        $sFunctionData &= @TAB & '$' & $sVariable & ' &= "' & StringLeft($sData, $iLength) & '" ' & @CRLF
        $sData = StringTrimLeft($sData, $iLength)
    WEnd

    If StringLen($sData) <> 0 Then
        $sFunctionData &= @TAB & '$' & $sVariable & ' &= "' & $sData & '"'
    EndIf
    $sFunctionData &= @CRLF & @TAB & 'Return $' & $sVariable & @CRLF & 'EndFunc   ;==>' & $sFunction
    ClipPut(__SetFile($sFunctionData, @ScriptDir & "\Function.au3"))
    Return $sFunctionData
EndFunc   ;==>_FileToAU3Binary

Func __GetFile($sFile, $sFormat = 0)
    Local $hFileOpen = FileOpen($sFile, $sFormat), $sData
    If $hFileOpen = -1 Then
        Return SetError(1, 0, "")
    EndIf
    $sData = FileRead($hFileOpen)
    FileClose($hFileOpen)
    Return $sData
EndFunc   ;==>_GetFile

Func __SetFile($sString, $sFile)
    Local $hFileOpen = FileOpen($sFile, 2)
    FileWrite($hFileOpen, $sString)
    FileClose($hFileOpen)
    If @error Then
        Return SetError(1, 0, $sString)
    EndIf
    Return $sString
EndFunc   ;==>__SetFile

Example use of Function:

_FileToAU3Binary("Merlin.gif", "bBinaryPic", "_ImageFile")

Edited June 14, 2011 by guinness