Anyone know how to flip a progress bar?

[ripdad]

Local $ui = GUICreate('test', 100, 160, -1, -1)
Local $pb = GUICtrlCreateProgress(50, 20, 10, 120, 0x04)
GUISetState(@SW_SHOW, $ui)

While 1
    For $i = 1 To 100
        GUICtrlSetData($pb, $i)
        Sleep(50)
    Next
    ExitLoop
WEnd

GUIDelete($ui)
Exit

[JoHanatCent]

What about:

For $i = 100 To 1 Step - 1

[ripdad]

Thats a great idea - but I need to graphically flip it.

[Yashied]

Thats a great idea - but I need to graphically flip it.

What do you mean?

[Yashied]

Thats a great idea - but I need to graphically flip it.

What do you mean?

[JohnOne]

After a little looking around, all the solutions I seen, were to draw your own progress bar.

Maybe in a label or something with graphics.

EDIT:

@Yashied

I think the OP wants to physically rotate the control by 180 degrees, so the progress advances from right to left.

Edited November 5, 2010 by JohnOne

[Yashied]

http://www.autoitscript.com/forum/index.php?showtopic=74649

[ripdad]

I was afraid of that - nothing simple

Thanks guys

btw -- theres nothing physical about an image on your screen!

Thats okay .. I had to think about it before I said graphically too. <grin>

Lets see, where was I ... flip, mirror, rotate ...

[JohnOne]

Well I'm no wordsmith, so just used what I had and drew attention to it with italics.

And it could be argued that a control has percieved physical properties anyway

[JoHanatCent]

So this is what 100x labels look like!

Local $ui = GUICreate('test', 100, 160, -1, -1)
GUICtrlCreateLabel(" ", 45, 20, 10, 1)
GUICtrlSetBkColor(-1, 0x00ff00)
GUISetState(@SW_SHOW, $ui)
While 1
    For $i = 1 To 100
        Sleep(50)
        GUICtrlCreateLabel(" ", 45, 20, 10, $i)
        GUICtrlSetBkColor(-1, 0x00ff00)
    Next
    ExitLoop
WEnd
GUIDelete($ui)
Exit

[iamtheky]

Drawing Vertical Progress (somewhat simply) - in case 90 degrees is what you meant by flip it.

expandcollapse popup

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


    $Top = 0
    $Bottom = @DesktopHeight
    $MAX = 50
    $Blocks = 50
    $each  = 50

For $i = 1 to $Blocks
$Rcolor = random (0x000000 , 0xFFFFFF)
    For $y = $Top To $Top + 40
For $x = 0 To $each



    _PixelSetColor ($x , $y , $Rcolor)

Next
Next

$Top = $Top + 50

sleep (500)   ; where an action would go

If $Top > @DesktopHeight Then
$i = 1
$Top = 0
Endif
Next


Func _PixelSetColor($XCoord, $YCoord, $Color)
    Local $dc = DllCall("user32.dll", "int", "GetDC", "hwnd", 0)
    If Not IsArray($dc) Then Return -1
    DllCall("gdi32.dll", "long", "SetPixel", "long", $dc[0], "long", $XCoord, "long", $YCoord, "long", _
            "0x" & StringRegExpReplace(hex($Color,6), "(..)(..)(..)", "\3\2\1")) ; Change to 0xBBGGRR hex colour format.
    DllCall("user32.dll", "int", "ReleaseDC", "hwnd", 0, "hwnd", $dc[0])
EndFunc ;==>_PixelSetColor

[Malkey]

Try this.

Local $ui = GUICreate('test', 100, 160, -1, -1)

Local $pb = GUICtrlCreateProgress(30, 20, 10, 120, BitOR(0x04, 0x01))
GUICtrlSetBkColor($pb, 0x000080)
GUICtrlSetColor($pb, 0xD4D0C8)

Local $pb1 = GUICtrlCreateProgress(70, 20, 10, 120, 0x04)

GUISetState(@SW_SHOW, $ui)

