Au3Irrlicht 2.0

[BiliyomKi]

lol

update: Improved menu, press esc to see the 'improved' ingame-menu

expandcollapse popup

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Run_AU3Check=n
#AutoIt3Wrapper_Add_Constants=n
#AutoIt3Wrapper_Tidy_Stop_OnError=n
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include "au3Irrlicht2.au3"
#include "array.au3"

HotKeySet("{ESC}", "_Menu")
HotKeySet("{F2}", "_exit")

_IrrStart($IRR_EDT_OPENGL, 800, 600, $IRR_BITS_PER_PIXEL_32, $IRR_WINDOWED, $IRR_SHADOWS, $IRR_CAPTURE_EVENTS, $IRR_VERTICAL_SYNC_ON)

Func _exit()
    _IrrStop()
EndFunc   ;==>_exit
Func _Menu()
    Menu(1)
EndFunc

Global Enum $MGUI_BTTN_BASLA, _ ;    102
        $MGUI_BTTN_CIKIS ;      103

$BitmapFont = _IrrGetFont("Meshes\fonthaettenschweiler.bmp")
_IrrGUISetFont($BitmapFont)
_IrrSetWindowCaption("My Game")

_IrrGUISetFont($BitmapFont)
_IrrGUISetColor($EGDC_3D_FACE, 192, 255, 255, 255)
;_IrrGUISetColor($EGDC_BUTTON_TEXT, 255, 64, 64, 255)
Menu(0)

Func Menu($a1 = 1)
    if $a1 = 1 Then
        $cam = _IrrGetNodePosition($CameraNode)
        $rot = _IrrGetCameraTarget($CameraNode)
        $waitingcam = _IrrAddCamera($cam[0],$cam[1],$cam[2],$rot[0],$rot[1],$rot[2])
        _IrrSetActiveCamera($waitingcam)
    EndIf
    _IrrShowMouse()
    if $a1 = 1 Then
        _IrrAddStaticText("Press 'Oyuna Devam' to Resume Game.", 15, 10, 2506, 36, $IRR_GUI_NO_BORDER, $IRR_GUI_NO_WRAP)
        _IrrAddButton(16, 36, 112, 64, $MGUI_BTTN_BASLA, "Oyuna Devam")
    Else
        Global $guiStatic = _IrrAddStaticText("Welcome to Unnamed Game :) Press 'Oyuna Başla' to Start the Game.", 15, 10, 2506, 36, $IRR_GUI_NO_BORDER, $IRR_GUI_NO_WRAP)
        _IrrAddButton(16, 36, 112, 64, $MGUI_BTTN_BASLA, "Oyuna Başla")
    EndIf
    _IrrAddButton(128, 36, 224, 64, $MGUI_BTTN_CIKIS, "Çıkış")
    _IrrGUIEvents(1)

    While _IrrRunning()
        _IrrBeginScene(0, 100, 200)
        _IrrDrawScene()
        _IrrDrawGUI()
        If _IrrGUIEventAvailable() Then
            $pGUIEvent = _IrrReadGUIEvent()
            $gui_ID = __getGuiEvt($pGUIEvent, $EVT_GUI_IID)
            $gui_Event = __getGuiEvt($pGUIEvent, $EVT_GUI_IEVENT)
            Select
                Case $gui_ID = $MGUI_BTTN_CIKIS
                    If $gui_Event = $EGET_BUTTON_CLICKED Then
                        _IrrGUIClear()
                        _IrrGUIEvents(0)
                        _IrrEndScene()
                        _IrrStop()
                    EndIf

                Case $gui_ID = $MGUI_BTTN_BASLA
                    If $gui_Event = $EGET_BUTTON_CLICKED Then
                        _IrrGUIClear()
                        _IrrGUIEvents(0)
                        if $a1 = 1 Then
                            _IrrSetActiveCamera($CameraNode)
                            _IrrHideMouse()
                        Else
                            LoadIt()
                        EndIf
                        ExitLoop
                    EndIf
            EndSelect
        EndIf
        _IrrEndScene()
    WEnd
