[SOLVED] _WMIDateStringToDate() & _DateToWMIDateString()

[guinness]

Working Code has been Included!

More details about the WMI Date String can be found here >> http://technet.microsoft.com/en-us/library/ee156576.aspx

There is currently an Example of WMIDateStringToDate() floating around the Forums that uses StringMid() but I decided that I wanted to have a little go at improving my knowledge of StringRegExpReplace(). Therefore I created the following Functions with thanks to jhcd, PsaltyDS & GEOSoft >>

Function:

expandcollapse popup

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
; #FUNCTION# =========================================================================================================
; Name...........: _WMIDateStringToDate()
; Description ...: Converts a WMI date to a UK/US formatted date.
; Syntax.........: _WMIDateStringToDate($sDate)
; Parameters ....: $sDate - A WMI returned from an Object() call.
; Requirement(s).: v3.2.12.1 or higher
; Return values .: Success - A UK/US formatted date.
;                  Failure - Returns 0
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _WMIDateStringToDate($sDate)
    Local $sDelimeter = '/'
    Return StringRegExpReplace($sDate, '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\.\d{6}\+\d{3}', '\3' & $sDelimeter & '\2' & $sDelimeter & '\1 \4:\5:\6') ; jchd's Efficent Version - $10 Is The Number Of Minutes Difference Between Your Local Time And Greenwich Mean Time.
EndFunc   ;==>_WMIDateStringToDate

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
; #FUNCTION# =========================================================================================================
; Name...........: _DateToWMIDateString()
; Description ...: Converts a UK/US formatted date to WMI date.
; Syntax.........: _DateToWMIDateString($sDate)
; Parameters ....: $sDate - A UK/US formatted date.
; Requirement(s).: v3.2.12.1 or higher
; Return values .: Success - A WMI date.
;                  Failure - Returns 0
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _DateToWMIDateString($sDate)
    Local $iOffSet = 000, $oWMIService = ObjGet('winmgmts:{impersonationLevel = impersonate}!\\.\root\cimv2')
    Local $oColFiles = $oWMIService.ExecQuery('Select Bias From Win32_TimeZone')
    If IsObj($oColFiles) Then
        For $oObjectFile In $oColFiles
            $iOffSet = $oObjectFile.Bias ; Retrieve GMT Offset - http://technet.microsoft.com/en-us/library/ee156558.aspx
        Next
    EndIf
    Return StringRegExpReplace($sDate, '(\d{2})/(\d{2})/(\d{4})\s+(\d{2}):(\d{2}):(\d{2})', '\3\2\1\4\5\6.000000+') & $iOffSet ; jchd's Version.
EndFunc   ;==>_DateToWMIDateString

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
; #FUNCTION# =========================================================================================================
; Name...........: _WMIDateStringToDateLocale()
; Description ...: Converts a WMI date to a UK/US formatted date depending on your regional settings.
; Syntax.........: _WMIDateStringToDateLocale($sDate)
; Parameters ....: $sDate - A WMI returned from an Object() call.
; Requirement(s).: v3.2.12.1 or higher
; Return values .: Success - A UK/US formatted date.
;                  Failure - Returns 0
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _WMIDateStringToDateLocale($sDate)
    Return _DateTimeFormat(StringRegExpReplace($sDate, '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\.\d{6}\+\d{3}', '\1/\2/\3 \4:\5:\6'), 0)
EndFunc   ;==>_WMIDateStringToDateLocale

Example use of Function:

#include <Constants.au3>
#include <Date.au3>

Local $sDate = _DateToWMIDateString(@MDAY & '/' & @MON & '/' & @YEAR & ' ' & @HOUR & ':' & @MIN & ':' & @SEC) ; Get Todays Date & Time (01/12/2011 12:01:59)

MsgBox($MB_SYSTEMMODAL, '_DateToWMIDateString()', $sDate) ; Example of converting 01/12/2011 12:01:59 >> 20111201120159.000000+000
MsgBox($MB_SYSTEMMODAL, '_WMIDateStringToDate()', _WMIDateStringToDate($sDate)) ; Example of converting 20111201120159.000000+000 >> 01/12/2011 12:01:59

Edit: Updated with responses from below Edited June 30, 2014 by guinness

[PsaltyDS]

You might want to look at in the Example Scripts, at the change log in the first post:

06/12/2008 -- v2.0.1 -- Added geeky RegExp for WMI date conversion by weaponx

Here was the /page__view__findpost__p__534828.

Edited February 16, 2011 by PsaltyDS

[jchd]

I'd do this (several typos fixed):

Global $Date = _DateToWMIDateString(@MDAY & "/" & @MON & "/" & @YEAR & " " & @HOUR & ":" & @MIN & ":" & @SEC) ; Get Todays Date & Time (01/12/2011 12:01:59)

MsgBox(64, "_DateToWMIDateString()", $Date) ; Example of converting 01/12/2011 12:01:59 >> 20111201120159.00000+000
MsgBox(64, "_WMIDateStringToDate()", _WMIDateStringToDate($Date)) ; Example of converting 20111201120159.00000+000 >> 01/12/2011 12:01:59

Func _WMIDateStringToDate($sDate) ; Converts "20111201120159.00000+000" >> "01/12/2011 12:01:59"
    Return StringRegExpReplace($sDate, "(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\.\d{5}\+\d{3}", "$3/$2/$1 $4:$5:$6")
EndFunc   ;==>_WMIDateStringToDate

