How I read all data in List control

[konani]

Hi everyone,

I use List control to store data (GUICtrlCreateList). When program run, it add some data to this control. I use GUICtrlRead to read data in this control, but this function only read selected value. I wanna read all data in List control. How I do it?

Thanks for your help,

Edited June 8, 2010 by konani

[jfcby]

You will need to use a For Next statement and check out the _GUICtrlListBox from the help file.

jfcby

[GEOSoft]

Are you trying to return the list as an array or as a string?

To Return an array Call the following function with no second parameter, To return it as a delimited string call it with the second parameter being anything except Default, True or -1.

The first parameter is always the List control.

As an array >> _GUIList_GetAllItems($mylist) or _GUIList_GetAllItems($mylist, Default) or _GUIList_GetAllItems($mylist, -1)

As a string >> _GUIList_GetAllItems($mylist, 0) or _GUIList_GetAllItems($mylist, False)

Func _GUIList_GetAllItems($hWnd, $Array = True)
    If StringRegExp($Array, "(?i)-?1|default|True") Then
        $Array = True
    Else
        $Array = False
    EndIf
    If NOT IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)
    Local $sRtn = "", $iLen, $tHold, $aResult, $sSep = Opt("GUIDataSeparatorChar")
    $aResult = DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", $hWnd, "uint", 0x018B, "wparam", 0, "lparam", 0)
    If @Error Then Return SetError(@Error, @Extended, "")
    Local $iCount = $aResult[0]
    For $i = 0 To $iCount - 1
        $aResult = DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", $hWnd, "uint", 0x018A, "wparam", 0, "lparam", 0)
        If @Error Then Return SetError(@Error, @Extended, "")
        $iLen = $aResult[0] + 1
        $tHold = DllStructCreate("wchar Text[" & $iLen & "]")
        DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", $hWnd, "uint", 0x0189, "wparam", $i, "lparam", DllStructGetPtr($tHold))
        If @Error Then Return SetError(@Error, @Extended, "")
        $sRtn &= DllStructGetData($tHold, "Text") & $sSep
    Next
    $sRtn = StringTrimRight($sRtn, StringLen($sSep))
    If $Array Then Return StringSplit($sRtn, $sSep, 2)
    Return $sRtn
EndFunc   ;==>_GUIList_GetAllItems

EDIT: Fixed a potential error in the code and added error checking

Edited June 8, 2010 by GEOSoft

[konani]

  On 6/8/2010 at 4:42 PM, 'GEOSoft said:

Are you trying to return the list as an array or as a string?

To Return an array Call the following function with no second parameter, To return it as a delimited string call it with the second parameter being anything except Default, True or -1.

The first parameter is always the List control.

As an array >> _GUIList_GetAllItems($mylist) or _GUIList_GetAllItems($mylist, Default) or _GUIList_GetAllItems($mylist, -1)

As a string >> _GUIList_GetAllItems($mylist, 0) or _GUIList_GetAllItems($mylist, False)

Func _GUIList_GetAllItems($hWnd, $Array = True)
    If StringRegExp($Array, "(?i)-?1|default|True") Then
        $Array = True
    Else
        $Array = False
    EndIf
    If NOT IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)
    Local $sRtn = "", $iLen, $tHold, $aResult, $sSep = Opt("GUIDataSeparatorChar")
    $aResult = DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", $hWnd, "uint", 0x018B, "wparam", 0, "lparam", 0)
    If @Error Then Return SetError(@Error, @Extended, "")
    Local $iCount = $aResult[0]
    For $i = 0 To $iCount - 1
        $aResult = DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", $hWnd, "uint", 0x018A, "wparam", 0, "lparam", 0)
        If @Error Then Return SetError(@Error, @Extended, "")
        $iLen = $aResult[0] + 1
        $tHold = DllStructCreate("wchar Text[" & $iLen & "]")
        DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", $hWnd, "uint", 0x0189, "wparam", $i, "lparam", DllStructGetPtr($tHold))
        If @Error Then Return SetError(@Error, @Extended, "")
        $sRtn &= DllStructGetData($tHold, "Text") & $sSep
    Next
    $sRtn = StringTrimRight($sRtn, StringLen($sSep))
    If $Array Then Return StringSplit($sRtn, $sSep, 2)
    Return $sRtn
EndFunc   ;==>_GUIList_GetAllItems

EDIT: Fixed a potential error in the code and added error checking

Thanks in advance, I solved.

[Marshin]

GEOSoft,

your function works great.

thank you