EndFunc   ;==>Menu

Func LoadIt()
    $guiStatic = _IrrAddStaticText("[-]", 350, 290, 450, 350, $IRR_GUI_NO_BORDER, $IRR_GUI_NO_WRAP)
    _IrrGUISetColor($EGDC_BUTTON_TEXT, 255, 255, 255, 255)
EndFunc   ;==>LoadIt

;~ ############# GAME #############
Dim $Mesh1, $Node1, $Collision1, $Mesh2, $Node2, $Collision2, $Mesh3, $Node3, $Mesh4, $Mesh4Texture, $Node4, $Collision4, $Camera, $keyStruct, $x, $y, $moving = 0
Dim $Distance, $Position, $CollisionState, $CollisionAnimator, $CollisionAnimator2, $CameraNode, $CombinedCollision, $Target[5], $pMouseEvent, $vect[3], $blt1 = 0
Dim $NodeHit, $Ray, $Ray1[3], $Ray2[3], $Null, $CrosTex, $Bullethole1, $Trigger, $Playing[50], $Get, $Attack[50], $Bullet, $Camera = -2, $nodea3, $YaratikHareket[50]
Dim $BitmapFont, $beam[199], $blt = 0, $Monster[50][50], $NoHit, $ohMyRet[99], $dummy, $Attacked, $yaratiksayi = 1, $pos = 0, $AttackC = 0, $w, $h, $g[199], $something
Dim $vuruldu

_IrrHideMouse()
ilerleme("%0")

For $i = 1 To UBound($Monster) - 1
    $Monster[$i][0] = 999
    $Monster[$i][1] = 999
    $Monster[$i][2] = 0
    $Monster[$i][3] = 0
    $Attack[$i] = 0
Next
ilerleme("%15")
$HaritaLoad = _IrrGetMesh("Meshes\1.irrmesh")
$Harita = _IrrAddMeshToSceneAsOcttree($HaritaLoad)
_IrrSetNodeMaterialFlag($Harita, $IRR_EMF_LIGHTING, $IRR_OFF)
$Collision1 = _IrrGetCollisionGroupFromComplexMesh($HaritaLoad, $Harita, 0)
$BitmapFont = _IrrGetFont("Meshes\bitmapfont.bmp")
$YaratikLoad = _IrrGetMesh("Meshes\zumlin.md2")
$YaratikTexture = _IrrGetTexture("Meshes\zumlin.pcx")

ilerleme("%30")
$SilahLoad = _IrrGetMesh("Meshes\mar_rifle.3ds")
$SilahTexture = _IrrGetTexture("Meshes\m_rifl.bmp")
$Silah = _IrrAddMeshToScene($SilahLoad)
_IrrSetNodeMaterialTexture($Silah, $SilahTexture, 0)
_IrrSetNodeMaterialFlag($Silah, $IRR_EMF_LIGHTING, $IRR_OFF)
_IrrSetNodePosition($Silah, 7, -10, 20)
_IrrSetNodeRotation($Silah, 0, 0, 0)
_IrrSetNodeScale($Silah, .5, .5, .35)

ilerleme("%45")
YaratikEkle()
YaratikEkle()

ilerleme("%60")
$SmokeEmitter = __CreateParticleSettings(0, 0, 0, 0, 0, 0, 0, 0.04, 0, 80, 100, 255, 255, 255, 255, 255, 255, 800, 2000, 5.0, 5.0, 15.0, 15.0, 15)
$ParticleTexture = _IrrGetTexture("Meshes\ParticleGrey.bmp")
$CombinedCollision = _IrrCreateCombinedCollisionGroup()
_IrrAddCollisionGroupToCombination($CombinedCollision, $Collision1)
_IrrAddCollisionGroupToCombination($CombinedCollision, $Collision2)


