Can GUICtrlSetState click a menu item?

[LWC]

None of GUICtrlSetState's states seem to click menu items. $GUI_DEFBUTTON puts the chosen item in bold but that's it.

For example, if I have a menu called "File" (with "Open" and "Save"), I want a method to open the "File" tab.

I realize I can use WinMenuSelectItem or use "&File" with Send("!F"). But those are external methods. Is there an internal method for AutoIt's own internal GUIs?

Thanks!

Edited November 23, 2010 by LWC

[BrewManNH]

Why on earth would you want to try to do that with a control you already have full control over? If you want to "click" a menu item on a menu you created, just have your script do whatever that menu item does.

[LWC]

Because I'm updating this menu dynamically based on what you select in the menu itself.

[BrewManNH]

Which is completely different from what you asked in your original post.

[LWC]

You asked me "why on Earth" so I've answered to satisfy you. Can we get back to the original question? I just want the user to see the updated menu after they click the menu item that updates the menu.

Edited November 24, 2010 by LWC

[Melba23]

LWC,

As far as I know there is no way to open a menu "internally", but here is one way you might want to use to do what you want

Here is a workaround solution - see below for a programatic method:

expandcollapse popup

#include <GUIConstantsEx.au3>
#Include <GuiMenu.au3>

$hGUI = GUICreate("Test", 500, 500)

$mFilemenu = GUICtrlCreateMenu("File")
$mTestitem = GUICtrlCreateMenuItem("Test", $mFilemenu)
$mExititem = GUICtrlCreateMenuItem("Exit", $mFilemenu)
$mHelpmenu = GUICtrlCreateMenu("?")
$mAboutitem = GUICtrlCreateMenuItem("About", $mHelpmenu)

GUISetState()

$hMenu = _GUICtrlMenu_GetMenu($hGUI)
$iCount = _GUICtrlMenu_GetItemCount($hMenu) - 1

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExititem
            Exit
        Case $mTestitem
            ReOpenMenu("File")
        Case $mAboutitem
            MsgBox(0, "Solved", "That was not too hard!")
    EndSwitch

WEnd

Func ReOpenMenu($sText)

    ; Change the menu item text
    GUICtrlSetData($mTestitem, "New Title")

    ; Move through the menu items to match the passed title
    For $i = 0 To $iCount
        If $sText = _GUICtrlMenu_GetItemText($hMenu, $i) Then
            ; Get item location
            $aItemPos = _GUICtrlMenu_GetItemRect($hGUI, $hMenu, $i)
            ; Click to open the menu
            MouseClick("primary", $aItemPos[0] + 10, $aItemPos[1] + 10, 1, 0)
        EndIf
        ExitLoop
    Next

EndFunc

I hope that helps.

M23

Edit: Because George insisted - see below.

Edited November 26, 2010 by Melba23

[GEOSoft]

Hey M8

You should change that to MouseClick("primary", $aItemPos[0] + 10, $aItemPos[1] + 10, 1, 0) in case the user is a leftie.

M23 - 2

GEO - 15

[Melba23]

George,

As usual you are absolutely correct - it must come with advanced age, and of course I am not there quite yet.

I have done as you command and amended the post above, O Great (and Aged) One.

M23

[jvanegmond]

Internally, this uses $WM_MENUSELECT with $MF_MOUSESELECT (0x8000). You need to get the handle with GUICtrlGetHandle and then use GUICtrlSendMessage. No example yet, sorry.

Edit: This demonstrates it: Just recreate the message and it send it to your GUI (by handle).

Edited November 25, 2010 by Manadar

[Melba23]

LWC,

This is how you open a menu programatically (thanks to JamesBrooks for the hint ):

expandcollapse popup

#include <GUIConstantsEx.au3>
#Include <GuiMenu.au3>

$hGUI = GUICreate("Test", 500, 500)

$mFilemenu = GUICtrlCreateMenu("File")
$mTestFileitem = GUICtrlCreateMenuItem("Test File", $mFilemenu)
$mTestHelpitem = GUICtrlCreateMenuItem("Test Help", $mFilemenu)
$mExititem = GUICtrlCreateMenuItem("Exit", $mFilemenu)
$mHelpmenu = GUICtrlCreateMenu("Help")
$mAboutitem = GUICtrlCreateMenuItem("About", $mHelpmenu)

GUISetState()

$hMenu = _GUICtrlMenu_GetMenu($hGUI)
$iCount = _GUICtrlMenu_GetItemCount($hMenu) - 1
ConsoleWrite("Count: " & $iCount & @CRLF)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExititem
            Exit
        Case $mTestFileitem
            _OpenMenu("File")
        Case $mTestHelpitem
            _OpenMenu("Help")
        Case $mAboutitem
            MsgBox(0, "Solved", "That was a bit harder!")
    EndSwitch

WEnd

Func _OpenMenu($sText)

    ; Sleep to demonstrate the menus close and reopen
    Sleep(1000)

    ; Move through the menu items to match the passed title
    For $i = 0 To $iCount
        ConsoleWrite("Text: " & _GUICtrlMenu_GetItemText($hMenu, $i) & @CRLF)
        If $sText = _GUICtrlMenu_GetItemText($hMenu, $i) Then
            ConsoleWrite($i & @CRLF)
            ; Get submenu handle
            $hSubMenu = _GUICtrlMenu_GetItemSubMenu($hMenu, $i)
            ; Get item location
            $aItemPos = _GUICtrlMenu_GetItemRect($hGUI, $hMenu, $i)
            ; Reopen the menu
            _GUICtrlMenu_TrackPopupMenu($hSubMenu, $hGUI, $aItemPos[0], $aItemPos[3])
            ExitLoop
        EndIf
    Next

EndFunc

I hope it does what you want.

Manadar,

I tried lots of messages but none of them worked even though they matched the ones sent when I clicked on the menu:

GUI creation:

GUI: 0x0015090A
Menu: 0x010308A7

Sending message = _SendMessage($hGUI, $WM_MENUSELECT, 0x80900000, $hMenu):

MouseSelect
hWnd: 0x0015090A
$iMsg: 011F
$wParam: 0x80900000
$lParam: 0x010308A7

Popup
hWnd: 0x0015090A
$iMsg: 011F
$wParam: 0x80900000
$lParam: 0x010308A7

Message Sent.

Mouse clicked on menu:

MouseSelect
hWnd: 0x0015090A
$iMsg: 011F
$wParam: 0x80900000
$lParam: 0x010308A7

Popup
hWnd: 0x0015090A
$iMsg: 011F
$wParam: 0x80900000
$lParam: 0x010308A7

M23