Communicating multiple Autoit.exe Scripts

[arryo]

Hiii,

How can I script that multiple (at the same time) running autoit scripts can communicate with each other? Cause I made an Autoit-GUI and when I do an action with that, then it won't do anything until the action is finished.

The goal is:

1. Start "Main Autoit.exe" -> GUI

Example: "Start" on Main Autoit.exe clicked -> 2. Start "lolbot Autoit.exe" -> sets, for example, opens firefox, sets $x = htmlcode of google page.

3. "Main Autoit.exe" recognizes when "lolbot Autoit.exe" is finished and then gets the variable $x.

4. Closes "lolbot Autoit.exe" & updates "Main Autoit.exe" with the new informations.

How is that possible?

[Yashied]

http://www.autoitscript.com/forum/index.php?showtopic=91346

[arryo]

http://www.autoitscript.com/forum/index.php?showtopic=91346

love you =)

[arryo]

Hmm, could you please show me a simple example? =( The example in your script is a bit to complicated for me.

My 2 scripts:

test.au3:

#Include <Messages.au3>
#Include <Array.au3>

Run("test2.exe")

_MsgRegister('logincheck1', 'lol1')


    
func lol2()
Msgbox(1, "lol", "received something. test2")
EndFunc



While True
Sleep(1000)
_MsgSend("logincheck2", "lol2" )
WEnd

test2.au3:

#Include <Messages.au3>

$lol = _MsgRegister('logincheck2', 'lol2')


        
        
        
func _Receiver($lol)
Msgbox(1, "lol", "received something.")
EndFunc

func lol2()
Msgbox(1, "lol", "received something. test2")
EndFunc


While True
WEnd

(ofc i compiled them).

[Melba23]

arryo,

I developed this from Yashied's script so I could understand what was going on myself. Just compile it and then run it twice:

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseUpx=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
; Based on code from Yashied

#include <GUIConstantsEx.au3>

Opt("WinTitleMatchMode", 3)

Global Const $WM_COPYDATA = 0x004A
Global $sThis_Win_Title, $sThat_Win_Title
Global $iY, $hInput, $hButton, $hLabel
Global $sMsg_To_Send, $sMsg_Rcvd, $sMsg_Set = ""

; Set GUI title
If WinExists("First Instance") Then
    If WinExists("Second Instance") Then Exit
    $sThis_Win_Title = "Second Instance"
    $sThat_Win_Title = "First Instance"
    $iY = 300
Else
    $sThis_Win_Title = "First Instance"
    $sThat_Win_Title = "Second Instance"
    $iY = 100
EndIf

; Create GUI
GUICreate($sThis_Win_Title, 400, 150, 100, $iY)

$hInput = GUICtrlCreateInput("", 20, 20, 360, 20)
$hButton = GUICtrlCreateButton("Send", 160, 60, 80, 30)
$hLabel = GUICtrlCreateLabel("", 20, 100, 360, 20)

GUIRegisterMsg($WM_COPYDATA, "_WM_COPYDATA")

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ; Send close message to other window
            _SendData(WinGetHandle($sThat_Win_Title), "@exit")
            Exit
        Case $hButton
            ; Send message to other window
            $sMsg_To_Send = GUICtrlRead($hInput)
            $hWnd = WinGetHandle($sThat_Win_Title)
            If (Not @error) And ($sMsg_To_Send <> "") Then _SendData($hWnd, $sMsg_To_Send)
    EndSwitch

    ; Check messages received
    If $sMsg_Rcvd = "@exit" Then Exit
    If $sMsg_Rcvd <> $sMsg_Set Then
        GUICtrlSetData($hLabel, $sMsg_Rcvd)
        $sMsg_Set = $sMsg_Rcvd
    EndIf

WEnd

Func _SendData($hWnd, $sData)

    Local $tCOPYDATA, $tMsg

    $tMsg = DllStructCreate("char[" & StringLen($sData) + 1 & "]")
    DllStructSetData($tMsg, 1, $sData)
    $tCOPYDATA = DllStructCreate("dword;dword;ptr")
    DllStructSetData($tCOPYDATA, 2, StringLen($sData) + 1)
    DllStructSetData($tCOPYDATA, 3, DllStructGetPtr($tMsg))
    $Ret = DllCall("user32.dll", "lparam", "SendMessage", "hwnd", $hWnd, "int", $WM_COPYDATA, "wparam", 0, "lparam", DllStructGetPtr($tCOPYDATA))
    If (@error) Or ($Ret[0] = -1) Then Return 0
    Return 1

EndFunc   ;==>_SendData

Func _WM_COPYDATA($hWnd, $msgID, $wParam, $lParam)

    Local $tCOPYDATA = DllStructCreate("dword;dword;ptr", $lParam)
    Local $tMsg = DllStructCreate("char[" & DllStructGetData($tCOPYDATA, 2) & "]", DllStructGetData($tCOPYDATA, 3))
    $sMsg_Rcvd = DllStructGetData($tMsg, 1)
    Return 0

EndFunc   ;==>_WM_COPYDATA

M23

[Yashied]

Script1.au3

#Include <Messages.au3>

_MsgRegister('Script1', '_MyReceiver1')

$i = 0

While 1
    If _IsReceiver('Script2') Then
        $i += 1
        _MsgSend('Script2', String($i))
    EndIf
    Sleep(4000)
WEnd

Func _MyReceiver1($sMessage)
    MsgBox(0, 'Script1', $sMessage, 1)
EndFunc   ;==>_MyReceiver1

Script2.au3

#Include <Messages.au3>

_MsgRegister('Script2', '_MyReceiver2')

$i = 0

While 1
    If _IsReceiver('Script1') Then
        $i += 1
        _MsgSend('Script1', String($i))
    EndIf
    Sleep(4000)
WEnd

Func _MyReceiver2($sMessage)
    MsgBox(0, 'Script2', $sMessage, 1)
EndFunc   ;==>_MyReceiver2

[Xenobiologist]

Hi,

you can also write something into e.g. a file and loop whether the status is written, or let the scripts communicate via tcp. (see Chat)

Mega

[Yashied]

Another way.

http://www.autoitscript.com/forum/index.php?showtopic=100500&view=findpost&p=718637