determing state of capslock, scroll, and numlock

[jftuga]

I searched the forums but did not come up with anything too quickly. How can I tell if the caps, scroll, and/or the num locks keys are on or off?

Thanks,

-John

[Helge]

If I remember correctly it was possible to retrive the state of at least 2 of

the 'locks in AutoIt v2. However I haven't seen this been done in v3.

It's strange really...

It might be possible with a DLLCall though..

Well, my guessing isn't exactly helping you, so maybe someone

else can do that..? Anyone ?

[GaryFrost]

Return of 0 is off, 1 is on

Global Const $VK_NUMLOCK = 0x90
Global Const $VK_SCROLL = 0x91
Global Const $VK_CAPITAL = 0x14

ConsoleWrite(_GetNumLock() & @LF)
ConsoleWrite(_GetScrollLock() & @LF)
ConsoleWrite(_GetCaps() & @LF)

Func _GetNumLock()
    Local $ret
    $ret = DllCall("user32.dll","long","GetKeyState","long",$VK_NUMLOCK)
    Return $ret[0]
EndFunc

Func _GetScrollLock()
    Local $ret
    $ret = DllCall("user32.dll","long","GetKeyState","long",$VK_SCROLL)
    Return $ret[0]
EndFunc

Func _GetCaps()
    Local $ret
    $ret = DllCall("user32.dll","long","GetKeyState","long",$VK_CAPITAL)
    Return $ret[0]
EndFunc

Edited June 1, 2005 by gafrost

[GaryFrost]

Or could be 1 function that returns an array of the 3 key states

Example:

$KeyStates = _GetKeyState()
For $i = 1 to $KeyStates[0]
    ConsoleWrite($KeyStates[$i] & @LF)
Next

Func _GetKeyState()
    Const $VK_NUMLOCK = 0x90
    Const $VK_SCROLL = 0x91
    Const $VK_CAPITAL = 0x14
    Local $ret, $a_keystate[4]
    $a_keystate[0] = 3
    $ret = DllCall("user32.dll", "long", "GetKeyState", "long", $VK_NUMLOCK)
    $a_keystate[1] = $ret[0]
    $ret = DllCall("user32.dll", "long", "GetKeyState", "long", $VK_SCROLL)
    $a_keystate[2] = $ret[0]
    $ret = DllCall("user32.dll", "long", "GetKeyState", "long", $VK_CAPITAL)
    $a_keystate[3] = $ret[0]
    Return $a_keystate
EndFunc  ;==>_GetKeyState

[jftuga]

gafrost,

Thanks. I could not have figured that out on my own!

How does someone go about learning about DllCall and user32.dll, (or other dlls) etc?

EDIT:

I just tried both versions of the code and got nothing back for the return values. I tried 3.1.1.38 and the .41 betas.

Any ideas?

-John

Edited June 1, 2005 by jftuga

[GaryFrost]

Do you use SciTe Editor?

If not change the ConsoleWrite to MsgBox statements

for example:

$KeyStates = _GetKeyState()
For $i = 1 to $KeyStates[0]
    MsgBox(0,"Key State",$KeyStates[$i])
Next

Func _GetKeyState()
    Const $VK_NUMLOCK = 0x90
    Const $VK_SCROLL = 0x91
    Const $VK_CAPITAL = 0x14
    Local $ret, $a_keystate[4]
    $a_keystate[0] = 3
    $ret = DllCall("user32.dll", "long", "GetKeyState", "long", $VK_NUMLOCK)
    $a_keystate[1] = $ret[0]
    $ret = DllCall("user32.dll", "long", "GetKeyState", "long", $VK_SCROLL)
    $a_keystate[2] = $ret[0]
    $ret = DllCall("user32.dll", "long", "GetKeyState", "long", $VK_CAPITAL)
    $a_keystate[3] = $ret[0]
    Return $a_keystate
EndFunc ;==>_GetKeyState

Edited June 1, 2005 by gafrost

[jftuga]

I tried this already (MsgBox). The problem is the $ret returns nothing. It does not even return a 0 or a 1. The MsgBox output is empty.

-John

[GaryFrost]

using the loop with consolewrite and using the release version of autoit

>Running: (3.1.1.1):C:\Program Files\AutoIt3\autoit3.exe "C:\Documents and Settings\Gary\My Documents\test5.au3" 

1

0

0

>AutoIT3.exe ended.

>Exit code: 0    Time: 1.077

Also running WinXp SP2

Info from MSDN

Function Information

Minimum DLL Version user32.dll

Header Declared in Winuser.h, include Windows.h

Import library User32.lib

Minimum operating systems Windows 95, Windows NT 3.1

you say $ret isn't returning anything, if you just $ret instead of $ret[0] then you would be correct. Edited June 1, 2005 by gafrost

[Vinzent]

for my self i prefer this code:

Global Const $VK_NUMLOCK = 0x90
Global Const $VK_SCROLL = 0x91
Global Const $VK_CAPITAL = 0x14


Func _LockKeyGetState($KeyHex)
    Local $ret
    $ret = DllCall("user32.dll","long","GetKeyState","long",$KeyHex)
    Return $ret[0]
EndFunc

e. g. numlock:

_LockKeyGetState($VK_NUMLOCK)

or

_LockKeyGetState(0x90)

 

It will return 1 if activated and 0 if not

[iamtheky]

almost 9 years old, it is not record setting but still...

[Melba23]

Vinzent,

Welcome to the AutoIt forum.

Please do not necro-post like this again. We discourage it because Autoit has changed so much since this thread was started that the old code seldom runs any more.

M23