[SOLVED] Creating a console

[engjcowi]

Hi guys

Firstly i apologise if this is a dumb question but its late and ive been wrecking my brain. Can anyone point me in the direction to creat an output console so th euser can see exactly whats goin on. I dont know if anyone remembers dvd decrypter but that had an output console that displayed the info on where the program was upto and what is was doing.

It just needs to be small but scrollable once completed.

Thanks

Jamie

Edited October 25, 2010 by engjcowi

[enaiman]

EditBox

[engjcowi]

Hi enaiman

Thats for the suggestion. Ive tried creating a form and puttin in an edit box called $comconsole and then used the command

GUICtrlSetData($comconsole, "this has updated")

to update the information going to the edit box. My problem is that when i use the same command up to add further information such as using a command button it just overwrites whats already there.

is there anyway i can tell it to keep whats there and add to a new line only please?

[BrewManNH]

Try this - Untested:

GUICtrlSetData($comconsole, GUICtrlRead($comconsole) & "this has updated")

[Richard Robertson]

DllCall("kernel32", "int", "AllocConsole")

[jaberwacky]

is there anyway i can tell it to keep whats there and add to a new line only please?

I use this:

GUICtrlSetData($comconsole, "this has updated", ' ')

[BrewManNH]

Nice tip jaberwocky, I've never used the default value parameter so I had forgotten about how it works in an edit control.

[engjcowi]

Jaberwocky thanks very much i didnt see that myself lol. All is now right with thte world and working and ive included an example below in case anyone would like to see.

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("Form2", 658, 386, 302, 218)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form2Close")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "Form2Minimize")
GUISetOnEvent($GUI_EVENT_MAXIMIZE, "Form2Maximize")
GUISetOnEvent($GUI_EVENT_RESTORE, "Form2Restore")
$Edit1 = GUICtrlCreateEdit("", 24, 48, 353, 217)
GUICtrlSetData(-1, "Edit1" & @CRLF)
GUICtrlSetOnEvent(-1, "Edit1Change")
$Button1 = GUICtrlCreateButton("Button1", 160, 304, 153, 41, 0)
GUICtrlSetOnEvent(-1, "Button1Click")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1

    Sleep(100)
WEnd

Func Button1Click()
GUICtrlSetData($edit1, "this has updated" & @CRLF, ' ')


EndFunc
Func Edit1Change()

EndFunc
Func Form2Close()
exit
EndFunc
Func Form2Maximize()

EndFunc
Func Form2Minimize()

EndFunc
Func Form2Restore()

EndFunc

[engjcowi]

Hi

sorry to be a pain. Ive created the following program using the bits of code above to run mkisofs. Ther is 2 attempts below, 1 is readt to run, the other is blocked by #cs and #ce so just delete the other whilw wend loop then use the commented out 1 to try. The problem is that i use ctupdate in the directory which has lots of lists with long fielnames and after a very short period the the output just stops (see attached pic) but the program continues behind the scenes. If i remove the folder containing the files then it reads the percentage fine. Is there a limit to the information a edit box can contain?

Hope someone can help

Thanks

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("Form2", 623, 451, 323, 153)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form2Close")

$Button1 = GUICtrlCreateButton("Exit", 176, 360, 265, 73, 0)
GUICtrlSetOnEvent(-1, "Button1Click")
$Comconsole = GUICtrlCreateEdit("Console", 56, 32, 529, 297, $ES_AUTOVSCROLL + $WS_VSCROLL)
GUICtrlSetData(-1, "Comconsole")
GUICtrlSetOnEvent(-1, "ComconsoleChange")
$Label1 = GUICtrlCreateLabel("ISO CREATION ", 264, 8, 83, 17)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

