_GetDirectoryFormat()

[guinness]

This SRE I came across whilst browsing the Include File.au3 (_FileListToArray) and felt that it should be given a Function all of its own. It use ByRef as a reference for the variable that is being passed to the Function and will either remove the trailing backslash or add a backslash.

Function:

; #FUNCTION# ====================================================================================================================
; Name ..........: _GetDirectoryFormat
; Description ...: Formats a directory string with either the trailing '\' removed or included. It can also check whether the directory exists and create if not present.
; Syntax ........: _GetDirectoryFormat(Byref $sDirectory[, $iAppend = 1[, $iFlag = 0]])
; Parameters ....: $sDirectory          - [in/out] A variable containing a directory string with either the trailing '\' included or excluded.
;                  $fAppend             - [optional] True - Append a backslash or False- Remove the appending backslash. Default is True.
;                  $fFlag               - [optional] Check if the directory exists and create if not present. True - Check & create or False - Don't check. Default is False.
; Return values .: Success - Returns directory string with the correct format.
;                  Failure - None
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _GetDirectoryFormat(ByRef $sDirectory, $fAppend = True, $fFlag = False)
    Local $sAppend = ''
    If $fAppend Or $fAppend = Default Then
        $sAppend = '\'
    EndIf
    $sDirectory = StringRegExpReplace($sDirectory, '[\\/]+$', '') & $sAppend
    If FileExists($sDirectory) = 0 And $fFlag Then
        DirCreate($sDirectory)
    EndIf
    Return $sDirectory
EndFunc   ;==>_GetDirectoryFormat

Example use of Function:

#include <Constants.au3>

Local $sExampleDirectory = 'C:\Example_Folder\\\'

_GetDirectoryFormat($sExampleDirectory, True) ; Change to 'C:\Example_Folder\' & don't check if directory exists.
ConsoleWrite($sExampleDirectory & @CRLF)

_GetDirectoryFormat($sExampleDirectory, False) ; Change to 'C:\Example_Folder' & don't check if directory exists.
ConsoleWrite($sExampleDirectory & @CRLF)

_Example_Old($sExampleDirectory) ; This was the old way of checking whether a directory has a backslash.
_Example_New($sExampleDirectory) ; This is the new way of checking whether a directory has a backslash.

