Window Handle/Title under mouse pointer

[Rawox]

Hi there,

Is there a way to get the title / handle from the window (not control) your mouse pointer is currently hovering over. (Not only active windows but inactive too).

I know AutoIt Window Info can do it but that's written in C, right, not in AutoIt...

Any ideas on how to do this?

Thanks in advance,

Rawox

[water]

A good place to start might be

Or have a look at _WinAPI_WindowFromPoint. The example returns a handle to the window at mouse coordinates.

Unfortunately this only works for active windows (according to the help file).

Edited November 16, 2010 by water

[Melba23]

Rawox,

This should get you started. At the moment it gives you all the windows (i.e including controls) but as it gives you the class info as well I will leave sorting that out as an exercise for the student:

#include <WinAPI.au3>

HotKeySet("{ESC}", "On_Exit")

Func On_Exit()
    Exit
EndFunc

$hCurr_HhWnd = 0

While 1

    If @AutoItX64 Then
        Local $tPoint = DllStructCreate("int X;int Y")
        DllStructSetData ( $tPoint, "X", MouseGetPos(0))
        DllStructSetData ( $tPoint, "Y", MouseGetPos(1))
        Local $tPoint64 = DllStructCreate("int64", DllStructGetPtr($tPoint))
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "int64", DllStructGetData($tPoint64, 1))
    Else
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
    EndIf

    If $aHwnd[0] <> $hCurr_HhWnd Then
        ConsoleWrite($aHwnd[0] & " - " & _WinAPI_GetClassName($aHwnd[0]) & @CRLF)
        $hCurr_HhWnd = $aHwnd[0]
    EndIf

WEnd

M23

[trancexx]

Here's an exercise for the advanced students; what would happen if every "int64" from Melba23's code would be replaced with "double"?

Extremely advanced students would run (hypothetical) code only in their advanced minds and still get the right answer.

Melba23?

[Melba23]

trancexx,

As both "int64" and "double" use 64 bits to contain the value, I imagine that the code would be unaffected.

But as I do not consider myself anywhere near "advanced" in this area I am probably completely wrong.

M23

[Ascend4nt]

rawox, just combine WindowFromPoint and GetAncestor to get the window. The window/control you get from the first API would be passed to GetAncestor, with a flag of 2 (GA_ROOT). The second call will return the window, not the control, under the mouse (which in certain cases will match what you get from the WindowFromPoint call). Note that this window won't necessarily be the main application window (could be a popup messagebox for example), but it does match the AutoIt Window Info tool's behavior.

You can of course go further and use a flag of 3 (GA_ROOTOWNER) to find the application window.

[Rawox]

Thanks for all the replies!

Ascend4nt?

How would I call these functions? I'm not that advanced in AutoIt, can it be done by using DLL Calls? Which DLL should I call then?

[Ascend4nt]

This is how to do it with the built-in UDF functions:

#include <WinAPI.au3>
#include <Misc.au3>
Local $stPoint=DllStructCreate($tagPOINT),$aPos,$hControl,$hWin,$aLastPos[2]=[-1,-1],$sLastStr='',$sStr

While Not _IsPressed('1B')
    $aPos=MouseGetPos()
    If $aPos[0]<>$aLastPos[0] Or $aPos[1]<>$aLastPos[1] Then
        DllStructSetData($stPoint,1,$aPos[0])
        DllStructSetData($stPoint,2,$aPos[1])
        $hControl=_WinAPI_WindowFromPoint($stPoint)
        $hWin=_WinAPI_GetAncestor($hControl,2)
        $sStr='Window at '&$aPos[0]&','&$aPos[1]&': "'&WinGetTitle($hWin)&'"'
        If $sLastStr<>$sStr Then
            ToolTip($sStr,0,@DesktopHeight-20)
            $sLastStr=$sStr
        EndIf
        $aLastPos=$aPos
    EndIf
    Sleep(15)
WEnd

On a side note - I'd just like to add that _WinAPI_WindowFromPoint() was poorly thought out - it should take x,y coordinates instead of a structure.