Input with only Numbers and decimal point

[Roshith]

Hi,

I want a GUI input to hold only numbers and decimal point. I created the Input with the style $ES_NUMBER (0x2000). But it does not accept decimal point. Could someone help

Thanks in advance..

[GEOSoft]

A wee bit of your code would have made this a touch simpler. I'll proceed on the assumption that you are using a message loop.

In your GUI messgage loop

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case -3
            Exit
    EndSwitch
    If StringRegExp(GUICtrlRead($my_input), "[^\d\.]" Then GUICtrlSetData($my_input, StringRegExpReplace(GuiCtrlRead($my_input), "[^\d\.]", ""))
WEnd

Edit: Forgot to add that you have to remove the $ES_NUMBER style

Edited December 10, 2010 by GEOSoft

[Melba23]

Roshith,

Welcome to the AutoIt forum.

Something I developed a while ago - it allows only digits, a decimal point and a leading minus. Set $iDecimal to the number of decimal places required:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Global $iDecimal = 3

GUICreate("Input Filter", 300, 30, -1, -1)
Global $inTest = GUICtrlCreateInput("", 5, 5, 290)
GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")
GUISetState(@SW_SHOW)

While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

Func MY_WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16)    ;HiWord

    If $iIDFrom = $inTest And $iCode = $EN_CHANGE Then

    $Read_Input = GUICtrlRead($inTest)
    If StringRegExp($Read_Input, '[^\d.-]|([{0-9,1}^\A-])[^\d.]') Then $Read_Input = StringRegExpReplace($Read_Input, '[^\d.-]|([{0-9,1}^\A-])[^\d.]', '\1')
    $Point1 = StringInStr($Read_Input, ".", 0)
    $Point2 = StringInStr($Read_Input, ".", 0, 2)
    If $Point2 <> 0 Then $Read_Input = StringLeft($Read_Input, $Point2 - 1)
    If $Point1 <> 0 Then $Read_Input = StringLeft($Read_Input, $Point1 + $iDecimal)
    GUICtrlSetData($inTest, $Read_Input)

    EndIf

EndFunc;==>_WM_COMMAND

Please ask if you have any questions.

M23

[funkey]

There is a great UDF doing this and more:

I always use this one becaus $ES_NUMBER is much to less.

[Roshith]

This is Awesome.. Thank you very much. I really appreciate the quick response.