CSV-Editor V0.8

[czardas]

There's some very useful looking code in this thread. Good for some study. Thanks to all.

[taietel]

funkey, with your permission, I have added another thing in menu (Recent Files). It records 10 most recent files used.

M.I.

CSV-Editor V0.8.au3

[guinness]

taietel some great Functions, But (sorry about that ) there is a potential problem with _CSV_FindDelimiter() in that if it Returns the Delimiter the File isn't closed!! So here is my attempt at the Function.

Function:

Func _CSV_FindDelimiter($sFileName)
    Local $aDelimiter = StringSplit(@TAB & "@,@;@,;@|@" & "'@" & '"', "@", 2), $aSRE
    Local $hFileOpen = FileOpen($sFileName, 0), $iIndex = 0, $iUbound = UBound($aDelimiter, 1), $sData
    If $hFileOpen = -1 Then
        Return SetError(1, 0, "")
    EndIf
    $sData = FileRead($hFileOpen)
    FileClose($hFileOpen)
    $aSRE = StringRegExp($sData, '(?s)(?i)(.*?)' & @CRLF, 3)
    If @error Then
        Return SetError(1, 0, "")
    EndIf
    If UBound($aSRE, 1) >= 2 Then
        $iIndex = 1
    EndIf
    For $A = 0 To $iUbound - 1
        If StringInStr($aSRE[0], $aDelimiter[$A]) <> 0 And StringInStr($aSRE[$iIndex], $aDelimiter[$A]) <> 0 Then
            Return $aDelimiter[$A]
        EndIf
    Next
    Return SetError(1, 0, "")
EndFunc   ;==>_CSV_FindDelimiter

[taietel]

guinness, sorry for what? I'm glad you saw that mistake. Thanks!

[AZJIO]

funkey

WM_COMMAND - to hide the input field with a loss of focus

problem remains : if the scrolling ListView, the "Input" does not scroll.

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

Opt("GUIOnEventMode", 1)
Global $aElement[2], $hActive, $iInput
Global $iListView, $hListView, $dummy1, $dummy2

$hGUI = GUICreate('Double click on the item', 450, 360)
GUISetOnEvent(-3, '_Exit')
$iInput = GUICtrlCreateInput("", 0, 0, 0, 0)
GUICtrlSetState(-1, $GUI_HIDE)
$iListView = GUICtrlCreateListView('Col 1|Col 2', 5, 5, 440, 330, BitOR($GUI_SS_DEFAULT_LISTVIEW, $LVS_REPORT, $LVS_SHOWSELALWAYS))
$hListView = GUICtrlGetHandle(-1)

For $i = 1 To 20
 $item1 = Random(10, 99, 1)
 $item2 = ''
 For $j = 1 To 9
  $item2 &= Chr(Random(97, 122, 1))
 Next
 GUICtrlCreateListViewItem($item1 & '|' & $item2, $iListView)
Next

GUICtrlCreateButton('Button', 10, 340, 70, 20)

$dummy1 = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, "_Exit")
$dummy2 = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, "_SaveChange")
Global $AccelKeys[2][2] = [["{ESC}", $dummy1],["{ENTER}", $dummy2]]
GUISetAccelerators($AccelKeys)
GUISetState()
GUIRegisterMsg(0x4E, "_WM_NOTIFY")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND") ; to hide the input field with a loss of focus

While 1
 Sleep(100000)
WEnd

