resolve remote computername

[memnon]

hello

is there an autoit function to get the name of a remote pc (like ping -a x.x.x.x from dos ?)

thx for answer

[Steveiwonder]

Using ping -a with Run() should do it

Edited February 9, 2011 by Steveiwonder

[UEZ]

You can use WMI to get the remote host name.

ping -a will only work when a DNS is available!

Br,

UEZ

Edited February 9, 2011 by UEZ

[memnon]

thx...

found a wy with autoit functions... _TCPIpToName

[UEZ]

I don't know whether _TCPIpToName will work when there is no DNS/WINS available.

Here a WMI version:

 

expandcollapse popup

;code by UEZ 2011

Global Const $oErrorHandler = ObjEvent("AutoIt.Error", "ObjErrorHandler")
$sIP = "127.0.0.1"
MsgBox(0, "Get Host Name", "IP: " & $sIP & " -> Host Name: " &  WMI_GetHostName($sIP))

Func WMI_GetHostName($host)
    Local $HostNameWMI, $colItems, $colItem, $ping
    $ping = Ping($host)
    If $ping Then
        $objWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & $host & "\root\cimv2")
        If @error Then Return SetError(2, 0, "")
        $colItems = $objWMIService.ExecQuery("SELECT SystemName FROM Win32_NetworkAdapter WHERE NetConnectionStatus=2", "WQL", 0x30)
        If IsObj($colItems) Then
            For $objItem In $colItems
                If $objItem.SystemName = "" Then Return SetError(3, 0, "")
                Return $objItem.SystemName
            Next
            Return $HostNameWMI
        Else
            Return SetError(3, 0, "")
        EndIf
    Else
        Return SetError(1, 0, "")
    EndIf
EndFunc


Func ObjErrorHandler()
    ConsoleWrite(   "A COM Error has occured!" & @CRLF  & @CRLF & _
                                "err.description is: "    & @TAB & $oErrorHandler.description    & @CRLF & _
                                "err.windescription:"     & @TAB & $oErrorHandler & @CRLF & _
                                "err.number is: "         & @TAB & Hex($oErrorHandler.number, 8)  & @CRLF & _
                                "err.lastdllerror is: "   & @TAB & $oErrorHandler.lastdllerror   & @CRLF & _
                                "err.scriptline is: "     & @TAB & $oErrorHandler.scriptline     & @CRLF & _
                                "err.source is: "         & @TAB & $oErrorHandler.source         & @CRLF & _
                                "err.helpfile is: "       & @TAB & $oErrorHandler.helpfile       & @CRLF & _
                                "err.helpcontext is: "    & @TAB & $oErrorHandler.helpcontext & @CRLF _
                            )
EndFunc

 

Br,
UEZ

Edited May 14, 2013 by UEZ

[memnon]

thx again, i will keep it alternative

[minimen456]

2UEZ: script is not working. I'm getting error message:

==> Variable must be of type "Object".:
$colItems = $objWMIService.ExecQuery("SELECT DNSHostName FROM Win32_ComputerSystem", "WQL", 0x30)
$colItems = $objWMIService^ ERROR

What's wrong?

[UEZ]

2UEZ: script is not working. I'm getting error message:

==> Variable must be of type "Object".:
$colItems = $objWMIService.ExecQuery("SELECT DNSHostName FROM Win32_ComputerSystem", "WQL", 0x30)
$colItems = $objWMIService^ ERROR

What's wrong?

I added an error handling to the code. Post the result from the console.

Did you run it with "127.0.0.1" or with a different host?

Br,

UEZ

Edited February 15, 2013 by UEZ

[minimen456]

Thanks for quick respond. I ran it with 127.0.0.1. I've got error message:

A COM Error has occured!
err.description is:
err.windescription:
err.number is: 80041017
err.lastdllerror is: 0
err.scriptline is: 11
err.source is:
err.helpfile is:
err.helpcontext is: 7602293

Then I added #RequireAdmin to the script. There was no error message this time but I didn't get any MsgBox (with computer name)

Edited February 15, 2013 by minimen456

[UEZ]

Disable UAC and try again or compile and run it.

Br,

UEZ

[minimen456]

I did what you've said. There isn't any information in the MsgBox. I tried both to run exe-file as User and RunAs Admin

Edited February 15, 2013 by minimen456

[UEZ]

You are using WinXP and DNSHostName method is not availabe for XP. I changed the code above again. Please try again.

Br,

UEZ

Edited February 15, 2013 by UEZ

[minimen456]

Now it works. Thanks