[SOLVED] GUICtrlCreateEdit() - Question...

[JScript]

Hello,

Anyone could tell me how can I make for a GUICtrlCreateEdit() be enabled only when I click the mouse over him, and when I click out it disable?

Edited March 23, 2011 by jscript

[bogQ]

#Include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
$gui = GUICreate("My GUI edit")  ; will create a dialog box that when displayed is centered
$myedit = GUICtrlCreateEdit("First line" & @CRLF, 176, 32, 121, 97, $ES_AUTOVSCROLL + $WS_VSCROLL)
GUISetState()
$state = 0
GUICtrlSetState($myedit,$GUI_DISABLE)
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    If _IsPressed("01") Then
        $over = GUIGetCursorInfo ( $gui )
        If $over[4] = $myedit Then
            If Not $state Then
                $state = 1
                GUICtrlSetState($myedit,$GUI_ENABLE)
            EndIf
        Else
            If $state Then 
                $state = 0
                GUICtrlSetState($myedit,$GUI_DISABLE)
            EndIf
        EndIf
        Do
            Sleep(10)
        Until Not _IsPressed("01")
    EndIf
    Sleep(10)
WEnd

Edited March 22, 2011 by bogQ

[JScript]

more or less it...

But the rest of the code blocks.

Do
            Sleep(10)
        Until Not _IsPressed("01")

[JScript]

I thought something like this: GUIRegisterMsg()

[bogQ]

that was example, this isnt copy paste site

That can b solved with one or two "If" if you know how

[JScript]

that was example, this isnt copy paste site

That can b solved with one or two "If" if you know how

Their example was very useful, a few changes after I came to this conclusion:

expandcollapse popup

#include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Global $hGUI, $hEdit

$hGUI = GUICreate("My GUI edit")
$hEdit = GUICtrlCreateEdit("", 117, 37, 206, 89, BitOR($ES_AUTOVSCROLL, $ES_MULTILINE, $ES_WANTRETURN, $WS_VSCROLL))
GUICtrlSetState($hEdit, $GUI_DISABLE)
GUISetState()

_GuiLoop()

Func _GuiLoop()
    Local Static $IsEnable = 0

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $GUI_EVENT_PRIMARYDOWN
                Local $aIsOver = GUIGetCursorInfo($hGUI)
                If $aIsOver[4] = $hEdit Then
                    If Not $IsEnable Then
                        $IsEnable = 1
                        GUICtrlSetState($hEdit, $GUI_ENABLE)
                        GUICtrlSetState($hEdit, $GUI_FOCUS)
                    EndIf
                Else
                    If $IsEnable Then
                        $IsEnable = 0
                        GUICtrlSetState($hEdit, $GUI_DISABLE)
                    EndIf
                EndIf
        EndSwitch
    WEnd
EndFunc   ;==>_GuiLoop

No need use the functions: _IsPressed() or Sleep.

I thank you!