Func _Example_Old($sDirectory)
    If Not (StringRight($sDirectory, StringLen('\')) == '\') Then $sDirectory &= '\'
    Return MsgBox($MB_SYSTEMMODAL, '_Example_Old()', $sDirectory)
EndFunc   ;==>_Example_Old

Func _Example_New($sDirectory)
    _GetDirectoryFormat($sDirectory, True)
    Return MsgBox($MB_SYSTEMMODAL, '_Example_New()', $sDirectory)
EndFunc   ;==>_Example_New

Edited April 9, 2013 by guinness

[burnell]

I get these Errors, but i don´t know what´s wrong:

"C:\Temp\temp01.au3"(154,70) : error: _GetDirectoryFormat() previously called with Const or expression on ByRef param(s).

Func _GetDirectoryFormat(ByRef $sDirectory, $iAppend = 1, $iFlag = 0)

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^

"C:\Temp\temp01.au3"(97,45) : REF: first call to _GetDirectoryFormat().

Local $_dir = _GetDirectoryFormat($i_dir, 1)

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^

C:\Temp\temp01.au3 - 1 error(s), 0 warning(s)

expandcollapse popup

Func CREATE_DIRS()
Local $temp
Local $success = 0, $no_success = 0, $already_exist = 0
Local $_start = Int(GUICtrlRead($StartValue))
Local $_end = Int(GUICtrlRead($EndValue))
Local $_width = Int(GUICtrlRead($NumberDigits))
Local $_pre = GUICtrlRead($Prefix)
Local $_post = GUICtrlRead($Postfix)
Local $i_dir = GUICtrlRead($DirectoryInput)
Local $_dir = _GetDirectoryFormat($i_dir, 1)
For $i = $_start To $_end
  $temp = $_dir & $_pre & StringFormat("%0" & String($_width) & ".0f", $i) & $_post
  If Not FileExists($temp) Then
   If DirCreate($temp) Then
    $success += 1
   Else
    $no_success += 1
   EndIf
  Else
   $already_exist += 1
  EndIf
Next
EndFunc   ;==>CREATE_DIRS

Func DO_PREVIEW()
Local $out = ""
Local $_start = Int(GUICtrlRead($StartValue))
Local $_end = Int(GUICtrlRead($EndValue))
Local $_width = Int(GUICtrlRead($NumberDigits))
Local $_pre = GUICtrlRead($Prefix)
Local $_post = GUICtrlRead($Postfix)
Local $i_dir = GUICtrlRead($DirectoryInput)
Local $_dir = _GetDirectoryFormat($i_dir, 1)
For $i = $_start To $_end
  $out = $out & _
    $_dir & _
    $_pre & _
    StringFormat("%0" & String($_width) & ".0f", $i) & _
    $_post & _
    @CRLF
Next
GUICtrlSetData($Preview, $out)
EndFunc   ;==>DO_PREVIEW

Func CHOOSE_TARGET_DIR()
Local $old_dir = GUICtrlRead($DirectoryInput)
Local $new_dir = FileSelectFolder("Verzeichnis für die neuen Ordner aussuchen", "", 7, $old_dir)
If $new_dir <> "" Then
  GUICtrlSetData($DirectoryInput, $new_dir)
EndIf
EndFunc   ;==>CHOOSE_TARGET_DIR

Func OPEN_DIR()
ShellExecute (_GetDirectoryFormat(GUICtrlRead($DirectoryInput), 1, 1), '',  '', 'open') ;should open Dir, if not exist, then create it!
EndFunc   ;==>OPEN_DIR

Func _GetDirectoryFormat(ByRef $sDirectory, $iAppend = 1, $iFlag = 0)
Local $sAppend = ""
If $iAppend Then
  $sAppend = "\"
EndIf
$sDirectory = StringRegExpReplace($sDirectory, "[\\/]+\z", "") & $sAppend
    If FileExists($sDirectory) = 0 And $iFlag Then
        DirCreate($sDirectory)
    EndIf
Return SetError(0, 0, $sDirectory)
EndFunc   ;==>_GetDirectoryFormat ~ Author... guinness

[guinness]

burnell,

The error is correct, as $sDirectory is a ByRef which means a variable should be passed not a string, which is the case for OPEN_DIR().

Func OPEN_DIR()
    Local $sDirectory = GUICtrlRead($DirectoryInput)
    ShellExecute(_GetDirectoryFormat($sDirectory, 1, 1), '', '', 'open') ;should open Dir, if not exist, then create it!
EndFunc   ;==>OPEN_DIR

[Yashied]

Return SetError(0, 0, $sDirectory)

is equivalent to

Return $sDirectory

[guinness]

Return SetError(0, 0, $sDirectory)

is equivalent to

Return $sDirectory

Yeh, no idea why I did that. Plus I was going to recommend _WinAPI_PathAddBackSlash anyway.

[guinness]

Updated code.

[burnell]

guinness

Thanks for the hint.

[guinness]

You're welcome. But I urge you to look at Yashied's WinAPIEx and the _WinAPI_Path(Add) OR (Remove)Backslash() functions

[guinness]

I've updated the syntax and added support for the Default keyword. Please see the original post for more details. I have also changed $iAppend and $iFlag to accept boolean values instead of the previous 0 or 1. Thanks.

[guinness]

Fixed the code above. It was destroyed by a Forum update.

[guinness]

This is kind of redundant now WinAPIShPath.au3 contains ...

_WinAPI_PathAddBackslash()
_WinAPI_PathRemoveBackslash()