ConvertFileSize UDF

[Steveiwonder]

Hey All,

Very small UDF i've thrown together. I'm using FILEGETSIZE alot in my current project and it returns the size in bytes... i needed to convert this to either GB MB or KB.

Thought i'd share it as i couldn't find anything else on the forum.

UDF:

expandcollapse popup

;==================================================================================
; AutoIt Version:   3.3.4.0
; Language:         English
; Author:           Steveiwonder
; Requirements:     None
;==================================================================================
; Function:         ConvertSize
; Description:      Converts a given number(bytes) into GB/MB/KB/B
; Parameter(s):     $FileSizeInBytes - the size of file / folder in bytes


; Return Value(s):  Returns array
;                   [0] contains the converted file/folder size in GB/MB/KB/B rounded to two decimal places.
;                   [1] contains either GB/MB/KB/B
; Author(s):        Steveiwonder
;==================================================================================
Func _ConvertSize($FileSizeInBytes)
    
    Local $n[2] = [$FileSizeInBytes, ""]

        
    If $n[0] >= 1073741824 Then ; = or greater than 1GB
        $n[0] = $n[0]/(1024*1024*1024)
        $n[1]= "GB"
        
    ElseIf $n[0] >= 1048576 Then ; = or greater than 1MB
        $n[0] = $n[0]/(1024*1024)
        $n[1]= "MB"     
    
    ElseIf $n[0] >= 1024 Then ; = or greater than 1KB
        $n[0] = $n[0]/(1024)
        $n[1]= "KB"
        
    Else
        $n[0] = $n[0]
        $n[1]= "B"      
    EndIf
    
    $n[0] = Round($n[0], 2)
    
    Return $n
EndFunc

Example Script:

#include "func_ConvertFileSize.au3"
$fileSize = DirGetSize("C:\Windows")
$xSize = _ConvertSize($fileSize)

MsgBox(64, "Size Conversion", $fileSize & " bytes = " & $xSize[0] & " " & $xSize[1])

Do what you want with it, i'm sure it can be modified to make it better.

Steveiwonder

func_ConvertFileSize.au3

Edited February 26, 2010 by Steveiwonder

[dmob]

Nice!! I've also been converting bytes to human-readable formats a lot... This UDF makes it much easier, neater and consistent. Thanks for your share.

Edited February 26, 2010 by dmob

[MrCreatoR]

Nice, but have been done before: http://www.autoitscript.com/forum/index.php?showtopic=63770&view=findpost&p=475855

[MrCreatoR]

Func _String_GetFormattedSize($iByteSize, $iRound=2, $sRetFormat=-1)
    Local $asBytes[9] = [8, 'KB', 'MB', 'GB', 'TB', 'PB', 'EB', 'ZB', 'YB'] ;Last two unreachable ;)
    Local $iBytes_Val = 2 ^ 10
    
    If $iByteSize < $iBytes_Val Then Return $iByteSize & ' Bytes'
    
    Local $iRetFormat_IsString = IsString($sRetFormat)
    Local $iFor = 1, $iTo = 8, $iStep = 1
    
    If $iRetFormat_IsString Then
        If Not StringRegExp($sRetFormat, "\A(?i)(KB|MB|GB|TB|PB|EB|ZB|YB)\z") Then Return SetError(1, 0, $iByteSize)
    Else
        Local $iFor = 8, $iTo = 1, $iStep = -1
    EndIf
    
    For $i = $iFor To $iTo Step $iStep
        If ($iRetFormat_IsString And $sRetFormat = $asBytes[$i]) Or _
            (Not $iRetFormat_IsString And $iByteSize >= $iBytes_Val ^ $i) Then
                Return Round($iByteSize / $iBytes_Val ^ $i, $iRound) & ' ' & $asBytes[$i]
        EndIf
    Next
EndFunc

[mLipok]

Quick search, a small modification, and this is the end result:

expandcollapse popup

MsgBox(0, '', _String_GetFormattedSizeEx(7098459644))

; #FUNCTION# ====================================================================================================================
; Name ..........: _String_GetFormattedSizeEx
; Description ...: Return ByteSize in human-readable format ("complex format" GB + MB + KB )
; Syntax ........: _String_GetFormattedSizeEx($iByteSize)
; Parameters ....: $iByteSize           - an integer value.
; Return values .: ByteSize in format like this:  7 GB 770 MB 089 KB
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _String_GetFormattedSizeEx($iByteSize)
    Local $sKB = _String_GetFormattedSize(7098459644, 0, 'KB')
    Local $sMB = _String_GetFormattedSize(7098459644, 0, 'MB')
    Local $sGB = _String_GetFormattedSize(7098459644, 0, 'GB')
    Return $sGB & ' ' & StringRight($sMB, 6) & ' ' & StringRight($sKB, 6)