ilerleme("%75")
$MeshTexture = _IrrGetTexture("Meshes\beam.png")
$Monster[1][1] = 100
$Monster[1][0] = _IrrAddFPSCamera(0, 150.0, 0.5, -1, __CreatePtrKeyMapArray($keyStruct, $KEY_KEY_W, $KEY_KEY_S, $KEY_KEY_A, $KEY_KEY_D, $KEY_SPACE), 5, 100, 2.0)
$keyStruct = 0
$CameraNode = $Monster[1][0]
_IrrAddChildToParent($Silah, $CameraNode)
$CollisionAnimator = _IrrAddCollisionAnimator($CombinedCollision, $CameraNode, 30.0, 30.0, 30.0, 0.0, -3.0, 0.0, 0.0, 50.0, 0.0)
$CrosTex1 = _IrrGetTexture("Meshes\c1.png")
$CrosTex2 = _IrrGetTexture("Meshes\c2.png")

ilerleme("%100")
_IrrGUIEvents(0)
_IrrGUIClear()

While _IrrRunning()
    While _IrrMouseEventAvailable()
        $pMouseEvent = _IrrReadMouseEvent()
        $Get = __getMouseEvt($pMouseEvent, $EVT_MOUSE_IACTION)
        If $Get = $IRR_EMIE_LMOUSE_PRESSED_DOWN Then $Trigger = 1
        If $Get = $IRR_EMIE_LMOUSE_LEFT_UP Then $Trigger = 0
    WEnd
    While _IrrKeyEventAvailable()
        $pKeyEvent = _IrrReadKeyEvent()
        If __getKeyEvt($pKeyEvent, $EVT_KEY_IKEY) = $KEY_KEY_E Then
            If __getKeyEvt($pKeyEvent, $EVT_KEY_IDIRECTION) = $IRR_KEY_DOWN Then
                If $yaratiksayi < 48 And $yaratiksayi <> "MAX" Then
                    YaratikEkle()
                Else
                    $yaratiksayi = "MAX"
                EndIf
            EndIf
        EndIf
        If __getKeyEvt($pKeyEvent, $EVT_KEY_IKEY) = $KEY_KEY_Q Then
            If __getKeyEvt($pKeyEvent, $EVT_KEY_IDIRECTION) = $IRR_KEY_DOWN Then
                For $i = 2 To UBound($Monster) - 1
                    If $Monster[$i][0] <> 999 And $Monster[$i][1] <> "die" Then
                        $ewq = _IrrGetNodeAbsolutePosition($Monster[$i][0])
                        YaratikHareket(2, $i, $ewq[0] + 10, $ewq[1], $ewq[2])
                    EndIf
                Next
            EndIf
        EndIf
        If __getKeyEvt($pKeyEvent, $EVT_KEY_IKEY) = $KEY_KEY_F Then
            If __getKeyEvt($pKeyEvent, $EVT_KEY_IDIRECTION) = $IRR_KEY_DOWN Then HepsiniOldur()
        EndIf
    WEnd
    If $Trigger = 1 Then Algila()
    If $NodeHit Then Vurus()
    AtakBitti()
    If $moving = 1 Then YaratikHareket(1)
    If TimerDiff($Bullet) >= 150 Then KursunSil()

    CanKontrol()
    _IrrBeginScene(0, 0, 0)
    _IrrDrawScene()
    CanlariYaz()
    _IrrGetScreenSize($w, $h)

    If $AttackC = 1 Then _IrrDraw2DImageElement($CrosTex2, ($h + 101) / 2, ($w - 303) / 2, 0, 0, 64, 64, $IRR_USE_ALPHA)
    If $AttackC = 0 Then _IrrDraw2DImageElement($CrosTex1, ($h + 101) / 2, ($w - 303) / 2, 0, 0, 64, 64, $IRR_USE_ALPHA)
    $metrics = "FPS: " & _IrrGetFPS() & @CRLF & "MONSTERS: " & $yaratiksayi
    _Irr2DFontDraw($BitmapFont, $metrics, 4, 4, 250, 52)
    _IrrEndScene()
WEnd
_IrrStop()

