Slider And Slider Automatic

[MikeTranser]

Two Script problem

First: (I need Create Label only in TabSheet2)

Case $Slider1
        $silder = GUICtrlRead($Slider1)
        GUICtrlDelete($Label3)
        GUICtrlCreateLabel($silder, 328, 120, 35, 20)In $TabSheet2
        GUICtrlSetColor(-1, 0x0000FF)
        GUICtrlSetBkColor(-1, 0xFFFFFF)

Second: I need slider automatic "If you hold slider the label is create automatic no put down"

[Melba23]

MikeTranser,

Q1. Create the label when you create the Tab structure so that you get it in the right place - then use GUICtrlSetState(-1, $GUI_HIDE) to hide it. When you want it to appear, just use $GUI_SHOW to make it appear.

Q2. I do not understand what you want to do in the second part of your request ("If you hold slider the label is create automatic no put down") - can you please explain in a bit more detail?

M23

[MikeTranser]

In slider you must hold slider and turn right/left and you must put down slider to effect. (I need autmatic)

Q1. Do you show me in my script?

[Melba23]

Miketranser,

I understand now! I think this does what you want:

expandcollapse popup

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$tab = GUICtrlCreateTab(10, 10, 200, 100)

    $tab0 = GUICtrlCreateTabItem("Tab 0")

    $tab1 = GUICtrlCreateTabItem("Tab 1")

    $tab2 = GUICtrlCreateTabItem("Tab 2")
    ; Create label and hide it
    $hLabel = GUICtrlCreateLabel("", 30, 80, 50, 20)
    GUICtrlSetState(-1, $GUI_HIDE)

GUICtrlCreateTabItem(""); end tabitem definition

$hSlider = GUICtrlCreateSlider(10, 250, 480, 30)

GUISetState()

$iLastSlider = 0

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; When cursor is over slider and button is down
    $aInfo = GUIGetCursorInfo($hGUI)
    If $aInfo[2] = 1 And $aInfo[4] = $hSlider Then Check_Slider()

WEnd

Func Check_Slider()

    ; Show label
    GUICtrlSetState($hLabel, $GUI_SHOW)
    ; While button is pressed
    While $aInfo[2]
        $iCurrSlider = GUICtrlRead($hSlider)
        ; Update label if value has changed
        If $iCurrSlider <> $iLastSlider Then
            $iLastSlider = $iCurrSlider
            GUICtrlSetData($hLabel, $iCurrSlider)
        EndIf
        $aInfo = GUIGetCursorInfo($hGUI)
    WEnd
    ; Hode label again
    GUICtrlSetState($hLabel, $GUI_HIDE)

EndFunc

M23

[MikeTranser]

Thanks Melba23,

And please close topic.