Trigger a function when pressing Enter on a GUI-Input

[Matthy]

Hey all,

i have a GUI with inputs, and the purpose of those inputs is adding elements it works now by putting information in to the fields "GUICtrlCreateInput" fields and you can add them by using a add button "GUICtrlCreateButton" however its not that handy you keep mousing or tabbing to the add button and then shift tabbing back to the input field.

is it possible to run the function that should be triggered by the button by enter if its in a input field?

I thougth of using hotkeyset but that influences the whole envoinrent.

is there a better solution??

thanks

Matthy

[norax]

Hey all,

i have a GUI with inputs, and the purpose of those inputs is adding elements it works now by putting information in to the fields "GUICtrlCreateInput" fields and you can add them by using a add button "GUICtrlCreateButton" however its not that handy you keep mousing or tabbing to the add button and then shift tabbing back to the input field.

is it possible to run the function that should be triggered by the button by enter if its in a input field?

I thougth of using hotkeyset but that influences the whole envoinrent.

is there a better solution??

thanks

Matthy

$BS_DEFPUSHBUTTON use this style when creating the button also make sure to #include <ButtonConstants.au3>

this will make the button press when u hit enter

edit: lol beat mel to this one so they get all complex and out do my answer =(

Edited June 9, 2010 by norax

[Melba23]

Matthy,

You mean like this:

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

$gui = GUICreate( "test", 200, 200)
$inp = GUICtrlCreateInput("", 10, 10,100,20)
$but = GUICtrlCreateButton("clear text", 120, 10)
$hDummy = GUICtrlCreateDummy()
GUICtrlSetState($but, $GUI_HIDE)
GUISetState(@SW_SHOW)

; Set accelerator for Enter to action the Dummy code
Dim $AccelKeys[1][2]=[["{ENTER}", $hDummy]]
GUISetAccelerators($AccelKeys)

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $hDummy
            ; Check input has focus
            If _WinAPI_GetFocus() = GUICtrlGetHandle($inp) Then
                $sText = GUICtrlRead($inp)
                MsgBox(0,"test", "You typed in " & $sText)
                GUICtrlSetState($but, $GUI_SHOW)
            EndIf
        Case $msg = $but
            GUICtrlSetData($inp, "")
            GUICtrlSetState($but, $GUI_HIDE)
    EndSelect

WEnd
GUIDelete()

M23