Func HepsiniOldur()
    For $i = 2 To UBound($Monster) - 1
        If $Monster[$i][1] <> "die" And $Monster[$i][0] <> 999 Then
            $Monster[$i][1] = 0
        EndIf
    Next
    $yaratiksayi = 2
EndFunc   ;==>HepsiniOldur

Func ilerleme($yuzde)
    _IrrGUISetText($guiStatic, "LOADING " & $yuzde)
    _IrrBeginScene(0, 100, 200)
    _IrrDrawScene()
    _IrrDrawGUI()
    _IrrEndScene()
    Sleep(10)
EndFunc   ;==>ilerleme

Func YaratikEkle($HP = 100)
    $yaratiksayi += 1
    $Monster[$yaratiksayi][0] = _IrrAddMeshToScene($YaratikLoad)
    $Monster[$yaratiksayi][1] = $HP
    _IrrSetNodeMaterialTexture($Monster[$yaratiksayi][0], $YaratikTexture, 0)
    _IrrSetNodeMaterialFlag($Monster[$yaratiksayi][0], $IRR_EMF_LIGHTING, $IRR_OFF)
    _IrrPlayNodeMD2Animation($Monster[$yaratiksayi][0], $IRR_EMAT_STAND)
    _IrrSetNodeScale($Monster[$yaratiksayi][0], 2, 2, 2)
    _IrrSetNodePosition($Monster[$yaratiksayi][0], Random(-500, 500, 1), -200, Random(-500, 500, 1))
    $Collision = _IrrGetCollisionGroupFromMesh($YaratikLoad, $Monster[$yaratiksayi][0]);2
EndFunc   ;==>YaratikEkle

Func CanlariYaz()
    For $Whp = 2 To UBound($Monster) - 1
        If $Monster[$Whp][1] <> "die" And $Monster[$Whp][0] <> 999 Then
            $posi = _IrrGetNodePosition($Monster[$Whp][0])
            _IrrGetScreenCoordinatesFrom3DPosition($x, $y, $posi)
            _Irr2DFontDraw($BitmapFont, "ID " & $Whp - 1 & @LF & "HP: " & $Monster[$Whp][1], $x, $y, $x, $y)
        EndIf
    Next
    _Irr2DFontDraw($BitmapFont, "HP: " & $Monster[1][1], 10, 580, 800, 600) ;player
EndFunc   ;==>CanlariYaz

Func AtakBitti()
    For $aB = 1 To UBound($Monster) - 1
        If TimerDiff($Attack[$aB]) >= 400 Then
            If $Monster[$aB][2] = 1 Then
                Dim $NodeHit = 0, $AttackC = 0
                $Attack[$aB] = -1
                $Monster[$aB][2] = 0
                If $Monster[$aB][1] <> "die" Then _IrrPlayNodeMD2Animation($Monster[$aB][0], $IRR_EMAT_STAND)
            EndIf
        EndIf
    Next
EndFunc   ;==>AtakBitti

Func KursunSil()
    For $adr = 1 To $blt
        _IrrRemoveNode($beam[$adr])
    Next
    $blt = 0
    $blt1 = 0
EndFunc   ;==>KursunSil

Func CanKontrol()
    For $i = 1 To UBound($Monster) - 1
        If $Monster[$i][1] <= 0 And Not $Monster[$i][1] = "die" Then Oldur($i)
    Next
EndFunc   ;==>CanKontrol

