Sum of Numbers Entered

[BlakeOh]

Hi All,

I'm new to AutoIt and loving it thus far. I have a (probably) very simple question for a script I am trying to create:

What I'm doing is creating a simple GUI where a value is entered and the digits are added together and a new value is presented. What I cannot figure out how to do is add consecutive digits, for example:

User enters 1234

User is presented with 10 (1+2+3+4)

any help is appreciated!

[Malkey]

Here is an example.

Local $value, $iIn, $sStr
$iIn = InputBox("Testing", "Enter numbers")

For $i = 1 To StringLen($iIn)
    $value += StringMid($iIn, $i, 1)
    $sStr &= StringMid($iIn, $i, 1) & "+"
Next
MsgBox(0, "Results", $value & " (" & StringTrimRight($sStr, 1) & ")")

[DW1]

Another way to do the same thing, but with an array:

#Include <Array.au3>
$iIn = InputBox("Testing", "Enter numbers")
$aString = StringSplit($iIn,"")
MsgBox(0, "Results", Execute(_ArrayToString($aString,'+',1)) & " (" & _ArrayToString($aString,'+',1) & ")")

Edited May 14, 2010 by danwilli

[Marlo]

Dan beat me to it with the StringSplit method

Dim $sNumbers = "123456789" ;Our numbers we want to add together.
Dim $aNumbers = StringSplit($sNumbers, "") ;split te numbers up into an array so: [1] = 1, [2] = 2, etc
Dim $iSum ;this variable will hold the answer

For $I = 1 To $aNumbers[0]
    ;Go through each number in our array and add it to our sum
    $iSum += $aNumbers[$I]
Next

MsgBox(64, "Addition", $sNumbers & " added together is " & $iSum) ;Display the answer

[Spiff59]

Another way to do the same thing, but with an array:

#Include <Array.au3>
$iIn = InputBox("Testing", "Enter numbers")
$aString = StringSplit($iIn,"")
MsgBox(0, "Results", Execute(_ArrayToString($aString,'+',1)) & " (" & _ArrayToString($aString,'+',1) & ")")

Clever use of the _ArrayToString() delimiter and Execute(). Kudos.

(also possibly the first useful implementation of Execute() I've seen in 2 years lol)

[Malkey]

Another example.

Local $sStr = StringTrimRight(StringRegExpReplace(InputBox("Testing", "Enter numbers"), "(\d)", "\1+"), 1)

MsgBox(0, "Results", Execute($sStr) & " (" & $sStr & ")")

[BlakeOh]

Thanks so much guys! What a great community.

This is actually the first part of a larger project and I stumbled a bit. I will play around with all these examples.

Thanks again all.