Disable Red "X"

[usera]

Greeting,

Looking for a way to disable the red "X" in the right top cornor of the active window.

for example I use script to launch "notepad.exe" but disable the "X" close so user can not close the notepad window but wait for a while then the script close it

Thanks

usera

[E1M1]

Why do you need this I wonder? you can set windows style using _WinAPI_SetWindowLong()

[usera]

Thanks for quick feedback. Could you please little bit details please?

usera

[E1M1]

it's 100% doable with help file, you need to set notepad style toosomething that dont have red X. Style I dont remember but when you look at GUICReate from hel... that page has link to possible styles.

[usera]

I can understand that for create a new windows. but how to use it for existing application? for example winword.exe or notepad.exe?

Thanks

[ChrisL]

Remove red x...

or just disable it with Opt("GUIEventOptions",1)...

#include <GUIConstantsEx.au3>

Opt("GUIEventOptions",1)

GuiCreate("Sample")
$button = GuiCtrlCreateButton("Close",10,10)
GuiSetState()
While 1
    $sMsg = GuiGetmsg()
    Switch $sMsg
        Case $GUI_EVENT_CLOSE
            ;Do nothing
        Case $GUI_EVENT_MINIMIZE
            GuiSetState(@SW_MINIMIZE)
        Case $GUI_EVENT_RESTORE
            GUISetState(@SW_RESTORE)
        Case $button
            Exit
    EndSwitch

WEnd

Edit:~ While I was writing this I then saw the on an external application bit so this wont be of any use!

Edited March 10, 2011 by ChrisL

[usera]

So the idea is just this.

I use script to launch "notepad.exe" then wait for it open. Since I use script to open it, So for sure I know all the information about the "notepad.exe" include the windows size, buttons. so from there I disable the red "X" button, that is all.

Problem is do Not know how to write the code.

usera

[Ascend4nt]

Credits to Melba23 for finding this. Change 1 to 0 to re-enable:

#include <GuiMenu.au3>
$hWnd=WinGetHandle("[CLASS:Notepad]")
_GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hWnd), $SC_CLOSE, 1, False)

[usera]

Credits to Melba23 for finding this. Change 1 to 0 to re-enable:

#include <GuiMenu.au3>
$hWnd=WinGetHandle("[CLASS:Notepad]")
_GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hWnd), $SC_CLOSE, 1, False)

Thanks for help, but really how to use it ? I am just new.

usera

[usera]

thanks, figured out.

[usera]

Credits to Melba23 for finding this. Change 1 to 0 to re-enable:

#include <GuiMenu.au3>
$hWnd=WinGetHandle("[CLASS:Notepad]")
_GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hWnd), $SC_CLOSE, 1, False)

thanks

for line

$hWnd=WinGetHandle("[CLASS:Notepad]") if I use winword.exe. what will replace "Notepad" ?

and for winwaitactive("[CLASS:notepad]") same question if I use winword.exe. what will replace "Notepad" ?

thanks

usera

[guinness]

Use AU3Info.exe in SciTe (look under the Tools Menu) to find the CLASS. I don't use MS Office.

Edit: Or try this code >>

#include <GUIMenu.au3>

Global $PID = Run("Notepad.exe") ; Change to WinWord.exe
Sleep(500)
Global $hWnd = _WinGetHandleByPID($PID)
_GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hWnd), $SC_CLOSE, 1, False)

Func _WinGetHandleByPID($i_pid, $f_array = False, $f_visibleonly = True)
    If Not IsInt($i_pid) Then $i_pid = ProcessExists($i_pid)

    Local $a_winlist = WinList()
    Local $a_retarray[$a_winlist[0][0] + 1], $i_add

    For $iwin = 1 To $a_winlist[0][0]
        If WinGetProcess($a_winlist[$iwin][1]) = $i_pid Then
            If $f_visibleonly Then
                If BitAND(WinGetState($a_winlist[$iwin][1]), 2) Then
                    If Not $f_array Then Return $a_winlist[$iwin][1]
                    $i_add += 1
                    $a_retarray[$i_add] = $a_winlist[$iwin][1]
                EndIf
            Else
                If Not $f_array Then Return $a_winlist[$iwin][1]
                $i_add += 1
                $a_retarray[$i_add] = $a_winlist[$iwin][1]
            EndIf
        EndIf
    Next

    If Not $i_add Then Return SetError(1, 0, 0)

    ReDim $a_retarray[$i_add + 1]
    $a_retarray[0] = $i_add
    Return $a_retarray
EndFunc

Edit: New version provided by SmOke_N

Edited March 11, 2011 by guinness

[SmOke_N]

Return WinGetHandle(StringSplit(StringTrimRight($sData, 1), Chr(1)))

This makes no sense. Are you suggesting that using WinGetHandle() this way actually enumerates through the StringSplit() array and makes each one a hwnd?

Your vars are a bit confusing too... maybe this is more to the point?

Func _WinGetHandleByPID($i_pid, $f_array = False, $f_visibleonly = True)
    If Not IsInt($i_pid) Then $i_pid = ProcessExists($i_pid)

    Local $a_winlist = WinList()
    Local $a_retarray[$a_winlist[0][0] + 1], $i_add

    For $iwin = 1 To $a_winlist[0][0]
        If WinGetProcess($a_winlist[$iwin][1]) = $i_pid Then
            If $f_visibleonly Then
                If BitAND(WinGetState($a_winlist[$iwin][1]), 2) Then
                    If Not $f_array Then Return $a_winlist[$iwin][1]
                    $i_add += 1
                    $a_retarray[$i_add] = $a_winlist[$iwin][1]
                EndIf
            Else
                If Not $f_array Then Return $a_winlist[$iwin][1]
                $i_add += 1
                $a_retarray[$i_add] = $a_winlist[$iwin][1]
            EndIf
        EndIf
    Next

    If Not $i_add Then Return SetError(1, 0, 0)

    ReDim $a_retarray[$i_add + 1]
    $a_retarray[0] = $i_add

    Return $a_retarray
EndFunc

[guinness]

I found the Function from here >>

I was perhaps a little too keen to get the code onto the Forum. Thanks for the new version.

With the Variable naming I use the advice from here >> http://www.autoitscript.com/autoit3/udfs/UDF_Standards.htm

Edited March 11, 2011 by guinness

[SmOke_N]

I found the Function from here >>

I was perhaps a little too keen to get the code onto the Forum. Thanks for the new version.

The stringsplit is fine, but you added WinGetHandle(), remember that StringSplit() returns an array, so essentially, you're getting the handle to nothing the way you modified it.

Anyway, that example shows how to return a window title, [n][0] = title, [n][1] = handle, using them appropriately you can avoid WinGetHandle() all together .

[guinness]

I just wiped my eyes and realised you were Returning the StringSplit() Array. I hope I am allowed this one slip up on here I now understand. Thanks.