Run a Func every 5 mins using @MIN

[Rogue5099]

Trying to run a function every 5 mins.

If @MIN = "00" Or @MIN = "05" Or @MIN = "10" Or @MIN = "15" Or @MIN = "20" Then....

Got to be an easier way!

[iamtheky]

5 minutes from the last time the function ran might be better accomplished with timerinit and timerdiff. Because in your current example if your function takes 4 minutes to run, it would only wait a minute then run again.

[Rogue5099]

That's a good idea. The function only takes 5 secs MAX to run. I want it to run on the MIN though not loose any seconds over time.

If StringInStr(@MIN, "5", 0, 2, 1) = 2 Or StringInStr(@MIN, "0", 0, 2, 1) = 2 Then

Above works only on 5 mins not on the min ending in 0

Edited April 9, 2011 by rogue5099

[Rogue5099]

Found it:

If Mod(@MIN, 5) = 0 Then

[darkjohn20]

$iMinutes = 5

$hTimer = TimerInit()



While 1

    If TimerDiff($hTimer) > ($iMinutes * 60000) Then

        ConsoleWrite("5 minutes have passed!" & @CRLF)

        $hTimer = TimerInit()

    EndIf

WEnd

Edited April 9, 2011 by darkjohn20

[guinness]

Why not use AdlibRegister?

[wakillon]

Another way

#Include <Date.au3>

Global $_Timer = _NowCalc ( )
Global $_Interval = 5

While 1
    $_NowCalc = _NowCalc ( )
    If _DateDiff ( "n", $_Timer, $_NowCalc ) >= $_Interval Then  ; 5 min
        ConsoleWrite ( "->---- " & $_Interval & " Minutes elapsed : " & $_NowCalc & @Crlf )
        $_Timer = $_NowCalc
    EndIf
    Sleep ( 10 )
WEnd

[sahsanu]

Found it:

If Mod(@MIN, 5) = 0 Then

If you want to run at 00, 05, 10, 15... then this script will do:

Global $switch = 0
While 1
    IF Mod(@MIN,5) = 0 Then
        If $switch = 0 Then
            ConsoleWrite("It is time to run: " & @MIN & @CRLF) ;Here goes your stuff
            $switch = 1
        EndIf
    Else
        $switch = 0
    EndIf
Sleep(250)
WEnd

[Rogue5099]

Why not use AdlibRegister?

I am sending an email and I need it on the 5's not any other time to check for errors in system.

If I use AdlibRegister then it goes from whenever the script is started.