Func Oldur($bYaratik)
    _IrrPlayNodeMD2Animation($Monster[$bYaratik][0], $IRR_EMAT_CROUCH_DEATH)
    $Monster[$bYaratik][1] = "die"
    $SmokeParticles = _IrrAddParticleSystemToScene($IRR_NO_EMITTER)
    _IrrAddAnimatedMeshSceneNodeEmitter($SmokeParticles, $Monster[$bYaratik][0], True, 0.25, False, $SmokeEmitter)
    _IrrSetNodeMaterialTexture($SmokeParticles, $ParticleTexture, 0)
    _IrrSetNodeMaterialFlag($SmokeParticles, $IRR_EMF_LIGHTING, $IRR_OFF)
    _IrrAddFadeOutParticleAffector($SmokeParticles, 2000, 16, 8, 0)
    $asdf = _IrrGetNodeAbsolutePosition($Monster[$bYaratik][0])
    _IrrAddParticleAttractionAffector($SmokeParticles, $asdf[0], $asdf[1], $asdf[2], 20.0, $IRR_REPEL)
    _IrrSetNodePosition($SmokeParticles, $asdf[0], $asdf[1], $asdf[2])
    _IrrSetNodeMaterialType($SmokeParticles, $IRR_EMT_TRANSPARENT_VERTEX_ALPHA)
    _IrrAddFadeAnimator($Monster[$bYaratik][0], 1000, 500)
    _IrrAddFadeAnimator($SmokeParticles, 1000, 0)
EndFunc   ;==>Oldur

Func Algila()
    $Target = _IrrGetCameraTarget($CameraNode)
    $Ray = _IrrGetRayFromScreenCoordinates(400, 300, $CameraNode)
    $Ray1[0] = $Ray[0][0]
    $Ray1[1] = $Ray[0][1]
    $Ray1[2] = $Ray[0][2]
    $Ray2[0] = $Ray[1][0]
    $Ray2[1] = $Ray[1][1]
    $Ray2[2] = $Ray[1][2]
    _IrrGetNodeAndCollisionPointFromRay($Ray1, $Ray2, $NodeHit, $Target[0], $Target[1], $Target[2], $Null, $Null, $Null, 0, $IRR_NO_OBJECT)
EndFunc   ;==>Algila

Func Vurus()
    If $NodeHit And $Trigger = 1 Then
        $NoHit = False
        For $i = 1 To UBound($Monster)
            If $i = 49 Then
                $NoHit = True
                ExitLoop
            EndIf
            If $NodeHit = $Monster[$i][0] And $i > 1 Then ExitLoop
        Next
        $Attacked = $i
        If $Monster[$Attacked][1] < 1 Then $NoHit = True
        If $NoHit = True Then
            Dim $Bullet = TimerInit(), $Trigger = 0
            $blt += 1
            Beam()
        Else
            Dim $Bullet = TimerInit()
            $Trigger = 0
            $blt += 1
            $blt1 += 1
            $Attack[$Attacked] = TimerInit()
            $Monster[$Attacked][2] = 1
            Beam()
            $Monster[$Attacked][1] -= 10
            $vuruldu = $Attacked
            _IrrPlayNodeMD2Animation($Monster[$Attacked][0], $IRR_EMAT_PAIN_A)
            $Monster[$Attacked][2] = 1
            $AttackC = 1
        EndIf
    EndIf
EndFunc   ;==>Vurus

Func Beam()
    $beam[$blt] = _IrrAddBeamSceneNode()
    _IrrSetBeamSize($beam[$blt], 2)
    _IrrSetNodeMaterialTexture($beam[$blt], $MeshTexture, 0)
    _IrrSetNodeMaterialType($beam[$blt], $IRR_EMT_TRANSPARENT_ADD_COLOR)
    $posi = _IrrGetNodeAbsolutePosition($Silah)
    _IrrSetBeamPosition($beam[$blt], $posi[0], $posi[1] + 2, $posi[2], $Target[0], $Target[1] + 10, $Target[2])

    $g[$blt1] = _IrrAddBillBoardToScene(2, 2, $Target[0], $Target[1] + 10, $Target[2])
    _IrrSetNodeMaterialTexture($g[$blt1], $MeshTexture, 0)
    _IrrSetNodeMaterialFlag($g[$blt1], $IRR_EMF_LIGHTING, $IRR_OFF)
    _IrrSetNodeMaterialType($g[$blt1], $IRR_EMT_TRANSPARENT_ADD_COLOR)
    _IrrAddFadeAnimator($g[$blt1], 1000)
EndFunc   ;==>Beam

