guictrlsetdata flickering

[GodForsakenSoul]

a snippet of my code.

Sleep(20)
GUICtrlSetData($mg_ctrl_TimeLabel,"Welcome. Today is the "&@MDAY&"."&@MON&"."&@YEAR&". The time is "&@HOUR&":"&@MIN&":"&@SEC)

the problem is that it flickers. quite noticeably too. right now i'm trying to set the sleep value to something that is both fast to react to buttons being pressed and not to fast so that the message won't flicker as it updates. i've looked in the obvious (to me) parts of the help file for a solution and have yet to find one.

any suggestions?

[Realm]

Hello GodForsakenSoul,

I noticed that the smallest increment of time to be displayed is a second, have you tried to increase the Sleep to 1000, maybe even 250, should help to reduce or get rid of the flicker, the flicker is from updating 50x per second at a sleep rate of 20ms

Realm

Edit: 250ms should not be a large pause while waiting for a button to be pressed either. thats 4 checks per second.

Edited October 19, 2010 by Realm

[bogQ]

#include <GUIConstantsEx.au3>
GUICreate("My GUI")
$sec = @SEC
$mg_ctrl_TimeLabel = GUICtrlCreateLabel("", 10, 30, "500")
GUISetState()
Do
    $msg = GUIGetMsg()
    If $sec <> @SEC Then
        $sec = @SEC
        GUICtrlSetData($mg_ctrl_TimeLabel,"Welcome. Today is the "&@MDAY&"."&@MON&"."&@YEAR&". The time is "&@HOUR&":"&@MIN&":"&@SEC)
    EndIf
Until $msg = $GUI_EVENT_CLOSE

Edited October 19, 2010 by bogQ

[Melba23]

GodForsakenSoul,

The normal trick to prevent this is to change the data only when it needs changing. In this case the @SEC is changing the most rapidly so I would suggest something along these lines (untested):

$iSec = 0
; Start Loop

If @SEC <> $iSec Then
    $iSec = @SEC
    GUICtrlSetData(.....)
EndIf

; End Loop

Now you only update when @SEC changes once per second and the flickering should stop.

A similar trick can be used if you have to change the state of a control - just check the current state and only change state if required.

M23

[GodForsakenSoul]

as usual, melba comes up with an ingenius solution that was sitting RIGHT THERE under my nose...

i'm not sure if i love you or hate you... lol.

[Melba23]

GodForsakenSoul,

bogQ suggested it as well - so you have a double problem!

M23

[Mat]

As a generic rule I use:

If GUICtrlRead($Ctrl) <> $Data Then GUICtrlSetData($Ctrl, $Data)

That means that it won't set the content unless it is different, so no flicker. In this case Melba's right as usual though

[UEZ]

Here another method:

#include <GUIConstantsEx.au3>
GUICreate("My GUI")
$mg_ctrl_TimeLabel = GUICtrlCreateLabel("", 10, 30, "500")
GUISetState()

Update()
AdlibRegister("Update", 500)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

AdlibUnRegister("Update")
Exit

Func Update()
    GUICtrlSetData($mg_ctrl_TimeLabel,"Welcome. Today is the "&@MDAY&"."&@MON&"."&@YEAR&". The time is "&@HOUR&":"&@MIN&":"&@SEC)
EndFunc

But it still flickers sometimes -> bogQ example is much better.

Br,

UEZ

Edited October 19, 2010 by UEZ