FileChangeDir(@ScriptDir & "\files\")


#cs
$pid = Run('mkisofs.exe -l -J -r -V "APHC" -o "' & @DesktopDir & '\APHC.iso" ' & '"' & @ScriptDir & '"', "", @SW_hide, 0x8) ; 0x8 = $STDERR_MERGED (StdOutRead receives Stdout and stderr)
$sOutput = ''
While 1

    Sleep(50)
    $sRead = StdoutRead($pid)
    If @error <> 0 Then ExitLoop
    $sOutput &= $sRead
    ;oolTip($sOutput)
    GUICtrlSetData($Comconsole, $sOutput, ' ')
WEnd
StdioClose($pid)
ToolTip("")
MsgBox(0, 'Finished', $sOutput)

#ce





$foo = Run('mkisofs.exe -l -J -r -V "APHC" -o"' & @DesktopDir & '\APHC.iso" ' & '"' & @ScriptDir & '"', "", @SW_Hide, $STDERR_CHILD + $STDOUT_CHILD)

While 1
    $line = StderrRead($foo)
    If @error Then ExitLoop
        $message = ""
    $message = $line
    GUICtrlSetData($Comconsole, $message, ' ')
Wend
MsgBox(0, 'ISO Created', $message)
StdioClose($line)





Func Button1Click()
ProcessClose("mkisofs.exe")
exit
EndFunc
Func ComconsoleChange()

EndFunc
Func Form2Close()
ProcessClose("mkisofs.exe")
exit
EndFunc

[enaiman]

Add this line, after you create the edit box:

GUICtrlSetLimit(-1, 9999999)

@RichardRobertson

How about an UDF around that?

Edited October 24, 2010 by enaiman

[Richard Robertson]

Why do you need a UDF? It's a single line. After you allocate it, you just use ConsoleWrite to send data to it.

[engjcowi]

@Enaiman

Thanks thats done the trick.

Richard Robertson - i never knew that either thanks

[enaiman]

@RichardRobertson

Why do you need a UDF? It's a single line. After you allocate it, you just use ConsoleWrite to send data to it.

So simple? - wow, I do need to have a closer look at that

Thanks alot.

[Ascend4nt]

Hmm, I too was curious about this one-API-call-does-it-all, so I tested it out. But alas, it doesn't work with ConsoleWrite.

Here's the way I got it to work for me:

DllCall("kernel32.dll","bool","AllocConsole")
$hConsole=DllCall("kernel32.dll","handle","GetStdHandle","int",-11)
ConsoleWrite("Console handle:"&$hConsole[0]&", Error:"&@error&@CRLF)
$aRet=DllCall("kernel32.dll","bool","WriteConsoleW","handle",$hConsole[0],"wstr","Testing123","dword",10,"dword*",0,"ptr",0)
MsgBox(0,"see any consoles?","look harder!")

Note that WriteConsole must be called with a handle retrieved through GetStdHandle, and the program must not be run from SciTE (otherwise you won't get a valid handle).

[enaiman]

@Ascend4nt

Thank you very much for your input.

[Richard Robertson]

Well I've never tried using the console with AutoIt. I just knew the function.

[bs27975]

On 10/25/2010 at 6:37 PM, Ascend4nt said:

 

DllCall("kernel32.dll","bool","AllocConsole")
$hConsole=DllCall("kernel32.dll","handle","GetStdHandle","int",-11)
ConsoleWrite("Console handle:"&$hConsole[0]&", Error:"&@error&@CRLF)
$aRet=DllCall("kernel32.dll","bool","WriteConsoleW","handle",$hConsole[0],"wstr","Testing123","dword",10,"dword*",0,"ptr",0)
MsgBox(0,"see any consoles?","look harder!")

 

Nice! Thank you. Cut, Paste, Done.

Except ...
How to know when (not) running running within SciTE, to know to (not) call this?

i.e. Make console output / debugging establishment fire and forget regardless of the environment of the time.
- permitting one to just ConsoleWrite "away" trusting it will always be displayed appropriately.

[jchd]

Easy:

Global $CW = @Compiled ? _ConsoleWrite : ConsoleWrite

Func _ConsoleWrite(ByRef $s)
    Local Static $hCon = __ConsoleInit()
    DllCall("kernel32.dll", "bool", "WriteConsoleW", "handle", $hCon, "wstr", $s, "dword", StringLen($s), "dword*", 0, "ptr", 0)
    Return
EndFunc

Func __ConsoleInit()
    DllCall("kernel32.dll", "bool", "AllocConsole")
    Return DllCall("kernel32.dll", "handle", "GetStdHandle", "int", -11)
EndFunc

For $i = 1 to 10
    $cw($i & " - Hello world!" & @LF)
Next

Just invoke $CW($string_to_be_displayed) when needed.