Func YaratikHareket($aDurum, $aYaratik = 0, $aX = 0, $bY = 0, $cZ = 0)
    Select
        Case $aDurum = 1
            For $i = 2 To UBound($Monster) - 1
                If TimerDiff($YaratikHareket[$i]) >= 100 And $Monster[$i][0] <> 999 And $Monster[$i][1] <> "die" Then
                    _IrrPlayNodeMD2Animation($Monster[$i][0], $IRR_EMAT_STAND)
                    $Monster[$i][3] = 0
                    $YaratikHareket[$i] = -1
                    $something = 1
                EndIf
            Next
            If $something = 1 Then
                $moving = 0
                $something = 0
            EndIf
        Case $aDurum = 2
            If $Monster[$aYaratik][3] = 0 Then
                _IrrPlayNodeMD2Animation($Monster[$aYaratik][0], $IRR_EMAT_RUN)
            EndIf
            _IrrSetNodePosition($Monster[$aYaratik][0], $aX, $bY, $cZ)
            $Monster[$aYaratik][3] = 1
            $YaratikHareket[$aYaratik] = TimerInit()
            $moving = 1
    EndSelect
EndFunc   ;==>YaratikHareket

edit:

bogQ; I tested it a lot, there's no 'no target' error, maybe you doing something wrong?

Edited June 13, 2011 by BiliyomKi

[bogQ]

No im dooing everything from the book

$AttackC = 0 on nude for on second loop of killing monsters

set monsters HP to 10 to test faster, add max (50 from the start) of them and start killing, after your done with first 50 add another 50 and start testing one more time, you shud see it on second 50 mobs the error if im not wrong

[BiliyomKi]

sorry, I killed 200 zumlins, still no error

edit: $attackC is not for killing monsters, its only for Crosshair selecting

Edited June 13, 2011 by BiliyomKi

[bogQ]

dont understand

$yaratiksayi

Func HepsiniOldur()

For $i = 2 To UBound($Monster) - 1

If $Monster[$i][1] <> "die" And $Monster[$i][0] <> 999 Then

$Monster[$i][1] = 0

EndIf

Next

$yaratiksayi = 2

EndFunc ;==>HepsiniOldur

on top you have it declared to b =1

and after reset =2?

Edited June 13, 2011 by bogQ

[kaotkbliss]

I just tried it out and must say, Great work so far!

I also wanted to confirm what BogQ said.

It seems that when some Zumlin are created, you cannot shoot them. The target never changes color and their HP doesn't go down. Also the "hit" animation doesn't play.

Win7 x64 running in x86

[bogQ]

my bets are on $yaratiksayi, maby im wrong, there are lots of complicity in there with attack funcs so im having problems to spot problem.

kaotkbliss any SS from your work? im starting to become SS maniac lol

Edit: or anyone else if he started to work on something?

Edited June 14, 2011 by bogQ

[kaotkbliss]

Not yet. I was converting the different areas to .obj but then got into trying to learn java to make android apps to sell... that isn't going so well. I can't seem to find a good place to learn. all I can find are examples with little or no explination

[bogQ]

how about game maker instead of java?

info page

http://www.droidgamers.com/index.php/game-news/android-game-news/1010-game-maker-by-yoyo-games-officially-supporting-android-now

[monoscout999]

hi. i´m getting this error on any example..

>"C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.exe" /run /prod /ErrorStdOut /in "G:\Agustin\autoit\au3Irrlicht2\irrtest.au3" /autoit3dir "C:\Program Files (x86)\AutoIt3" /UserParams    
+>15:19:30 Starting AutoIt3Wrapper v.2.0.1.24    Environment(Language:0C0A  Keyboard:0000040A  OS:WIN_7/  CPU:X64 OS:X64)
>Running AU3Check (1.54.19.0)  from:C:\Program Files (x86)\AutoIt3
+>15:19:30 AU3Check ended.rc:0
>Running:(3.3.6.1):C:\Program Files (x86)\AutoIt3\autoit3_x64.exe "G:\Agustin\autoit\au3Irrlicht2\irrtest.au3"    
@@ Debug(5) : _IrrStart() = False
>Error code: 2
+>15:19:31 AutoIT3.exe ended.rc:0
>Exit code: 0    Time: 1.986

