Window Handle from PID

[SublimePorte]

I have a program which could have several instances open, all of which would appear the same through winmatch of titles/classes etc.

Is there a away to get a handle for the window when launching it via it's PID?

[Yoriz]

Yes FAQ # 24 How can I get a window handle when all I have is a PID?

[SublimePorte]

I ended up writing my own function and luckily I did...

That function in the FAQ doesn't seem to have a timeout, which could result in endless loops.

Also some processes seem to be attached to more than one window. Try running that function with notepad for instance, just hangs for me.

Here's what I came up with:

Func WinHandFromPID($pid, $winTitle="", $timeout=8)
    Local $secs = 0
    Do
        $wins = WinList($winTitle)
        For $i = 1 To UBound($wins)-1
            If (WinGetProcess($wins[$i][1]) == $pid) And (BitAND(WinGetState($wins[$i][1]), 2)) Then Return $wins[$i][1]
        Next
        Sleep(1000)
        $secs += 1
    Until $secs == $timeout
EndFunc

Only get's the handle for visible windows.

[PsaltyDS]

Only get's the handle for visible windows.

Only gets the handle for the FIRST visible window. As was pointed out earlier, a process can and often does have multiple windows. Try it this way:

#include <Array.au3>

; ...

; Returns an array of all Windows associated with a given process
Func WinHandFromPID($pid, $winTitle = "", $timeout = 8)
    Local $secs = TimerInit()
    Do
        $wins = WinList($winTitle)
        For $i = UBound($wins) - 1 To 1 Step -1
            If (WinGetProcess($wins[$i][1]) <> $pid) Or (BitAND(WinGetState($wins[$i][1]), 2) = 0) Then _ArrayDelete($wins, $i)
        Next
        $wins[0][0] = UBound($wins) - 1
        If $wins[0][0] Then Return SetError(0, 0, $wins)
        Sleep(1000)
    Until TimerDiff($secs) >= $timeout * 1000
    Return SetError(1, 0, $wins)
EndFunc   ;==>WinHandFromPID

Edited July 6, 2010 by PsaltyDS

[Earthshine]

oops, i was using this thread for another questions. sorry mods!

Edited December 19, 2017 by Earthshine

[jaja714]

On 7/5/2010 at 1:35 AM, Yoriz said:

Yes FAQ # 24 How can I get a window handle when all I have is a PID?

The winlist needs to be inside the do.  Then, you can get rid of the first sleep.