_GUICtrlListView_CreateArray() - Create an array from a ListView.

[garbb]

This is the fastest one I have seen so far, thanks. It seems that the built-in ControlListView() functions are faster than the _GUICtrlListView_... UDF functions for some reason.

[guinness]

I wonder what it's like on _GUICtrlListView_Create() controls?

[Skysnake]

great! Should be included in the standard documentation!

[vantastic87]

Here is another way i've used.

Func ExportSystemSummary()

$stringbuildcol1=""
$stringbuildaddcol=""
$List = $Summarylist ;;;;;SWAP OUT FOR ANY LIST;;;;;
local $exportarray[0][7] ;;;; BUILD ARRAY BASED OFF HOW MANY COLUMNS YOU HAVE IN LIST;;;;;;
;_ArrayDisplay($exportarray)

    $rowcount = _GUICtrlListView_GetItemCount($List)
    $colcount = _GUICtrlListView_GetColumnCount($List)

    For $r = 0 to $rowcount -1
        $col1 = _GUICtrlListView_GetItemText($List,$r)
        $stringbuildcol1 = $col1

        For $c = 1 to $colcount
            $col2 = _GUICtrlListView_GetItemText($List,$r,$c)

            if $col2 <> '' then
            $stringbuildaddcol = $stringbuildaddcol & "|" & $col2
            EndIf
        Next

        If $stringbuildaddcol <> '' then
        _ArrayAdd($exportarray,$stringbuildcol1 & $stringbuildaddcol,0,"|")
        Else
        _ArrayAdd($exportarray,$stringbuildcol1)
        EndIf

        $stringbuildcol1=""
        $stringbuildaddcol=""
    Next

_ArrayDisplay($exportarray)

EndFunc

[mLipok]

1 hour ago, vantastic87 said:

Here is another way i've used.

Your code is very unclear .... I mean unreadable maybe because you forget to read this: * How to post code on the forum *
 

btw.
Welcome to the forum.

 

Edited March 9, 2016 by mLipok

[guinness]

Not quite the same as mine. Thanks though.

[HurleyShanabarger]

Just a little bit faster then the one with ControlListView:

 

expandcollapse popup

Func _GUICtrlListView_GetItemsArray($f_iCtrl)
    ; Get row and colum count
    Local $l_iRows = GUICtrlSendMsg($f_iCtrl, $LVM_GETITEMCOUNT, 0, 0)
    Local $l_iCols = _SendMessage(HWnd(GUICtrlSendMsg($f_iCtrl, $LVM_GETHEADER, 0, 0)), 0x1200)

    ; Error checking
    If $l_iRows * $l_iCols = 0 Then Return SetError(1)
    If IsHWnd($f_iCtrl) Then Return SetError(2)

    ; Create result array
    Local $l_aListView[$l_iRows][$l_iCols]

    ; Create structure and pointer
    Local $l_boUnicode = (GUICtrlSendMsg($f_iCtrl, $LVM_GETUNICODEFORMAT, 0, 0) <> 0)
    Local $l_hMessage = $l_boUnicode ? $LVM_GETITEMTEXTW : $LVM_GETITEMTEXTA
    Local $l_tBuffer = DllStructCreate($l_boUnicode ? "wchar Text[4096]" : "char Text[4096]")
    Local $l_pBuffer = DllStructGetPtr($l_tBuffer)
    Local $l_tItem = DllStructCreate($tagLVITEM)
    DllStructSetData($l_tItem, "TextMax", 4096)
    Local $l_pItem
    DllStructSetData($l_tItem, "Text", $l_pBuffer)

    ; Loop through listview
    For $l_iRow = 0 To $l_iRows - 1
        For $l_iCol = 0 To $l_iCols - 1
            ; Set data in structure
            DllStructSetData($l_tItem, "SubItem", $l_iCol)
            $l_pItem = DllStructGetPtr($l_tItem)
            DllStructSetData($l_tItem, "Text", $l_pBuffer)

            ;Get Data and populate array
            GUICtrlSendMsg($f_iCtrl, $l_hMessage, $l_iRow, $l_pItem)
            $l_aListView[$l_iRow][$l_iCol] = DllStructGetData($l_tBuffer, "Text")
        Next
    Next
    Return $l_aListView
EndFunc   ;==>_GUICtrlListView_GetItemsArray

Please note, that this one is expecting control ID not handle.

Edited October 6, 2017 by HurleyShanabarger

[sudeepjd]

I would like to share my version of this since I am using the Array functions...

#include <GuiListView.au3>
#include <Array.au3>

Func _GUICtrlListView_GetItemsArray($hListView)
   $cnt = _GUICtrlListView_GetItemCount($hListView)
   If $cnt > 0 Then
      $firstLine = _GUICtrlListView_GetItemTextArray($hListView, 0)
      _ArrayTranspose($firstLine)
      If $cnt > 1 Then
         For $i = 1 to $cnt-1
            $moreLine = _GUICtrlListView_GetItemTextArray($hListView, $i)
            _ArrayTranspose($moreLine)
            _ArrayConcatenate($firstLine, $moreLine)
         Next
      EndIf

      ;Remove the first columns as it contains the counts of each line
      _ArrayColDelete($firstLine, 0)

      Return $firstLine
   Else
      Return False
   EndIf
EndFunc