While 1
    For $i = 1 To 100
        GUICtrlSetData($pb, $i)
        GUICtrlSetData($pb1, 100 - $i)
        Sleep(50)
    Next
    For $i = 1 To 100
        GUICtrlSetData($pb, 100 - $i)
        GUICtrlSetData($pb1, $i)
        Sleep(50)
    Next
    ExitLoop
WEnd

[Melba23]

Malkey,

Very clever.

M23

[JohnOne]

The ctrl and ctrl background colors wont set for me, they just look like normal progress bars with normal orientation.

[Yashied]

Only for a themeable windows.

expandcollapse popup

#Include <WinAPIEx.au3>
#Include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global $hForm, $Pic

$hForm = GUICreate('MyGUI', 200, 300)
$Pic = GUICtrlCreatePic('', 91, 20, 18, 260)
_SetHProgressBackwards($Pic, 0)
GUISetState()

While 1
    For $i = 0 To 100
        _SetHProgressBackwards($Pic, $i)
        Sleep(20)
    Next
    For $i = 100 To 0 Step -1
        _SetHProgressBackwards($Pic, $i)
        Sleep(20)
    Next
WEnd

Func _SetHProgressBackwards($CtrlID, $iPercent)

    Local $hWnd, $hDC, $hMemDC, $hSv, $hObj, $hBitmap, $hTheme, $tRect, $tClip, $Width, $Height

    $hWnd = GUICtrlGetHandle($CtrlID)
    If Not $hWnd Then
        Return 0
    EndIf
    $Width = _WinAPI_GetClientWidth($hWnd)
    $Height = _WinAPI_GetClientHeight($hWnd)
    $hDC = _WinAPI_GetDC($hWnd)
    $hMemDC = _WinAPI_CreateCompatibleDC($hDC)
    $hBitmap = _WinAPI_CreateSolidBitmap(0, _WinAPI_GetSysColor($COLOR_3DFACE), $Width, $Height, 0)
    $hSv = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $hTheme = _WinAPI_OpenThemeData($hWnd, 'Progress')
    $tRect = _WinAPI_CreateRectEx(0, 0, $Width, $Height)
    _WinAPI_DrawThemeBackground($hTheme, 2, 0, $hMemDC, $tRect)
    $tRect = _WinAPI_CreateRectEx(0, 0, $Width, $Height * $iPercent / 100)
    $tClip = _WinAPI_CreateRectEx(1, 1, $Width - 2, $Height - 2)
    _WinAPI_DrawThemeBackground($hTheme, 6, 1, $hMemDC, $tRect, $tClip)
    _WinAPI_CloseThemeData($hTheme)
    _WinAPI_ReleaseDC($hWnd, $hDC)
    _WinAPI_SelectObject($hMemDC, $hSv)
    _WinAPI_DeleteDC($hMemDC)
    _WinAPI_DeleteObject(_SendMessage($hWnd, 0x0172, 0, $hBitmap))
    $hObj = _SendMessage($hWnd, 0x0173)
    If $hObj <> $hBitmap Then
        _WinAPI_DeleteObject($hBitmap)
    EndIf
    Return 1
EndFunc   ;==>_SetHProgressBackwards

Edited November 5, 2010 by Yashied

[JohnOne]

Now that is exactly what the Op was after.

Superb that Yashied.

[UEZ]

Here my try:

Local $hGUI = GUICreate("Test", 100, 500)
Local $bg_p = GUICtrlCreateProgress(40, 0, 20, 500, 0x04)
GUICtrlSetData($bg_p, 100)
Local $fg_p = GUICtrlCreateProgress(40, 0, 20, 500, 0x04)
GUICtrlSetData($fg_p, 0)
GUISetState()

For $i = 0 To 501
    GUICtrlSetPos($fg_p, 40, $i)
    Sleep(20)
Next

Do
Until GUIGetMsg() = -3

I know it is flickering but maybe it can be fixed with styles...

@Yashied: very cool solution from your post #15!

Br,

UEZ

Edited November 5, 2010 by UEZ

[JoHanatCent]

Me 2