EndFunc   ;==>_String_GetFormattedSizeEx

; #FUNCTION# ====================================================================================================================
; Name ..........: _String_GetFormattedSize
; Description ...: Return ByteSize in human-readable format (one of avalaible size format)
; Syntax ........: _String_GetFormattedSize($iByteSize[, $iRound = 2[, $sRetFormat = -1]])
; Parameters ....: $iByteSize           - an integer value.
;                  $iRound              - [optional] an integer value. Default is 2.
;                  $sRetFormat          - [optional] a string value. Default is -1.
; Return values .: ByteSize in choosen format
; Author ........: MrCreatoR
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.autoitscript.com/forum/topic/110713-convertfilesize-udf/#comment-777347
; Example .......: No
; ===============================================================================================================================
Func _String_GetFormattedSize($iByteSize, $iRound = 2, $sRetFormat = -1)
    Local $asBytes[9] = [8, 'KB', 'MB', 'GB', 'TB', 'PB', 'EB', 'ZB', 'YB'] ;Last two unreachable ;)
    Local $iBytes_Val = 2 ^ 10

    If $iByteSize < $iBytes_Val Then Return $iByteSize & ' Bytes'

    Local $iRetFormat_IsString = IsString($sRetFormat)
    Local $iFor = 1, $iTo = 8, $iStep = 1

    If $iRetFormat_IsString Then
        If Not StringRegExp($sRetFormat, "\A(?i)(KB|MB|GB|TB|PB|EB|ZB|YB)\z") Then Return SetError(1, 0, $iByteSize)
    Else
        Local $iFor = 8, $iTo = 1, $iStep = -1
    EndIf

    For $i = $iFor To $iTo Step $iStep
        If ($iRetFormat_IsString And $sRetFormat = $asBytes[$i]) Or _
                (Not $iRetFormat_IsString And $iByteSize >= $iBytes_Val ^ $i) Then
            Return Round($iByteSize / $iBytes_Val ^ $i, $iRound) & ' ' & $asBytes[$i]
        EndIf
    Next
EndFunc   ;==>_String_GetFormattedSize

 

Now ready to use in my script.
Thanks for sharing.

mLipok

 

[mLipok]

there was a bug in my _String_GetFormattedSizeEx()

Here is fixed version:

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _String_GetFormattedSizeEx
; Description ...: Return ByteSize in human-readable format ("complex format" GB + MB + KB )
; Syntax ........: _String_GetFormattedSizeEx($iByteSize)
; Parameters ....: $iByteSize           - an integer value.
; Return values .: ByteSize in format like this:  7 GB 770 MB 089 KB
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _String_GetFormattedSizeEx($iByteSize)
    Local Enum _
            $SIZE_B = 1, _
            $SIZE_KB = $SIZE_B * 1024, _
            $SIZE_MB = $SIZE_KB * 1024, _
            $SIZE_GB = $SIZE_MB * 1024

    Local $SIZE_GB_DIV = Int($iByteSize / $SIZE_GB)
    $iByteSize = $iByteSize - ($SIZE_GB * $SIZE_GB_DIV)

    Local $SIZE_MB_DIV = Int($iByteSize / $SIZE_MB)
    $iByteSize = $iByteSize - ($SIZE_MB * $SIZE_MB_DIV)

    Local $SIZE_KB_DIV = Int($iByteSize / $SIZE_KB)
    $iByteSize = $iByteSize - ($SIZE_KB * $SIZE_KB_DIV)

    Local $SIZE_B_DIV = Int($iByteSize / $SIZE_B)
    $iByteSize = $iByteSize - ($SIZE_B * $SIZE_B_DIV)

    Local $sResult = $SIZE_GB_DIV & ' GB ' & StringRight($SIZE_MB_DIV, 6) & ' MB ' & StringRight($SIZE_KB_DIV, 6) & ' KB'
    ConsoleWrite("! $iByteSize = " & $iByteSize & @CRLF)
    If $iByteSize <> 0 Then _
            Return SetError(1, 0, $sResult)
    ConsoleWrite("! " & $sResult & @CRLF)
    Return $sResult
EndFunc   ;==>_String_GetFormattedSizeEx