Getting a window topmost by handle [solved]

[Psychoman]

Context

After playing with AutoIt for some time I'm trying to get a window topmost.

I'd like to get the same effect as AutoIt v3 Window Info with the flag Always On Top set.

The window can be put on top of all other windows with a button.

GUI

I have this window with 2 buttons on it.

The first button Set window topmost will change the style of the window to make it topmost.

The second button Set window normal will reset the style of the window.

By default he window is not topmost.

Source code

expandcollapse popup

; --------
; Includes
; --------

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


; ---------
; Variables
; ---------

Global $varWindow, $varButtonTopmost, $varButtonNormal, $varLoop, $varMessage


; ----
; Main
; ----

$varWindow = GUICreate("Win", 130, 75)
$varButtonTopmost = GUICtrlCreateButton("Set window topmost", 10, 10, 110)
$varButtonNormal = GUICtrlCreateButton("Set window normal", 10, 40, 110)
GUISetState(@SW_SHOW)
$varLoop = True

While $varLoop
    $varMessage = GUIGetMsg()
    Select
        Case $varMessage = $GUI_EVENT_CLOSE
            $varLoop = False
            Exit
        Case $varMessage == $varButtonTopmost
            _Button_Topmost_Clicked()
        Case $varMessage == $varButtonNormal
            _Button_Normal_Clicked()
    EndSelect
WEnd


; ---------
; Functions
; ---------

Func _Button_Topmost_Clicked()
    Local $varStyles = GUIGetStyle($varWindow)
    GUISetStyle($varStyles[0], BitOr($varStyles[1], $WS_EX_TOPMOST), $varWindow)
EndFunc


Func _Button_Normal_Clicked()
    Local $varStyles = GUIGetStyle($varWindow)
    GUISetStyle($varStyles[0], BitXor($varStyles[1], $WS_EX_TOPMOST), $varWindow)
EndFunc

Question

The source code above doesn't work.

The window just won't be placed topmost.

Could someone tell me why this code doesn't work?

As I have been browsing and searching this forum forever help would greatly be appreciated.

Edited January 26, 2011 by Psychoman

[kaotkbliss]

in your functions, instead of using guictrlsetstate, have you tried WinSetOnTop?

Func _Button_Topmost_Clicked()

WinSetOnTop($varWindow,"",1)

EndFunc

Func _Button_Normal_Clicked()

WinSetOnTop($varWindow,"",0)

EndFunc

[jaberwacky]

kaotkbliss beat me to it!

FOILED once again!

Edited January 25, 2011 by jaberwocky6669

[kaotkbliss]

Would have gotten away with it too if it weren't for those meddling kids, Jabberwocky?

[ShawnW]

Umm so if you are able to click the button, would the window not already be on top?

[Psychoman]

in your functions, instead of using guictrlsetstate, have you tried WinSetOnTop?

Actually I didn't.

I came across this function on the forum and in the help files.

The documentation states that the first parameter has to be the name of the window.

WinSetOnTop ( "title", "text", flag )

It's true that if you follow the link in the documentation you get a description on how to use the title parameter.

Although I took a look at that documentation I must have missed the last part, stating that the parameter title can be replaced with a handle.

Now it works like a charm.

Thanks a lot kaotkbliss

[kaotkbliss]

Umm so if you are able to click the button, would the window not already be on top?

It changes the flag of the window

1 being always on top so no matter if you click another window afterwards the other will still be on top

[jaberwacky]

Would have gotten away with it too if it weren't for those meddling kids, Jabberwocky?

Next time, next time.