Local $ui = GUICreate('test', 100, 160, -1, -1, 0x80880000)
Local $pb = GUICtrlCreateLabel("  ", 43, 20, 15, 1, 0x1000)
GUICtrlSetBkColor(-1, 0x00ff00)
GUISetState(@SW_SHOW, $ui)
While 1
    For $i = 1 To 100
        GUICtrlSetData($pb, $i)
        GUICtrlSetPos($pb, 43, 20, 15, 1 + $i)
        Sleep(50)
    Next
    GUICtrlSetData($pb, "Ok!")
    Sleep(250)
    ExitLoop
WEnd
GUIDelete($ui)
Exit

[ripdad]

Whoa .. you guys have been busy!

I appreciate all your efforts -- and I have checked every one of them. Very nice work indeed!

But they still lack the speed (1ms) of the native progress bar. And I have to call that twice!

It's in a very tight loop. If it were not for that, perhaps one of your solutions would work.

I imagine someone will get use of them. It's was a good exercise. Thanks again for your time.

[iamtheky]

What do you mean by "lack the speed" - response time from call?

Heres a vertical bar using Taietel's _Gradient()

expandcollapse popup

#include <WindowsConstants.au3>


$gui = GUICreate("", 40, @DesktopHeight, 0 , 0 , $WS_POPUPWINDOW)
GUISetBkColor (0x000000, $gui)
GUISetState(@SW_SHOW)

;   Example
_Gradient(0xFF0000, 0x00ff00,40,@DesktopHeight,0,0,1)

While 1

    Sleep(10)
    Switch GUIGetMsg()
        Case -3
            Exit
    EndSwitch
WEnd


; #FUNCTION# ====================================================================================================
; Name...........:  _Gradient
; Description....:  Create gradient between two colors
; Syntax.........:  _Gradient($lColor1, $lColor2, $iW=100, $iH=20, $iX=0, $iY=0, $iDirection=0)
; Parameters.....:  $lColor1 - First color to begin with
;                   $lColor2 - Second color
;                   $iW - width of the area, [Optional]
;                   $iH - height of the area, [Optional]
;                   $iX - position from left, [Optional]
;                   $iY - position from top, [Optional]
;                   $iY - direction to fill the gradient, [Optional]
;                           0 - vertical fill
;                           1 - horizontal fill
;
; Return values..:  none
;
; Author.........:  taietel
; Reference.....:   http://www.tannerhelland.com/
; ===============================================================================================================
Func _Gradient($lColor1, $lColor2, $iW=100, $iH=20, $iX=0, $iY=0, $iDirection=0)
    Local $m, $Ri,$Rf,$Rs,$Gi,$Gf,$Gs,$Bi,$Bf,$Bs
    Switch $iDirection
        Case 0
            $m = $iW
        Case 1
            $m = $iH
    EndSwitch

    $Ri = Mod($lColor1,256)
    $Gi = BitAND($lColor1/256,255)
    $Bi = BitAND($lColor1/65536,255)

    $Rf = Mod($lColor2,256)
    $Gf = BitAND($lColor2/256,255)
    $Bf = BitAND($lColor2/65536,255)

    $Rs = Abs($Ri - $Rf)/$m
    $Gs = Abs($Gi - $Gf)/$m
    $Bs = Abs($Bi - $Bf)/$m

    If $Rf < $Ri Then $Rs = -$Rs
    If $Gf < $Gi Then $Gs = -$Gs
    If $Bf < $Bi Then $Bs = -$Bs

    For $i = 0 To $m
        $Rf = $Ri + $Rs * $i
        $Gf = $Gi + $Gs * $i
        $Bf = $Bi + $Bs * $i
        GUICtrlCreateLabel(" ", $iX+$i-$i*$iDirection, $iY + $i*$iDirection, 2+$iDirection*$iW, 2+(1-$iDirection)*$iH)
        GUICtrlSetBkColor(-1, "0x"&Hex($Bf,2) & Hex($Gf,2) & Hex($Rf,2))
;~      sleep(10) ; running items in this loop
    Next
EndFunc

Edited November 6, 2010 by iamtheky