How to clear or delete the scite console output

[wimhek]

After 1 hour of debugging, I found out that I was looking at the wrong Console output :-(

Question is : How to clear or delete the scite console output.

Q2. Can I clear the output from within an autoit script ?

[water]

A1: Shift + F5 (see under Tools)

A2: You can automate the SciTe window like any other window. So simply send Shift + F5 to the SciTe window

Edited November 21, 2009 by water

[BugFix]

I can't see the problem. If you run an script with output to console (ConsoleWrite), so are cleared the console everytime the script runs again.

[wimhek]

I can't see the problem. If you run an script with output to console (ConsoleWrite), so are cleared the console everytime the script runs again.

Nope, the output is appended at the end, and after running of the script the console window skips to the first line (and displays the errors)

Even after topping and starting scite, the log is not deleted.

[wimhek]

Thank You very much for your quick answer. Shift F5 indeed clearst the console output, but after running the script I got the old data back.

Edited November 21, 2009 by wimhek

[Jos]

This is a methode to clear to Output pane during script execution:

For $x = 1 to 100
    ConsoleWrite($x & @CRLF)
Next
ConsoleWrite("clear output in 1 sec" & @CRLF)
Sleep(1000)
SendSciTE_Command("menucommand:420") ; Clear Output pane "IDM_CLEAROUTPUT"
ConsoleWrite("cleared" & @CRLF)
For $x = 1 to 100
    ConsoleWrite($x & @CRLF)
Next
Exit
;
; Send command to SciTE
Func SendSciTE_Command($sCmd)
    Local $Scite_hwnd = WinGetHandle("DirectorExtension")
    Local $WM_COPYDATA = 74
    Local $CmdStruct = DllStructCreate('Char[' & StringLen($sCmd) + 1 & ']')
    DllStructSetData($CmdStruct, 1, $sCmd)
    Local $COPYDATA = DllStructCreate('Ptr;DWord;Ptr')
    DllStructSetData($COPYDATA, 1, 1)
    DllStructSetData($COPYDATA, 2, StringLen($sCmd) + 1)
    DllStructSetData($COPYDATA, 3, DllStructGetPtr($CmdStruct))
    DllCall('User32.dll', 'None', 'SendMessage', 'HWnd', $Scite_hwnd, _
            'Int', $WM_COPYDATA, 'HWnd', 0, _
            'Ptr', DllStructGetPtr($COPYDATA))
EndFunc   ;==>SendSciTE_Command

Jos

Edited November 21, 2009 by Jos

[wimhek]

Thank you , this works. Ik wil put this solution into MYUDF an implement it standard on all my scripts :-)