[SOLVED] Date from a WMI Function is returning with ?? contained in the String.

[guinness]

I'm using a Function by to get the Date/Time taken of a Photo.

What I can't get my head around is the Date returned contains ??'s when shown in the Console of SciTE, but in a MsgBox() this isn't the case.

My intention is to convert the date from 26/02/2011 15:15 to 26-02-2011, which as you can see in _Example_2() is working, so it isn't the SRE that's the problem. I have substituted ?? in the SRE (no use!) Tried StringReplace(), String() but to no avail. If anyone has an idea or a reference to MSDN then this would be much appreciated. Thank you.

The example below takes you through the steps:

expandcollapse popup

Global $File = FileOpenDialog("Select A Photo", @ScriptDir, "(*.*)")
If @error Then Exit

_Example_1($File)
_Example_2($File)

Func _Example_1($sFilePath) ; Not Working!
    ConsoleWrite("Example 1 (Using Real Date!)" & @CRLF)
    $iDate = _Read_File_Properties($sFilePath) ; Get Files "Taken Date"
    ConsoleWrite("The Date of " & $sFilePath & " = " & $iDate & @CRLF)
    MsgBox(0, "Lets Check!", "Does the Console show ??'s in the date, because MsgBox() doesn't " & @CRLF & @CRLF & $iDate)
    $iConvertedDate = StringRegExpReplace($iDate, "(\d{2})/(\d{2})/(\d{4})\s+(\d{2}):(\d{2})", "$2-$1-$3") ; Convert 26/02/2011 15:15 >> 02-26-2011
    ConsoleWrite("The Date of " & $sFilePath & " converted from >> " & $iDate & " is " & $iConvertedDate & @CRLF & @CRLF)
EndFunc   ;==>_Example_1

Func _Example_2($sFilePath) ; Working!
    ConsoleWrite("Example 2 (Using Fake Date!)" & @CRLF)
    $iDate = "26/02/2011 15:15" ; Get Files "Taken Date"
    ConsoleWrite("The Date of " & $sFilePath & " = " & $iDate & @CRLF)
    MsgBox(0, "Lets Check!", "Does the Console show ??'s in the date, because MsgBox() doesn't " & @CRLF & @CRLF & $iDate)
    $iConvertedDate = StringRegExpReplace($iDate, "(\d{2})/(\d{2})/(\d{4})\s+(\d{2}):(\d{2})", "$2-$1-$3") ; Convert 26/02/2011 15:15 >> 02-26-2011
    ConsoleWrite("The Date of " & $sFilePath & " converted from >> " & $iDate & " is " & $iConvertedDate & @CRLF & @CRLF)
EndFunc   ;==>_Example_2

Func _Read_File_Properties($sPassed_File_Name) ; By Melba23: http://www.autoitscript.com/forum/topic/109450-file-properties/page__view__findpost__p__770326
    Local $iError = 0
    Local $sDir_Name = StringRegExpReplace($sPassed_File_Name, "(^.*\\)(.*)", "\1")
    Local $sFile_Name = StringRegExpReplace($sPassed_File_Name, "^.*\\", "")
    Local $sDOS_Dir = FileGetShortName($sDir_Name, 1)

    Local $oShellApp = ObjCreate("shell.application")
    If IsObj($oShellApp) Then
        Local $oDir = $oShellApp.NameSpace($sDOS_Dir)
        If IsObj($oDir) Then
            Local $oFile = $oDir.Parsename($sFile_Name)
            If IsObj($oFile) Then
                $sFile_Property = $oDir.GetDetailsOf($oFile, 12) ; Insert number for property required - Windows Vista/7: Time Taken Or Windows XP: 26
                Return $sFile_Property
            Else
                $iError = 3
            EndIf
        Else
            $iError = 2
        EndIf
    Else
        $iError = 1
    EndIf
    If $iError > 0 Then
        Local $sMsg = "Could not read File Properties" & @CRLF & @CRLF & _
                $iError & @CRLF & @CRLF & $sPassed_File_Name
        MsgBox(0, "Error", $sMsg)
    EndIf
EndFunc   ;==>_Read_File_Properties

UPDATED: See working code >>

Edited March 1, 2011 by guinness

[Xenobiologist]

Hi,

no problem for me. Output shows :

Example 1 (Using Real Date!)
The Date of c:\Dokumente und Einstellungen\xf01145\Eigene Dateien\Eigene Bilder\Flyer\Dreh_CIMG6129_ohneRot.jpg = 07.02.2005 11:20
The Date of c:\Dokumente und Einstellungen\xf01145\Eigene Dateien\Eigene Bilder\Flyer\Dreh_CIMG6129_ohneRot.jpg converted from >> 07.02.2005 11:20 is 07.02.2005 11:20

Example 2 (Using Fake Date!)
The Date of c:\Dokumente und Einstellungen\xf01145\Eigene Dateien\Eigene Bilder\Flyer\Dreh_CIMG6129_ohneRot.jpg = 26/02/2011 15:15
The Date of c:\Dokumente und Einstellungen\xf01145\Eigene Dateien\Eigene Bilder\Flyer\Dreh_CIMG6129_ohneRot.jpg converted from >> 26/02/2011 15:15 is 02-26-2011

Besides I used

$sFile_Property = $oDir.GetDetailsOf($oFile, 25) ; Insert number for property required - Windows Vista/7: Time Taken Or Windows XP: 26

Mega

[guinness]

Thanks for Testing! You must be using XP because 25 is Blank on Vista/7. I forgot to mention that this is only Date out of all the properties that Returns one with ??

I think it's just one of those things on Vista/7!

[guinness]

OK, so a kind user pointed me in the right direction, by using the following SRE destroyed the ??'s!

$iDate = StringRegExpReplace($iDate, "[^0-9]", "") ; Remove All Non-Digit Characters.

Example:

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
Global $File = FileOpenDialog("Select A Photo", @ScriptDir, "(*.*)")
If @error Then Exit
MsgBox(0, "_ImageTakenDate()", "The Image was taken on >> " & _ImageTakenDate($File))

Func _ImageTakenDate($hFileName) ; Modified From Code By Melba23: http://www.autoitscript.com/forum/topic/...operties/page__view__findpost_
    Local $iEntry = 12
    If @OSVersion = "WIN_XP" Then $iEntry = 26
    Local $sDirectoryName = StringRegExpReplace($hFileName, "(^.*\\)(.*)", "\1")
    Local $sFileName = StringRegExpReplace($hFileName, "^.*\\", "")
    Local $sDirectoryDOS = FileGetShortName($sDirectoryName, 1)

    Local $oObjCreate = ObjCreate("shell.application")
    If IsObj($oObjCreate) Then
        Local $oDirectory = $oObjCreate.NameSpace($sDirectoryDOS)
        If IsObj($oDirectory) Then
            Local $oFile = $oDirectory.Parsename($sFileName)
            If IsObj($oFile) Then Return _ConvertDate($oDirectory.GetDetailsOf($oFile, $iEntry))
        EndIf
    EndIf
    Return SetError(1, 0, 0)
EndFunc   ;==>_ImageTakenDate

Func _ConvertDate($iDate)
    If Not StringInStr($iDate, ":") Then Return SetError(1, 0, 0)
    $iDate = StringRegExpReplace($iDate, "[^0-9]", "") ; Remove All Non-Digit Characters.
    Return StringRegExpReplace($iDate, "(\d{2})(\d{2})(\d{4})(\d{2})(\d{2})", "$1-$2-$3 $4:$5") ; Convert To 16-02-2011.
EndFunc   ;==>_ConvertDate

Edited March 1, 2011 by guinness