Random number in file

[Read]

How to make random combinations script

Ex.

test.txt is number combinations

01 02 03

01 02 04

01 02 05

test.bin coming random combinations

01 02 05

01 02 03

01 02 04

$sData = FileRead(@ScriptDir & "\test.txt")
$random = // random code here!!! How?
$hFile = FileOpen(@ScriptDir & "\test.bin", 18)
FileWrite($hFile, $random)
FileClose($hFile)

Eng bad

[Melba23]

Read,

How to make random combinations

Did you look to see if Random appeared in the Help file? Probably not or you would have found it.

M23

[Read]

test.bin come always "NULLNULLČ»¢Q9@" -something is very wrong.

maybe help?

[guinness]

That could be correct, but without any code it can be a little difficult to diagnose the problem

Edit: Check the flags for FileOpen()

Global $sRandom = Random(0, 100)
Global $hFile = FileOpen(@ScriptDir & "\Test.bin", 2)
FileWrite($hFile, $sRandom)
FileClose($hFile)

Edited March 5, 2011 by guinness

[Read]

What is it > 59.7735021729022 ?

test.bin must coming random combinations - take test.txt comb. and make random in test.bin

one example of 100 - not work

$sData = FileRead(@ScriptDir & "\test.txt")
$random1 = Random($sData,0)
$hFile = FileOpen(@ScriptDir & "\test.bin", 18)
FileWrite($hFile, $random1)
FileClose($hFile)

Edited March 5, 2011 by Read

[Bowmore]

If I have understood your first post correctly, then I think this may be what you are looking for.

#include <file.au3> 


local $aData,$MaxRow,$rmd,$temp,

_FileReadToArray(@ScriptDir & "\test.txt", $aData)
$MaxRow = UBound($aData) - 1
For $i = 1 To $MaxRow
    $rnd = Random(1, $MaxRow, 1)
    $temp = $aData[$i]
    $aData[$i] = $aData[$rnd]
    $aData[$rnd] = $temp
Next
$hFile = FileOpen(@ScriptDir & "\test.bin", 18)
For $i = 1 To $MaxRow
    FileWrite($hFile, $random1)
Next
FileClose($hFile)

Edit: fixed bug in script

Edited March 5, 2011 by Bowmore

[Read]

Bowmore!

Edit only: #include <arrsy.au3> >> #include <array.au3>

Error:

Array.au3 don't have _FileReadToArray but File.au3 is it - both not work

[Bowmore]

Script in previous post has now been fixed.

[somdcomputerguy]

What is it &gt; 59.7735021729022 ?

The Random() function has flags too. Change

$random1 = Random($sData,0)

to

$random1 = Random($sData,1)

<strike>or</strike> and, read thru the Help file some more.

Edited March 5, 2011 by somdcomputerguy

[MvGulik]

Random ( [Min [, Max [, Flag]]] )

Parameters

Min [optional] The smallest number to be generated. The default is 0.

Max [optional] The largest number to be generated. The default is 1.

Flag [optional] If this is set to 1 then an integer result will be returned. Default is a floating point number.

[Read]

Not work.

Error:

Script in previous post has now been fixed.

[Bowmore]

You should be capable of fixing that yourself. Just remove the stray comma at the end of the line as indicated by the error message.

[Read]

Can't

Something is wrong here or no: FileWrite($hFile, $random1)???

[SmOke_N]

$random1 looks to be a code mistake.

Replace it with:

$aData[$i]

Edit:

After looking at that code, I don't see you still getting the results you want.

There was no exception made for carriage return/Line feeds.

And it's still reading an "ansi" text file, then writing it to a binary file... not sure why we'd do that.

Edited March 6, 2011 by SmOke_N
missed code tag

[Read]

Yes, not work.

What would be a working code?

[SmOke_N]

Yes, not work.

What would be a working code?

The working solution could happen much faster if you took the time and did some tutorials.

You are showing us no desire to either read the help file, comprehend it, or both.

http://www.autoitscript.com/wiki/FAQ#Where_can_I_learn_AutoIt.3F_Are_there_any_tutorials.3F

Keep in mind, anyone that helps you here is because they want to. There are no have to's.

I assume this is what you're after.

expandcollapse popup

#region Example only data
Global $gs_filefrom = @ScriptDir & "\test.txt"
Global $gs_fileto = @ScriptDir & "\test.bin"

If Not _my_FileToRandomLines($gs_filefrom, $gs_fileto) Then
    Switch @error
        Case 1
            MsgBox(16 + 262144, "Error", "Error opening " & $gs_filefrom)
        Case 2
            MsgBox(16 + 262144, "Error", "Empty file " & $gs_fileto)
        Case 3
            MsgBox(16 + 262144, "Error", "Error opening " & $gs_fileto)
    EndSwitch
    Exit
EndIf
#region Example only data

; Param 1: The file to read from
; Param 2: The file to write to
; Param 3: The read flag ( default is 0 for reading standard text file )
; Param 3: The write flag ( default is 2 for erasing old content and creating a new standard text file )
Func _my_FileToRandomLines($s_filein, $s_fileout, $i_readflag = 0, $i_writeflag = 2)

    If $i_readflag = -1 Or $i_readflag = Default Then $i_readflag = 0
    If $i_writeflag = -1 Or $i_writeflag = Default Then $i_writeflag = 2

    ; open with reader flag mode
    Local $h_open = FileOpen($s_filein, $i_readflag)
    If $h_open = -1 Then Return SetError(1, 0, 0)

    Local $s_fread = FileRead($h_open)
    FileClose($h_open)

    If $s_fread = "" Then Return SetError(2, 0, 0)

    ; open write to file
    $h_open = FileOpen($s_fileout, $i_writeflag)
    If $h_open = -1 Then Return SetError(3, 0, 0)

    ; split file lines
    Local $a_lines = StringSplit(StringStripCR($s_fread), @LF)

    ; shuffle lines, start at index 1, index 0 is only count
    Local $a_writelines = _ArrayShuffle($a_lines, 1)

    For $iline = 1 To $a_writelines[0]
        FileWriteLine($h_open, $a_writelines[$iline])
    Next

    FileClose($h_open)

    Return 1
EndFunc

Func _ArrayShuffle($a_arr, $i_lb = 0)
    Local $i_ub = UBound($a_arr) - 1

    Local $v_tmp, $i_rndm
    For $irow = $i_lb To $i_ub
        $v_tmp = $a_arr[$irow]
        $i_rndm = Random($i_lb, $i_ub, 1)
        $a_arr[$irow] = $a_arr[$i_rndm]
        $a_arr[$i_rndm] = $v_tmp
    Next

    Return $a_arr
EndFunc

Edited March 6, 2011 by SmOke_N
brainfart

[Read]

works very well, thanks SmOke_N!

Thanks all