OutlookEX UDF

[david1337]

Thank you water

[water]

When you run _Ol_Open on this machine do you get an error (@error <> 0)? Or do you still get the configuration screen?

[david1337]

_OL_Open gives no errors, and no configuration screen

[water]

Then there is at least the default profile - but not fully configured. 

[david1337]

Sorry my bad!

_OL_Open gives this error:

@error = 9

@extended = 0

[water]

So you could open Outlook, check for errors and close Outlook again. 

[david1337]

Yeah, if I can't avoid the crash with _OL_MailSignatureGet error handling in any way, it would have to use _OL_Open.
Problem with _OL_Open  is that if a user is starting up Outlook manually while _OL_Open is used, then Outlook closes again for that user.

I will try to see if I can fix the error handling of _OL_MailSignatureGet  somehow.

Thanks for your time water !

[david1337]

Okay with even more testing I found out that it's only the _OL_Close function that causes their manual start of Outlook to close :-)

I think that my speaking time on this thread is used up the next couple of days! Have a nice weekend

Edited January 26, 2017 by david1337

[bon3o]

Hi!

I have allmost figured out how to copy messages from one folder to another. But what should i do if there are subfolders? Also please can you explane what does the [0][0] & [1][0] next to $aOL_Item means? Sorry if it is a dumb question, i am not a coder(((

Local $sFilePath = "C:\tmp\outlook.log"
Local $iFileExists = FileExists($sFilePath)
Global $oOutlook = _OL_Open()
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)
If $iFileExists Then
    MsgBox($MB_SYSTEMMODAL, "Error, outlook.log exists", "this operation shuold run once" )
 Else
   _FileCreate("c:\tmp\outlook.log")
   $aOL_Item = _OL_ItemFind($oOutlook, "*\\Входящие", $olMail, "", "", "", "EntryID")
    While  $aOL_Item[0][0] > 0
   $aOL_Item = _OL_ItemFind($oOutlook, "*\\Входящие", $olMail, "", "", "", "EntryID")
   _OL_ItemMove($oOutlook, $aOL_Item[1][0], Default, "*\\Inbox")
   If @error = 1 Then MsgBox(16, "OutlookEX UDF: _OL_ItemCopy Example Script", "Error copying mail to another folder. @error = " & @error)
   Wend
EndIf
_OL_Close($oOutlook)

 

[water]

You need to loop through the array like this:

Local $sFilePath = "C:\tmp\outlook.log"
Local $iFileExists = FileExists($sFilePath)
Global $oOutlook = _OL_Open()
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)
If $iFileExists Then
    MsgBox($MB_SYSTEMMODAL, "Error, outlook.log exists", "this operation should run once" )
Else
   _FileCreate("c:\tmp\outlook.log")
   $aOL_Item = _OL_ItemFind($oOutlook, "*\\Входящие", $olMail, "", "", "", "EntryID")
   For $i = 1 to $aOL_Item[0][0]
       _OL_ItemMove($oOutlook, $aOL_Item[$i][0], Default, "*\\Inbox")
       If @error Then MsgBox(16, "OutlookEX UDF: _OL_ItemCopy Example Script", "Error copying mail to another folder. @error = " & @error)
   Next
EndIf
_OL_Close($oOutlook)

$aOL_Item[0][0] holds the number of data rows in the array, $aOL_Item[0][1] the number of columns.

Edited January 28, 2017 by water
Fixed typo

[bon3o]

water! Thank you so much! Now the script runs without an error so i can continue to copy next folder items.

[water]

Glad you like my solution

[bon3o]

btw, what should i do with the subfolders? is there a way to move like this : "\\inbox1\*" "\\inbox2\"  to move all the existing subfolders to inbox2 without moving the parent folder inbox1?

[water]

Use _OL_FolderTree to get a list of folders in "\\inbox1\*" and then loop through the returned array and use _OL_FolderMove for each entry.

[bon3o]

What am i doing wrong?

$aFol = _OL_FolderTree($oOutlook, "*\\Входящие\")
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OL_FolderTree Example Script", "Error accessing folder 'Outlook-UDF-Test'. @error = " & @error)
;_ArrayDisplay($aFol, "OutlookEX UDF: _OL_FolderTree Example Script - Tree starting with '*\Outlook-UDF-Test'")
For $i = 1 to $aFol[0][0]
       _OL_FolderMove($oOutlook, $aFol[$i][0], "*\\Inbox")
       If @error Then MsgBox(16, "OutlookEX UDF: _OL_ItemCopy Example Script", "Error copying mail to another folder. @error = " & @error)
   Next

I get an error: Array variable has incorrect number of subscripts or subscript dimension range exceeded.(((

 

Edited January 28, 2017 by bon3o

[bon3o]

Why do i get hidden post`s?

[Jos]

2 minutes ago, bon3o said:

Why do i get hidden post`s?

There is a check in our forums to avoid spam that does this. Not going to explain too much about it, but don't worry, we will approve them when one of us is around.

Jos

Edited January 28, 2017 by Jos

[water]

_OL_FolderMove moves the folder and all subfolders. So you only need to list the first level of directories using _OL_FolderTree.

$aFol = _OL_FolderTree($oOutlook, "*\\Входящие\", 1)
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OL_FolderTree Example Script", "Error accessing folder 'Outlook-UDF-Test'. @error = " & @error)
;_ArrayDisplay($aFol, "OutlookEX UDF: _OL_FolderTree Example Script - Tree starting with '*\Outlook-UDF-Test'")
For $i = 1 to $aFol[0][0]
    _OL_FolderMove($oOutlook, $aFol[$i][0], "*\\Inbox")
    If @error Then MsgBox(16, "OutlookEX UDF: _OL_ItemCopy Example Script", "Error copying mail to another folder. @error = " & @error)
Next

 

[bon3o]

Unfortunately i get the same error((

"D:\Desktop\FolderMove.au3" (14) : ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
For $i = 1 to $aFol[0][0]
For $i = 1 to ^ ERROR

[water]

_OL_FolderTree returns a 1D array. So the script should look like:

$aFol = _OL_FolderTree($oOutlook, "*\\Входящие\", 1)
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OL_FolderTree Example Script", "Error accessing folder 'Outlook-UDF-Test'. @error = " & @error)
;_ArrayDisplay($aFol, "OutlookEX UDF: _OL_FolderTree Example Script - Tree starting with '*\Outlook-UDF-Test'")
For $i = 1 to $aFol[0]
    _OL_FolderMove($oOutlook, $aFol[$i], "*\\Inbox")
    If @error Then MsgBox(16, "OutlookEX UDF: _OL_ItemCopy Example Script", "Error copying mail to another folder. @error = " & @error)
Next

 

Edited January 28, 2017 by water