Func _DateToWMIDateString($sDate) ; Converts "01/12/2011 12:01:59" >> "20111201120159.00000+000"
    Local $iOffSet = 000
    Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & "." & "\root\cimv2")
    Local $oColFiles = $oWMIService.ExecQuery("Select * From Win32_TimeZone")
    If IsObj($oColFiles) Then
        For $oObjectFile In $oColFiles
            $iOffSet = $oObjectFile.Bias ; Retrieve GMT Offset - http://technet.microsoft.com/en-us/library/ee156558.aspx
        Next
    EndIf
    Return StringRegExpReplace($sDate, "(\d{2})/(\d{2})/(\d{4})\h+(\d{2}):(\d{2}):(\d{2})", "$3$2$1$4$5$6.000000+") & $iOffSet
EndFunc   ;==>_DateToWMIDateString

Disclaimer: I didn't test it!

[guinness]

Argh! Silly mistakes in my First Post! Thanks jchd for pointing them out. I tested yours and it seems your version of _WMIDateStringToDate() doesn't work for some reason, whereas mine did. And thanks for the alternative with _DateToWMIDateString() (there are more ways to peal a banana - PC version of an old idiom!)

PsaltyDS - Thanks for that, I didn't search about this to be honest (not like me) but then my script worked, I was just looking at other variations of doing the same thing. As you said in the _ProcessListProperties() post >> "Constructive criticism welcome." << Always felt this emoticon looks as though it's confused and not winking!

I hope no one minds me using the General Forum to ask about this?!

Edited February 16, 2011 by guinness

[jchd]

Ooops against Ooops: we've both made errors.

_WMIDateStringToDate() does work on the supplied example

_DateToWMIDateString() doesn't due to \h+ used in place of \s+ so the last line should be

Return StringRegExpReplace($sDate, "(\d{2})/(\d{2})/(\d{4})\s+(\d{2}):(\d{2}):(\d{2})", "$3$2$1$4$5$6.000000+") & $iOffSet

Also you might want to use StringFormat to make sure that $iOffset has leading zero(es).

[guinness]

Cool thanks for that, but i don't know how you are getting your version of _WMIDateStringToDate() to work? As it should be this >>

Return StringRegExpReplace($sDate, "(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\.\d{6}\+\d{3}", "$3/$2/$1 $4:$5:$6")

\d{5} was changed to \d{6}

Edited February 16, 2011 by guinness

[jchd]

I changed it from 6 to 5 digits to follow the [only] example _you_ gave

[guinness]

Yes...You're right, I'm sorry about that , was in a rush whilst typing the Example comments. So I was in the wrong this time ... Touché Touché!

Edited February 16, 2011 by guinness

[jchd]

No harm done, we all make dumb mistakes by the yard, don't we?

Indeed I was expecting you to catch this as I thought you successfully tested your code, so I was about positive it should have been \d{6}, but the accompanying example was .00000+000 so I sticked to it.

If only every error could be so elementary in all software industry!

[GEOSoft]

One of these days I have to get some time to take the WMI date code out og my compiled version of the Scripto-matic. I wrote a function to do exactly what you needed that uses a simple DLL call with StringFormat() that I was going to put in there instead.

It returned the correct results and it wasn't as convoluted as the existing WMIDateStringToDate()

[argumentum]

plaese help me with this regular expression stuff

#include <Constants.au3>
#include <Date.au3>

Local $sDate = @MDAY & '/' & @MON & '/' & @YEAR & ' ' & @HOUR & ':' & @MIN & ':' & @SEC ; Get Todays Date & Time (01/12/2011 12:01:59)
MsgBox($MB_SYSTEMMODAL, '_DateToWMIDateString()', $sDate & @CR & ' = ' & @CR & _DateToWMIDateString($sDate)) ; Example of converting 01/12/2011 12:01:59 >> 20111201120159.000000+000
MsgBox($MB_SYSTEMMODAL, '_WMIDateStringToDate()', _DateToWMIDateString($sDate) & @CR & ' = ' & @CR & _WMIDateStringToDate(_DateToWMIDateString($sDate))) ; Example of converting 20111201120159.000000+000 >> 01/12/2011 12:01:59
MsgBox($MB_SYSTEMMODAL, '_WMIDateStringToDateLocale()', _DateToWMIDateString($sDate) & @CR & ' = ' & @CR & _WMIDateStringToDate(_DateToWMIDateString($sDate)))

it don't work for me

[iamtheky]

I think that regexp is only checking for + signs, but i may be wrong.  This clears it up:

 

Func _WMIDateStringToDate($sDate)
    Local $sDelimeter = '/'
    Return StringRegExpReplace($sDate, '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\.\d{6}(\+|\-)\d{3}', '\3' & $sDelimeter & '\2' & $sDelimeter & '\1 \4:\5:\6') ; jchd's Efficent Version - $10 Is The Number Of Minutes Difference Between Your Local Time And Greenwich Mean Time.
EndFunc   ;==>_WMIDateStringToDate

 

[kylomas]

argumentum,

I use this function in a modified version of Scriptomatic that I use. 

Func CNVTDate($dtmDate)
    ; reformat date to mm/dd/yyyy hh:mm:ss and zero fill single digit values
    Return StringRegExpReplace(StringRegExpReplace($dtmDate, '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2}).*', '$2/$3/$1 $4:$5:$6'), '(?<!\d)(\d/)', '0$1')
EndFunc   ;==>CNVTDate

I also fixed the problem with WMI returning array's.  PM me if your interested.

kylomas