Close program in icon tray

[Tstudent]

I have a windows application that when i click on "minimize" is reduced to icon tray (lower right corner).

What i want is to close that program. But i want to close it normally (the same as click on X button), not brutally kill process.

Is it possible with AutoIt?

I could code a double left mouse click on the program's icon in the tray and after use winclose(title). The problem is that the position of the icon (in the icon tray) isn't always the same.

Is there a more elegant and effective solution?

Thank you

[Melba23]

Tstudent,

This code will right-click on an icon in the systray (notification area) if you add a part of the tooltip text for the specific app:

expandcollapse popup

#Include <GuiToolBar.au3>

Global $hSysTray_Handle, $iSystray_ButtonNumber

Global $sToolTipTitle = "" ; <<<<<<<<<<<<<<<< Enter some tooltip text for the icon you want here

$iSystray_ButtonNumber = Get_Systray_Index($sToolTipTitle)

If $iSystray_ButtonNumber = 0 Then
    MsgBox(16, "Error", "Icon not found in system tray")
    Exit
Else
    Sleep(500)
    _GUICtrlToolbar_ClickButton($hSysTray_Handle, $iSystray_ButtonNumber, "right")
EndIf

Exit

;............

Func Get_Systray_Index($sToolTipTitle)

    ; Find systray handle
    $hSysTray_Handle = ControlGetHandle('[Class:Shell_TrayWnd]', '', '[Class:ToolbarWindow32;Instance:1]')
    If @error Then
        MsgBox(16, "Error", "System tray not found")
        Exit
    EndIf

    ; Get systray item count
    Local $iSystray_ButCount = _GUICtrlToolbar_ButtonCount($hSysTray_Handle)
    If $iSystray_ButCount = 0 Then
        MsgBox(16, "Error", "No items found in system tray")
        Exit
    EndIf

    ; Look for wanted tooltip
    For $iSystray_ButtonNumber = 0 To $iSystray_ButCount - 1
        If StringInStr(_GUICtrlToolbar_GetButtonText($hSysTray_Handle, $iSystray_ButtonNumber), $sToolTipTitle) > 0 Then ExitLoop
    Next

    If $iSystray_ButtonNumber = $iSystray_ButCount Then
        Return 0 ; Not found
    Else
        Return $iSystray_ButtonNumber ; Found
    EndIf

EndFunc

It should not be too hard to adapt for your needs. I hope it helps.

M23

[AdmiralAlkex]

Have you tried WinClose or ProcessClose?

[Tstudent]

Winclose doesn't work because it require a window title that in this case doesn't exist.

Processclose is too brutal and doesn't close correctly a program.

I have found a solution utilizing the code of Melba.

Thank you