Disable Tabstop for specific button

[inm101]

I'm creating a button with the following command:

$shutdown = GUICtrlCreateButton("Shutdown", ($dw - $buw) / 2, 470, $buw, $buh)

How can I disable the tabstop for this button? I want to make it so the users HAVE to click the button to use it.

Thank you!

[Melba23]

inm101,

You can disable TabStop for a control like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("One", 10, 10, 50, 20)
GUICtrlCreateLabel("Two", 10, 30, 50, 20)
GUICtrlCreateLabel("Three", 10, 50, 50, 20)

GUICtrlCreateButton("One", 10, 100, 80, 30)

GUICtrlCreateButton("Two", 10, 140, 80, 30)
_WinAPI_SetWindowLong(GUICtrlGetHandle(-1), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle(-1), $GWL_STYLE), BitNOT($WS_TABSTOP)))

GUICtrlCreateButton("Three", 10, 180, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

This way you leave all the other styles in being.

M23

[inm101]

This was the magic line I was looking for:

_WinAPI_SetWindowLong(GUICtrlGetHandle(-1), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle(-1), $GWL_STYLE), BitNOT($WS_TABSTOP)))

Thank you very much.