Simple overlay

[krisddd]

I was wondering if anyone could help me or point me in the right direction with a project I'm trying to do.

Basically all I want to do is create a graphic overlay (a grid) on the screen and someone allow the user to adjust the size of the grid. The AutoIt script will the use the position and the size of the grid to accomplish the tasks I want. The grid would have to be transparent and the script should be allowed to click through it.

I did use search and I came across GhostIt which would allow me to accomplish this to some degree. I haven't tried it yet, but before I jump in head first, I wanted to see if there was possibly another approach I can take.

[Melba23]

krisddd,

Welcome to the Autoit forum.

From what I can see from the thread, GhostIt does not pass clicks. So drawing a GDI grid might be a better bet as this does allow clicks to pass.

Perhaps something like this:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

HotKeySet("{ESC}", "On_Exit")

Global $hGUI, $aRadio[5], $hButton, $iStep

$hGUI = GUICreate("Grid", 150, 190)

GUICtrlCreateLabel("Choose a grid step value", 10, 10, 150, 20)

GUIStartGroup()
For $i = 0 To 4
    $aRadio[$i] = GUICtrlCreateRadio(100 + ($i * 100), 55,  30 + ($i * 20), 100, 20)
Next
GUICtrlSetState($aRadio[0], $GUI_CHECKED)

$hButton = GUICtrlCreateButton("Show Grid", 35, 150, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            GUISetState(@SW_HIDE, $hGUI)
            For $i = 0 To 4
                If GUICtrlRead($aRadio[$i]) = 1 Then
                    $iStep = GUICtrlRead($aRadio[$i], 1)
                    ExitLoop
                EndIf
            Next
            Grid()
    EndSwitch

WEnd

; -------------

Func Grid()

    Local $iVerticals = Floor(@DesktopWidth / $iStep)
    Local $iHorizontals = Floor(@DesktopHeight / $iStep)

    Local $hRectangle_GUI = GUICreate("", @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUP, $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)
    GUISetBkColor(0x000000)

    Local $hMaster_Mask = _WinAPI_CreateRectRgn(0, 0, 0, 0)

    For $i = 0 To $iVerticals
        $hMask = _WinAPI_CreateRectRgn($i * $iStep, 0, ($i * $iStep) + 1,  @DesktopHeight)
        _WinAPI_CombineRgn($hMaster_Mask, $hMask, $hMaster_Mask, 2)
        _WinAPI_DeleteObject($hMask)
    Next

    For $i = 0 To $iHorizontals
        $hMask = _WinAPI_CreateRectRgn(0, $i * $iStep, @DesktopWidth, ($i * $iStep) + 1)
        _WinAPI_CombineRgn($hMaster_Mask, $hMask, $hMaster_Mask, 2)
        _WinAPI_DeleteObject($hMask)
    Next

    ; Set overall region
    _WinAPI_SetWindowRgn($hRectangle_GUI, $hMaster_Mask)

    GUISetState()

    While 1

        Sleep(10)

    WEnd

EndFunc   ;==>Grid

Func On_Exit()

    Exit

EndFunc

I hope that helps.

M23

[krisddd]

Thank you very much for your response. I will give this a try and let you know how it works out, but it does look promising.

And thanks, I've been meaning to join for a while, but the time just isn't there.

[uber125]

Thank you for this, it's almost exactly what I was looking for. 5stars

I only have one question. What value(s) are changed to tighten up the grid, I need something just a tad smaller then 100. I know this is resurrection, but I don't see the point in making anew post if question(s) is/are still relevant.

NVM I got it, thanks.

BTW in case anyone is wondering the same, try adjusting the numbers in the GUICtrlCreateRadio.

Edited April 1, 2011 by uber125