Change a GUI Input to password

[Morthawt]

Hi.

I am trying to, on the fly, if a certain word is typed into a gui input box, then turn it into a password field to shield the next input from being viewed, so I can perform more options based on the password entered. I have tried a switch with a case looking for a word, which worked, but it does not alter the input to have a password style:

heres the little snippet that works because the msgbox pops up, so I know it is varifying the right word. It just does not alter the field to a password field.

Case $usedport = 'tools'
    GUICtrlSetStyle($port, $ES_PASSWORD)
    MsgBox(0, '', 'test')

What am I doing wrong?

Thanks

[pieeater]

try using guictrlread(),

example:

$a = GUICtrlRead($usedport)
Case $a = 'tools'
    GUICtrlSetStyle($port, $ES_PASSWORD)
    MsgBox(0, '', 'test')

its making $a = whatever is in $usedport, and then checking if it = 'tools'

[guinness]

Have a look to change the Password Input from Showing/Hiding Password.

[smartee]

hi Morthawt,

Here's an example showing how to do it (without deleting and recreating controls like guinness's method)

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 162, 58, 216, 148)
$Input2 = GUICtrlCreateInput("Input2", 8, 8, 145, 21, BitOR($ES_PASSWORD, $ES_AUTOHSCROLL))
$Checkbox1 = GUICtrlCreateCheckbox("Show password", 8, 32, 145, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

;Retrieve the ASCII value of the default password char
$DefaultPassChar = GUICtrlSendMsg($Input2, $EM_GETPASSWORDCHAR, 0, 0)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Checkbox1
            If (GUICtrlRead($Checkbox1) = $GUI_CHECKED) Then
                GUICtrlSendMsg($Input2, $EM_SETPASSWORDCHAR, 0, 0)
            Else
                GUICtrlSendMsg($Input2, $EM_SETPASSWORDCHAR, $DefaultPassChar, 0)
            EndIf
            GUICtrlSetState($Input2, $GUI_FOCUS) ;Input needs focus to redraw characters
    EndSwitch
WEnd

Hope this helps,

-smartee

EDIT: Moved GUICtrlSetState() out of the If-Then structure

Edited May 6, 2011 by smartee

[guinness]

No Way! I look like such an idiot I didn't realise it could be done this way. I knew GUICtrlSetStyle() didn't work but didn't think about GUICtrlSendMsg()! Thanks. Time to edit the Function.

Edited May 6, 2011 by guinness

[Melba23]

smartee,

Excellent!

guinness,

Sorry for giving you misleading information all that time ago.

M23

Edit: Typnig.

Edited May 6, 2011 by Melba23

[guinness]

Melba23 its my fault for not searching properly >>

But I accept your apology