_RegJump()

[Yashied]

This function opens a registry editor (regedit.exe) in the specified hive ($sKey). Enjoy!

expandcollapse popup

_RegJump('HKCR\AutoIt3Script')

Func _RegJump($sKey)

    Local $Root, $Text = StringSplit($sKey, '\', 2)

    If IsArray($Text) Then
        $Text = $Text[0]
    Else
        $Text = $sKey
    EndIf
    Switch $Text
        Case 'HKEY_CLASSES_ROOT', 'HKEY_CURRENT_USER', 'HKEY_LOCAL_MACHINE', 'HKEY_USERS', 'HKEY_CURRENT_CONFIG'
            $Root = $Text
        Case 'HKCR'
            $Root = 'HKEY_CLASSES_ROOT'
        Case 'HKCU'
            $Root = 'HKEY_CURRENT_USER'
        Case 'HKLM'
            $Root = 'HKEY_LOCAL_MACHINE'
        Case 'HKU'
            $Root = 'HKEY_USERS'
        Case 'HKCC'
            $Root = 'HKEY_CURRENT_CONFIG'
        Case Else
            Return 0
    EndSwitch

    Local $Class = '[CLASS:RegEdit_RegEdit]'
    Local $Key = 'HKCU\Software\Microsoft\Windows\CurrentVersion\Applets\Regedit'
    Local $Delay = Opt('WinWaitDelay', 0)
    Local $Prev, $Result = 1

    If WinExists($Class) Then
        WinClose($Class)
        If Not WinWaitClose($Class, '', 5) Then
            $Result = 0
        EndIf
    EndIf
    If $Result Then
        $Prev = RegRead($Key, 'Lastkey')
        If @error Then
            $Prev = 0
        EndIf
        If Not RegWrite($Key, 'Lastkey', 'REG_SZ', StringReplace($sKey, $Text, $Root, 1)) Then
            $Result = 0
        Else
            If Not Run('regedit.exe') Then
                $Result = 0
                If IsString($Prev) Then
                    RegWrite($Key, 'Lastkey', 'REG_SZ', $Prev)
                EndIf
            EndIf
        EndIf
    EndIf
    Opt('WinWaitDelay', $Delay)
    Return $Result
EndFunc   ;==>_RegJump

Edited December 22, 2013 by Yashied

[JScript]

@Yashied

Cool, I'll use on my WindowsXP LiveCD (CDLogon.au3)!!!

[Fire]

Before i used regjump utlity from Sysinternals for this tasks.But now no need use it! Really Great!

Thank you very much Yashied.

+5 from me for Great Job.

Thank you.

Edited August 1, 2010 by Fire

[Digisoul]

Good Job Yashied.

[gcue]

yashield,

this works awesome..

any chance we can get it working when checking remote pc registry?

i tried changing that last key to a remote registry path - didnt work

i also opened regedit, chose a remote path manually, exited regedit... saw that the lastkey value was the remote registry path "hostname\hklm.."

but this didnt work. *sigh*

any ideas?

[ahmettben]

how to use the sample.?

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 401, 258, 192, 124)
$Button1 = GUICtrlCreateButton("HKLM-Run", 151, 192, 99, 25)
GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $Button1
   "HKLMSOFTWAREMicrosoftWindowsCurrentVersionRun";go key
         EndSwitch
WEnd

Edited April 3, 2012 by ahmettben

[JScript]

Hi,

Like this:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 401, 258, 192, 124)
$Button1 = GUICtrlCreateButton("HKLM-Run", 151, 192, 99, 25)
GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            _RegJump('HKLMSOFTWAREMicrosoftWindowsCurrentVersionRun')
    EndSwitch
WEnd

Regards,

João Carlos.

Edited April 3, 2012 by JScript

[ahmettben]

[guinness]

You have to include the function _RegJump into your script. Please read the Help file about Functions as this is a problem that can be easily solved by simply understanding of how AutoIt works.

Edited April 3, 2012 by guinness

[JScript]

You forgot to add the function in your script!

Regards,

João Carlos.

[ahmettben]

#include <RegJump.au3>

use such as udf

[guinness]

No, copy the function above and paste into your code. Seriously open that Help file and start learning about functions.

Like this:

; Your code

Func _RegJump()
; UDF code.
EndFunc

If it doesn't work this time post in your own thread as you're hijacking this example thread with questions that can be answered by reading the Help file.

Edited April 3, 2012 by guinness

[spf]

RegWrite('HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Applets\Regedit', 'LastKey', 'REG_SZ', '. . .')
run('regedit -m')

Edited May 5, 2013 by spf

[4EverMaAT]

On 8/2/2010 at 3:12 AM, Fire said:

Before i used regjump utlity from Sysinternals for this tasks.But now no need use it! Really Great!

Thank you very much Yashied.

+5 from me for Great Job.

Thank you.

But with regjump (SysInternals) there was a switch -c that allowed the program to automatically read clipboard contents and jump to that location.

Can this autoit script do (or be made to do) something similar?  I could run a shortcut that would then check clipboard contents for registry key and jump to it.

 

 

[Earthshine]

Why are you Necroposting? Start your own thread