Extracting just the filename and extension from a full path?

[nf67]

Hi there,

is it possible to extract just the filename and extension from a full file path (including the file itself)?

If so, how is this done?

Thanks in advance

[water]

Yes, _Pathsplit does what you need: "Splits a path into the drive, directory, file name and file extension parts"

For the exact syntax please see the help file.

[Melba23]

nf67,

Or you can use these SREs from Malkey to get various parts of the path directly:

expandcollapse popup

Local $sFile = "C:\Program Files\Another Dir\AutoIt3\AutoIt3.chm"

; Drive letter -                                     Example returns     "C"
Local $sDrive = StringRegExpReplace($sFile, ":.*$", "")

; Full Path with backslash -                         Example returns     "C:\Program Files\Another Dir\AutoIt3\"
Local $sPath = StringRegExpReplace($sFile, "(^.*\\)(.*)", "\1")

; Full Path without backslash -                     Example returns     "C:\Program Files\Another Dir\AutoIt3"
Local $sPathExDr = StringRegExpReplace($sFile, "(^.:)(\\.*\\)(.*$)", "\2")

; Full Path w/0 backslashes, nor drive letter -     Example returns     "\Program Files\Another Dir\AutoIt3\"
Local $sPathExDrBSs = StringRegExpReplace($sFile, "(^.:\\)(.*)(\\.*$)", "\2")

; Path w/o backslash, not drive letter: -             Example returns     "Program Files\Another Dir\AutoIt3"
Local $sPathExBS = StringRegExpReplace($sFile, "(^.*)\\(.*)", "\1")

; File name with ext -                                 Example returns     "AutoIt3.chm"
Local $sFilName = StringRegExpReplace($sFile, "^.*\\", "")

; File name w/0 ext -                                 Example returns     "AutoIt3"
Local $sFilenameExExt = StringRegExpReplace($sFile, "^.*\\|\..*$", "")

; Dot Extenstion -                                     Example returns     ".chm"
Local $sDotExt = StringRegExpReplace($sFile, "^.*\.", ".$1")

; Extenstion -                                         Example returns     "chm"
Local $sExt = StringRegExpReplace($sFile, "^.*\.", "")

MsgBox(0, "Path File Name Parts", _
        "Drive             " & @TAB & $sDrive & @CRLF & _
        "Path              " & @TAB & $sPath & @CRLF & _
        "Path w/o backslash" & @TAB & $sPathExBS & @CRLF & _
        "Path w/o Drv:     " & @TAB & $sPathExDr & @CRLF & _
        "Path w/o Drv or \'s" & @TAB & $sPathExDrBSs & @CRLF & _
        "File Name         " & @TAB & $sFilName & @CRLF & _
        "File Name w/o Ext " & @TAB & $sFilenameExExt & @CRLF & _
        "Dot Extension     " & @TAB & $sDotExt & @CRLF & _
        "Extension         " & @TAB & $sExt & @CRLF)

M23

[Mobius]

Just a simple example

$FILE = FileOpenDialog(@SCRIPTNAME,@WORKINGDIR,"Any(*.*)")
IF @ERROR THEN EXIT
$FILE = StringMid($FILE,StringInStr($FILE,"\",2,-1) +1)
MsgBox(64,@SCRIPTNAME,"FileName is: "& $FILE)
EXIT

Vlad

[ajag]

Or use the _PathSplit

#include <file.au3>

Dim $Path = "C:\Folder\SubFolder\File.ext"
Dim $szDrive, $szDir, $szFName, $szExt

_PathSplit($Path, $szDrive, $szDir, $szFName, $szExt)

MsgBox(0, "Filename", $szFName & $szExt )

A-Jay

[nf67]

Thank you Water, Melba, Mobius and Ajag for summing up all these solutions to choose from, much appreciated.