Choose Icon dialog UDF

[TomV]

Hi,

I'm new with DLL's, and this is my first UDF:

The UDF:

expandcollapse popup

; #FUNCTION# ;===============================================================================
;
; Name...........: _ChooseIcon
; Description ...: Let the user choose an icon from a file (*.dll or *.exe)
; Syntax.........: _ChooseIcon($Dll_File = "\shell32.dll")
; Parameters ....: $sDll_File - The DLL or EXE file what contains icons
; Return values .: Success - Returns the icon index
;                  Failure - Returns -1 and Sets @Error:
;                  |0 - No error.
;                  |1 - DLL/EXE file don't exists!
;                  |2 - Can not call the DLL file 'shell32.dll'
;                  |3 - Can not get DLL struct data!
; Author ........: Tom Valk
; Modified.......:
; Remarks .......:
; Related .......: _ChooseColor, _ChooseFont
; Link ..........;
; Example .......; Yes
;
; ;==========================================================================================
Func _ChooseIcon($sDll_File = "\shell32.dll")
    $sDll_File = @SystemDir & $sDll_File
    If Not FileExists($sDll_File) Then
        SetError(1)
        Return -1
    EndIf
    Local $sscInt = DllStructCreate("int")
    Local $sscString = DllStructCreate("wchar[260]")
    Local $sstructsize = DllStructGetSize($sscString) / 2
    DllStructSetData($sscString, 1, $sDll_File)
    DllCall("shell32.dll", "none", 62, "hwnd", 0, "ptr", DllStructGetPtr($sscString), "int", $sstructsize, "ptr", DllStructGetPtr($sscInt))
    If @error Then
        SetError(2)
        Return -1
    EndIf
    Local $nIconIndex = DllStructGetData($sscInt, 1)
    If @error <> 0 Then
        SetError(3)
        Return -1
    EndIf
    Return $nIconIndex
EndFunc   ;==>_ChooseIcon

An example:

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <IconChoose.au3>
Global $iIconIndex

; Example:

$iIconIndex = _ChooseIcon("\shell32.dll") ; Loads the DLL file: [@SystemDir]\shell32.dll

MsgBox(64, "_ChooseIcon Example", "Icon ID: " & $iIconIndex)

And if you like, you can add it to the Misc.au3 include file

Regards, Tom V

[MrCreatoR]

Has been done already, and with few more options (including proper error checking, wich is not the case in this function).

[Yashied]

This function also exists in WinAPI Extended UDF Library - _WinAPI_PickIconDlg().

[James]

Nice way to end the OP's year

Well done! Very good to see that you've been able to do this, however it's already been done before on several occasions. Perhaps you should check theirs out too?

[Dolemite50]

As far as first UDF's go, you really came out swinging. Nicely documented, clean code, functional script. You're definitely heading down the right track man, keep it up!

[Zedna]

Nice.

Just one note:

Instead of

DllCall("shell32.dll", "none", 62 ...

next time use

DllCall("shell32.dll", "none", "PickIconDlg" ...

Edited January 1, 2010 by Zedna

[trancexx]

Nice.

Just one note:

Instead of

next time use

You are wrong Zedna.

This function is better to call by ordinal. It's exported by name in version 6.0 or later of shell32.dll.

This way it's supported for all supporting systems for AutoIt.

[James]

You are wrong Zedna.

This function is better to call by ordinal. It's exported by name in version 6.0 or later of shell32.dll.

This way it's supported for all supporting systems for AutoIt.

Oh really? That is something to know. Where may you find the ordinal values?

[trancexx]

Oh really? That is something to know. Where may you find the ordinal values?

I'm using this nice script.

In fact that is very old version. The one I run is much faster. I should update that post.

... No, no I won't... yet.

[Zedna]

You are wrong Zedna.

This function is better to call by ordinal. It's exported by name in version 6.0 or later of shell32.dll.

This way it's supported for all supporting systems for AutoIt.

Interesting information.

As far as I know calling functions by their number is faster.

but on different OS that number (maybe) may change.

So I expect it's better to use name instead of number.

It's also better for code readability.

As about support for Shell version < 6.0 I think it's not much problem because Autoit dropped support for older Win9x OS systems.

[trancexx]

Interesting information.

As far as I know calling functions by their number is faster.

but on different OS that number (maybe) may change.

So I expect it's better to use name instead of number.

It's also better for code readability.

As about support for Shell version < 6.0 I think it's not much problem because Autoit dropped support for older Win9x OS systems.

For readability I suppose a comment explaining would be enough.

I believe XP (No SP) is below requirements.