StringSplit $CmdLineRaw

[guinness]

I found _ParseCMDLine() by Prog@ndy which is great if you are manually adding $CmdLine parameters like -p "FILENAME" but it doesn't work if you are passing a "RAW COMMANDLINE" of files that have been dropped on the EXE file.

So how do I split this data into an Array when blank space and '""' are contained in the string? Thanks for the advice, I have searched the forum with very little discussion on $CmdLineRaw.

$Example = 'C:\Users\Test\Desktop\PROGRAMNAME\settings.ini "C:\Users\Test\Desktop\PROGRAMNAME\PROGRAMNAME TESTING.au3" "C:\Users\Test\Desktop\PROGRAMNAME\PROGRAMNAME V1.0.au3" "C:\Users\Test\Desktop\PROGRAMNAME\Script Changes.txt"'

Edited October 18, 2010 by guinness

[Ascend4nt]

This is the PCRE I use for separating parameters.

There is a look-behind and look-ahead assertion to prevent grabbing quotes, while also allowing for cases where there are empty quotes (""):

Local $aParsedArray=StringRegExp($sStringToParse,'((?<=\s"|^")[^"]+(?=")|[^\s"]+)',3)

The only thing I'd do beforehand is expand any environment strings like %windir%. All you'd need for that is to just set the "ExpandEnvStrings" option, assign the string to itself (looks dumb, but accomplishes the needed expansion), then reset the option.

[guinness]

Another one to put in the Functions directory Thanks for helping. Plus cheers for the heads up on "ExpandEnvStrings", I tend to use _WinAPI_ExpandEnvironmentStrings() in my programs.

I am trying to make my example of WM_COPYDATA a little more simplistic!

Edited October 18, 2010 by guinness

[Juvigy]

Shouldnt $CmdLine array contain what you need?

[guinness]

Not if you're using WM_COPYDATA, which for some reason can't send Arrays! Before I was doing the following (See Below) in the WM_COPYDATA Function, but not very efficient, as the second process has to do all the work, whereas now the first instance can parse the Commandline data.

If IsArray($CmdLine) Then
    Local $TEMPmi_String = ""
    For $A = 1 To $CmdLine[0]
        $TEMPmi_String &= $CmdLine[$A] & "|"
    Next
    $CmdLineRaw = StringTrimRight($TEMPmi_String, 1)
EndIf

Edited October 18, 2010 by guinness

[guinness]

Thanks to Ascend4nt for the StringRegExp() syntax and the Authors of WinAPI.au3 for the "ExpandEnvironmentStringsW" API Function.

Example use of Function:

#include <Array.au3>
#include <WinAPI.au3>
#include <WinAPIShPath.au3>

Local $sCmdLine = '%WINDIR%\PROGRAMNAME\settings.ini "C:\Users\Test\Desktop\PROGRAMNAME\PROGRAMNAME TESTING.au3" "C:\Users\Test\Desktop\PROGRAMNAME\PROGRAMNAME V1.0.au3" "C:\Users\Test\Desktop\PROGRAMNAME\Script Changes.txt"'
Local $aArray = _CmdLineRaw($sCmdLine)
_ArrayDisplay($aArray, '_CmdLineRaw()')

$aArray = _WinAPI_CommandLineToArgv(_WinAPI_ExpandEnvironmentStrings($sCmdLine)) ; Using Win32 API calls.
_ArrayDisplay($aArray, '_WinAPI_CommandLineToArgv()')

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
; #FUNCTION# ====================================================================================================================
; Name ..........: _CmdLineRaw
; Description ...: Creates an array of a $CmdLineRaw string or similar.
; Syntax ........: _CmdLineRaw($sString)
; Parameters ....: $sString             - $CmdLineRaw-like string.
; Return values .: Success - An array, by default the first element ($aArray[0]) contains the number of strings returned, the remaining elements ($aArray[1], $aArray[n], etc.) contain the seperated strings.
;                  Failure - An array with the zeroth element set to 0.
; Author ........: guinness
; Modified ......:
; Remarks .......: Ascend4nt who designed the regular expression.
; Related .......: _StringParseParameters(): http://www.autoitscript.com/forum/topic/88995-stringparseparameters/
; Example .......: No
; ===============================================================================================================================
Func _CmdLineRaw($sString)
    Local $aReturn = StringRegExp('"' & @ScriptFullPath & '"' & ' ' & _WinAPI_ExpandEnvironmentStrings($sString), '((?<=\s"|^")[^"]+(?=")|[^\s"]+)', $STR_REGEXPARRAYGLOBALMATCH)
    $aReturn[0] = UBound($aReturn, 1) - 1
    Return $aReturn
EndFunc   ;==>_CmdLineRaw

Edited July 20, 2014 by guinness

[Gigglestick]

When running that last example (compiled and dropping a couple dozen files/folders on it), and adding an _ArrayDisplay($CmdLine) after yours, the only difference I see is that yours is a zero-based array and the built in $CmdLine is 1-based with a count.

[guinness]

The reason why I needed this was because I couldn't send an Array using WM_COPYDATA and therefore used to do it with $CmdLine >> which is of course slow, so sending $CmdLineRaw and then parsing seemed a more logical solution.

Edited May 5, 2011 by guinness

[Gigglestick]

I get that you can't pass an array using WM_COPYDATA, but you've created a function that turns a command-line formatted string into an array. Basically, you've made a function that does the same as the built in $CmdLine, but allows the input to be something other than the actual command line given to the script. That's great if you plan on creating your own list of files in the same format as a command line and then converting it to an array, but doesn't help you at all in the goal of passing a bar ("|") delimited string to WM_COPYDATA. You'll still have to convert the output of your function to a string.

[guinness]

You've lost me sorry! How would you do it when it comes to WM_COPYDATA? Because I just send $CmdLineRaw (which is normally a list of just files) and then use _CmdLineRaw()

If you are talking about the Example I gave ($CmdLineRaw = '%WINDIR%\PROGRAMNAME\settings.ini "C:\Users\Test\Desktop\PROGRAMNAME\PROGRAMNAME TESTING.au3" "C:\Users\Test\Desktop\PROGRAMNAME\PROGRAMNAME V1.0.au3" "C:\Users\Test\Desktop\PROGRAMNAME\Script Changes.txt"') then I just used this as an Example of course for standard use I would use $CmdLine and then use a For...Loop.

I should probably tidy up this post >>

Edited May 6, 2011 by guinness

[Gigglestick]

I'm just saying your _CmdLineRaw() function still spits out an array, which is not what you seem to need for WM_COPYDATA. You've recreated the built-in $CmdLine functionality.

You still have to loop through an array to create whatever you need to pass to WM_COPYDATA, whether it's using the built in $CmdLine or your own array... unless I've completely missed the point, which is not altogether impossible. Don't get me wrong, it's a nice function, and I may someday find a use for it in my own scripts, but I don't think it accomplishes what you're asking in relation to WM_COPYDATA.

Edited May 6, 2011 by Gigglestick

[guinness]

I have updated the Example >> you can see I have removed some code. I hope this makes sense now

Edited May 6, 2011 by guinness

[Gigglestick]

You were trying to recreate the $CmdLine funcionality to process the $CmdLineRaw passed to another instance of the script.

Yep. Got it. Nicely done.