Question about CreateWindowEx

[zeffy]

So basically, I need to use _WinAPI_CreateWindowEx() to make a window with a specific class name, to receive WM_COPYDATA messages from another program, and process the information with my autoit script. I have no idea where to even start with this, could someone point me in the right direction?

[rover]

what's so hard about searching the forum for CreateWindowEx (3 pages of results) and WM_COPYDATA (6 pages of results)?

Hint: look on first page of results for CreateWindowEx

Edited December 21, 2010 by rover

[zeffy]

hur dur use the seach function

I have already read dozens of topics on this subject, none of them had the specific information that I asked about. Thanks for not being helpful in the slightest, next time consider contributing to a thread before you post.

Edited December 21, 2010 by zeffy

[zeffy]

I love how helpful everyone is on this forum!

[zeffy]

Anyone feeling helpful?

Edited December 21, 2010 by zeffy

[Yashied]

expandcollapse popup

#Include <WinAPIEx.au3>
#Include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global Const $CW_USEDEFAULT = 0x80000000

Global Const $sClass = 'MyWindowClass'
Global Const $sName = 'MyProg'

Global $tWCEX, $tClass, $hWnd, $hProc, $hInstance, $Text = False

OnAutoItExitRegister('AutoItExit')

$hInstance = _WinAPI_GetModuleHandle(0)
$hProc = DllCallbackRegister('_WndProc', 'lresult', 'hwnd;uint;wparam;lparam')
$tClass = DllStructCreate('wchar[' & StringLen($sClass) + 1 & ']')
DllStructSetData($tClass, 1, $sClass)
$tWCEX = DllStructCreate($tagWNDCLASSEX)
DllStructSetData($tWCEX, 'Size', DllStructGetSize($tWCEX))
DllStructSetData($tWCEX, 'Style', 0)
DllStructSetData($tWCEX, 'hWndProc', DllCallbackGetPtr($hProc))
DllStructSetData($tWCEX, 'ClsExtra', 0)
DllStructSetData($tWCEX, 'WndExtra', 0)
DllStructSetData($tWCEX, 'hInstance', $hInstance)
DllStructSetData($tWCEX, 'hIcon', 0)
DllStructSetData($tWCEX, 'hCursor', 0)
DllStructSetData($tWCEX, 'hBackground', 0)
DllStructSetData($tWCEX, 'MenuName', 0)
DllStructSetData($tWCEX, 'ClassName', DllStructGetPtr($tClass))
DllStructSetData($tWCEX, 'hIconSm', 0)
_WinAPI_RegisterClassEx($tWCEX)

$hWnd = _WinAPI_CreateWindowEx(0, $sClass, $sName, 0, $CW_USEDEFAULT, $CW_USEDEFAULT, $CW_USEDEFAULT, $CW_USEDEFAULT, 0)

While 1
    Sleep(100)
    If $Text Then
        MsgBox(262144, '', $Text)
        $Text = 0
    EndIf
WEnd

Func _WinAPI_DefWindowProcW($hWnd, $iMsg, $wParam, $lParam)

    Local $Ret = DllCall('user32.dll', 'lresult', 'DefWindowProcW', 'hwnd', $hWnd, 'uint', $iMsg, 'wparam', $wParam, 'lparam', $lParam)

    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    Return $Ret[0]
EndFunc   ;==>_WinAPI_DefWindowProcW

Func _WndProc($hWnd, $iMsg, $wParam, $lParam)
    Switch $iMsg
        Case $WM_COPYDATA

            Local $tCOPYDATA = DllStructCreate('ulong_ptr;dword;ptr', $lParam)
            Local $tData = DllStructCreate('wchar[' & DllStructGetData($tCOPYDATA, 2) & ']', DllStructGetData($tCOPYDATA, 3))

            $Text = DllStructGetData($tData, 1)
            Return 1
    EndSwitch
    Return _WinAPI_DefWindowProcW($hWnd, $iMsg, $wParam, $lParam)
EndFunc   ;==>_WndProc

Func AutoItExit()
    _WinAPI_DestroyWindow($hWnd)
    _WinAPI_UnregisterClass($sClass, $hInstance)
    DllCallbackFree($hProc)
EndFunc   ;==>AutoItExit

Send a messages with the following code:

#Include <WindowsConstants.au3>

While 1
    $Text = InputBox('', 'String to send', '', '', 300, 130, 200, 200)
    If Not $Text Then
        Exit
    EndIf
    $hWnd = WinGetHandle('[CLASS:MyWindowClass;TITLE:MyProg]')
    $tCOPYDATA = DllStructCreate('ulong_ptr;dword;ptr')
    $tData = DllStructCreate('wchar[' & StringLen($Text) + 1 & ']')
    DllStructSetData($tData, 1, $Text)
    DllStructSetData($tCOPYDATA, 2, DllStructGetSize($tData))
    DllStructSetData($tCOPYDATA, 3, DllStructGetPtr($tData))
    DllCall('user32.dll', 'lresult', 'SendMessage', 'hwnd', $hWnd, 'uint', $WM_COPYDATA, 'ptr', 0, 'ptr', DllStructGetPtr($tCOPYDATA))
WEnd

Edited December 21, 2010 by Yashied

[guinness]

Wow, incredible! Something new to study about WM_COPYDATA! Thanks

[Ascend4nt]

Very nice job Yashied. I was curious about implementing a windows procedure before, its nice to see a working example.