; Displays Input element to the fore
Func _GUICtrlListView_EditItem($hWnd, $iIndex, $iSubItem)
 ;funkey 19.02.2010
 If $iIndex < 0 Then Return
 Local $aPos, $aRect, $iSum = 0
 Local $x, $y, $w, $h
 For $i = 0 To $iSubItem - 1
  $iSum += _GUICtrlListView_GetColumnWidth($hWnd, $i)
 Next
 $aRect = _GUICtrlListView_GetItemRect($hWnd, $iIndex)
 $aPos = ControlGetPos($hGUI, "", $hWnd)
 $x = $iSum + $aPos[0] + $aRect[0]
 $y = $aPos[1] + $aRect[1]
 $w = _GUICtrlListView_GetColumnWidth($hWnd, $iSubItem)
 $h = $aRect[3] - $aRect[1]
 GUICtrlSetPos($iInput, $x - 1, $y + 1, $w + 1, $h + 1)
 GUICtrlSetData($iInput, _GUICtrlListView_GetItemText($hWnd, $iIndex, $iSubItem))
 GUICtrlSetState($iInput, $GUI_SHOW)
 GUICtrlSetState($iInput, $GUI_FOCUS)
 $aElement[0] = $iIndex
 $aElement[1] = $iSubItem
EndFunc

; Save changes to the item
Func _SaveChange()
 Local $sText = GUICtrlRead($iInput)
 If StringInStr($sText, @CR) Or StringInStr($sText, @LF) Then
  If StringLeft($sText, 1) <> '"' And StringInStr(StringMid($sText, 2, StringLen($sText) - 2), '"') Then $sText = StringReplace($sText, '"', "'")
  $sText = '"' & StringReplace($sText, '"', '') & '"'
 EndIf
 _GUICtrlListView_BeginUpdate($hActive)
 _GUICtrlListView_SetItemText($hActive, $aElement[0], $sText, $aElement[1])
 GUICtrlSetState($iInput, $GUI_HIDE)
 _GUICtrlListView_SetColumnWidth($hListView, $aElement[1], -2) ;$LVSCW_AUTOSIZE_USEHEADER
 _GUICtrlListView_EndUpdate($hActive)
 Return $sText ; return text if you want to use it
EndFunc

Func _WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
 Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR
 $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
 $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
 $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
 $iCode = DllStructGetData($tNMHDR, "Code")
 Switch $hWndFrom
  Case $hListView
   Switch $iCode
    Case $NM_DBLCLK ; Double click to edit ListView item
     Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
     _GUICtrlListView_EditItem($hListView, DllStructGetData($tInfo, "Index"), DllStructGetData($tInfo, "SubItem"))
     $hActive = $hListView
   EndSwitch
 EndSwitch
 Return $GUI_RUNDEFMSG
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
 #forceref $hWnd, $iMsg
 Local $iIDFrom, $iCode
 $iIDFrom = BitAND($iwParam, 0xFFFF) ; LoWord
 $iCode = BitShift($iwParam, 16) ; HiWord
 Switch $iIDFrom
  Case $iInput
   Switch $iCode
    Case $EN_KILLFOCUS
     GUICtrlSetState($iInput, $GUI_HIDE)
   EndSwitch
 EndSwitch
 Return $GUI_RUNDEFMSG
EndFunc

Func _Exit()
 Exit
EndFunc

Edited April 7, 2012 by AZJIO

[MrCreatoR]

Very good work, but the script crashed when one of the columns is very large.

It's crashed because of RegExp, here is an example:

$vTest = '"'

For $i = 1 To 5935 ;Change to 5934 and no crash
    $vTest &= '0'
Next

$vTest &= '"'

$aRet = StringRegExp($vTest, '([^"])*', 3) ;Or change the pattern to '([^"]*)'
ConsoleWrite("Result: " & $aRet[1] & @LF)

[meows]

498

Thanks for this! It is most helpfull

[poolcat]

I tried to create some CSV functions. All files I checked were parsed wihtout errors:

 

Edit: fixed a few errors in _ParseCSV

Hi Andy,

Thanks for the good work!

Theres a little thing in that could easily blow up the memory when working with large files. Change the last iteration in _parsecsv to this

        If $iSub = $iSubBound Then
            $iSubBound += 1
            ReDim $aResult[int($iBound/$iSubBound)+1][$iSubBound]
        EndIf

and all is good

Cheers.

[funkey]

Changed few things to run with actial version of AutoIt.

 

Download in first post.