I read that this is...

|2 - IrrlichtWrapper.dll not found

I unzip the "au3Irrlicht2.0.4.zip" file on a folder and try it to run, i try to copy the dlls to the script folder, include folder and always get the error

¿Can you help me?

[kaotkbliss]

try placing it in the same directory as your irrtest.au3 file

[monoscout999]

try placing it in the same directory as your irrtest.au3 file

i already try it and doesn`y work

[kaotkbliss]

I think I may also have a copy in the system32 folder on my pc

I don't quite remember, but you could try placing them there.

[bogQ]

heare are the needed paths if im not wrong, chose one of them

MsgBox(0,"", StringReplace(@ScriptDir & "\bin;" & @ScriptDir & "\..\bin;" & EnvGet("PATH"),";",@CRLF))

youl probably need to copy all 4 dlls

IrrlichtWrapper.dll, Irrlicht.dll, msvcp71.dll msvcr71.dll

to one location from msgbox result

system32 folder recommended

Edited June 20, 2011 by bogQ

[monoscout999]

I`m still getting error... i copy and paste the four dlls to ALL the folders that appear on the MsgBox

Screen --->

(The red marked are unknow for me :S i guess that is useful if i have the script dir in anohter folder)

I place the script on the au3Irrlicht2 Folder

Screen --->

I Reboot My PC After that... and nothing

My OS is Win7 Ultimate 64bits, i use AutoIt 3.3.6.1 and use the last Full Scite version(my "About SciTe sayas "Version 1.79 Jul 16 2009 18:30:31", but i donwloaded the last of it (February 28, 2010) :S bug¿?)

[bogQ]

maby this can help

pls read it from the top to the end

[monoscout999]

maby this can help

pls read it from the top to the end

Thank you a lot... that is... the only thing left to do is change the SciTE config to run the scripts like 32bit version.. ¿did you know how to do it?

EDIT; I found the way to do it, editing the au3.properties file

commenting the #57 line and un commenting the #58 line

;command.go.$(au3)="$(SciteDefaultHome)\AutoIt3Wrapper\AutoIt3Wrapper.exe" /run /prod /ErrorStdOut /in "$(FilePath)" /autoit3dir "$(autoit3dir)" /UserParams $(1) $(2) $(3) $(4)
command.go.$(au3)="$(autoit3dir)\autoit3.exe" /ErrorStdOut "$(FilePath)" $(1) $(2) $(3) $(4)

Edited June 20, 2011 by monoscout999

[BrewManNH]

#AutoIt3Wrapper_UseX64=n

[bogQ]

that one i realy dont know, im still usinf xp x86

Maby someone else can assist or try to post into chat or general support

Edited June 20, 2011 by bogQ

[monoscout999]

#AutoIt3Wrapper_UseX64=n

That is the correct way to do it! thank you.

EDIT: Can you edit the Example Launcher script, adding a #requireadmin because i got Win7 and i cant merge the help file,

second thing.. How do you merge the help files? i put that question here

Edited June 21, 2011 by monoscout999

[bogQ]

That edit can only b done from

linus

and

JRowe

or maby smashly if he have code for it

I dont think that you can merge them, dont know why should anyone try something like that if Au3Irrlicht dont come with standard instalation of autoit. Recreating the help files for personale use mean rebilding them over and over every time when new version of autoit or Au3Irrlicht come out.

@linus,JRowe or maby smashly

Some edits are needed

#include "au3Irr2_constants.au3" to b removed from all the sub inclyde scripts becase its enought to inclyde it one time only in au3Irrlicht2.au3 main UDF.

to add #AutoIt3Wrapper_UseX64=n - return error on @AutoItX64

As monoscout999 already tolded and Example Launcher script need recompiling after adding #AutoIt3Wrapper_UseX64=n

dono if it's good idea to add #RequireAdmin in include

original wraper help file for undocumented funcs is still needed becase in help file there still are some important funcs that don`t have description, can you add as part of package?