Re-sizable gui

[Skitty]

I'm trying to create a gui with an inputbox at the right side, how do I create a control that always stays in that position?

Problem is that when the script is run at a different screen resolution, the control is way off to the right and out of the screen.

I tried using @Desktopwidth / 2 + 800 but it fails when the screen is that of an acer aspire one d250 net-book but works when using a 21" monitor.

I also wanted to create a horizontal progress bar but its always in a different position with different screen resolutions.

If any one can locate a topic where this has been looked on before? or are there special functions to take care of this?

[guinness]

Have a look in the Help File for GUICtrlResizing() or some code to replicate the problem with?!

[Skitty]

Have a look in the Help File for GUICtrlResizing() or some code to replicate the problem with?!

that function seem's to be specific to a window with a boarder.

Sorry for not mentioning this before but the gui in question is created as so...

GUICreate("", @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUP, $WS_EX_TOPMOST)

Edited April 22, 2011 by System238

[wakillon]

An inputBox always at right side, like this ?

#include <WindowsConstants.au3>

HotKeySet ( "{ESC}", "_HotKey" )

$_Gui = GUICreate ( "", @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUP, $WS_EX_TOPMOST )
$_Width = 250
GUISetState ( )

$answer = InputBox ( "Question", "Where were you born?", "Planet Earth", "", $_Width, 50, @DesktopWidth - $_Width , 0, 0, $_Gui )

While 1
WEnd

Func _HotKey ( )
    Exit
EndFunc ;==> _HotKey ( )

[Skitty]

An inputBox always at right side, like this ?

#include <WindowsConstants.au3>

HotKeySet ( "{ESC}", "_HotKey" )

$_Gui = GUICreate ( "", @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUP, $WS_EX_TOPMOST )
$_Width = 250
GUISetState ( )

$answer = InputBox ( "Question", "Where were you born?", "Planet Earth", "", $_Width, 50, @DesktopWidth - $_Width , 0, 0, $_Gui )

While 1
WEnd

Func _HotKey ( )
    Exit
EndFunc ;==> _HotKey ( )

AW STUPID ME!!!

What I meant was a gui input control box, not that input box lol. thanks for the effort though.

[bwochinski]

Not sure if this is the best way, but I figured you can just use a function that allows you to position controls essentially by % of screen instead of actual pixels.

The "scale()" function is pretty much it.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

HotKeySet("{ESC}", "end")

;modify these 2 variables to test resolutions...
Global $winW = @DesktopWidth/1.5
Global $winH = @DesktopHeight/1.5

$win = GUICreate("", $winW, $winH, 0, 0, $WS_POPUP, $WS_EX_TOPMOST)
$edit1 = GUICtrlCreateInput("test", scale(800,1), scale(400,2), scale(150,1))

GUISetState(@SW_SHOW)


While True
    Sleep(250)
WEnd

Func end()
    Exit
EndFunc

Func scale($pct, $axis)
    $pct /= 1000        ;translates screen to a 1000 x 1000 area in any resolution
    If $axis = 1 Then
        Return $winW * $pct
    ElseIf $axis = 2 Then
        Return $winH * $pct
    EndIf
    Return -1
EndFunc

[UEZ]

Something like that?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 295, 76, -1, -1,  BitOR($WS_POPUP, $WS_THICKFRAME,$WS_TABSTOP), $WS_EX_TOPMOST)
$Input = GUICtrlCreateInput("Input", 160, 8, 121, 21)
GUICtrlSetResizing(-1, $GUI_DOCKRIGHT+$GUI_DOCKTOP+$GUI_DOCKHEIGHT)
$bExit = GUICtrlCreateButton("Exit", 208, 40, 75, 25)
GUICtrlSetResizing(-1, $GUI_DOCKRIGHT+$GUI_DOCKTOP+$GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE, $bExit
            Exit
    EndSwitch
WEnd

Br,

UEZ

Edited April 22, 2011 by UEZ