UPDOWN help

[darklonerlv]

im trying to set the updown counter to increase in 100 increments aka 5100 5200 5300 etc etc have the limit set i just cant figure out how to set this

[PsaltyDS]

I don't think you can set the UpDown control itself for that, but you can catch the event when it is changed and then update the Edit control's value. It would be UDN_DELTAPOS by WM_NOTIFY.

For example, if the Edit control contains 5100 and the Up button is clicked to 5101, the event handler would quickly change the value to 5200.

[darklonerlv]

I don't think you can set the UpDown control itself for that, but you can catch the event when it is changed and then update the Edit control's value. It would be UDN_DELTAPOS by WM_NOTIFY.

For example, if the Edit control contains 5100 and the Up button is clicked to 5101, the event handler would quickly change the value to 5200.

hmm maybe ill go about it another way then.

[Melba23]

darklonerlv,

It is not that difficult:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <UpDownConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hInput = GUICtrlCreateInput("5000", 10, 10, 100, 20)
$hUpDown = GUICtrlCreateUpdown($hInput, BitOR($UDS_WRAP, $UDS_NOTHOUSANDS))
GUICtrlSetLimit($hUpDown, 6000, 5000)

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    ; Is it from the UpDown?
    If BitAND($wParam, 0xFFFF) = $hUpDown Then
        ; Create NMUPDOWN structure
        Local $tStruct = DllStructCreate("hwnd;long;int;long;long", $lParam)
        ; Is it a change message?
        If DllStructGetData($tStruct, 3) = 0xFFFFFD2E Then ; $UDN_DELTAPOS
            ; Alter the change value
            DllStructSetData($tStruct, 5, 100 * DllStructGetData($tStruct, 5))
        EndIf
    EndIf

EndFunc

The NMUPDOWN structure holds:

1 - Handle of UpDown
2 - ControlID of UpDown
3 - Message type sent by UpDown
4 - Current value of UpDown
5 - Change to apply to input (+/-1)

Once we intercept the change message all we have to do is set the change value to +/-100 and let Windows do the rest!

M23