Value of 0 = "" ?

[ken82m]

Maybe I'm crazy

If I store the 0 as a string it works fine but as a number the field is read as empty.

#include <Array.au3>
Dim $array[5]
$Array[0] = 1
$Array[1] = 2
$Array[2] = 3
$Array[3] = 0
$Array[4] = 5
_ArrayDisplay($array)
For $i = 0 To 4
If $array[$i] = "" Then MsgBox(0,$i & " is blank", $array[$i])
Next
Exit

[jvanegmond]

Try this:

#include <Array.au3>
Dim $array[5]
$Array[0] = 1
$Array[1] = 2
$Array[2] = 3
$Array[3] = 0
$Array[4] = 5
_ArrayDisplay($array)
For $i = 0 To 4
If $array[$i] == "" Then MsgBox(0,$i & " is blank", $array[$i])
Next
Exit

Behavior of the "simple" comparison using one = comparison has always surprised me. Therefore I choose to use the == comparison which is much simpler to understand and to use.

[ken82m]

Interesting never heard of that one. Learn a little more of the increased level of my stupidity everyday lol

I wanted to smash my had against the wall with this lastnight lol

Thanks

Edited March 13, 2009 by ken82m

[Spiff59]

I'd posted to have the documentation corrected a while back.

Feature Request (Documentation)

Autoit's documentation ought to fully describe the difference between = and ==.

[ken82m]

yeah definitely a good little tidbit for the book.

I mean unless your a die hard programmer or already killed yoruself on this one who's gonna know.

And from the looks of it, it's the only exception to the quick summary they give so couldn't hurt to add an extra line.

[jvanegmond]

I think the more common rule to describe this behavior is that the strings to compare them with are converted into numbers if they only contain numbers.

For example these are all true:

3 = "3"

2 = "2"

1 = "1"

0 = ""

since "" evaluates 0 .. It is an exception because there is nothing in the string. But 0 is nothing too so, it is correct in one way or another.

[GEOSoft]

In a case like that you can also use String() to get valid results as well. Yes...it's in the help file.

#include <Array.au3>
Dim $array[5]
$Array[0] = 1
$Array[1] = 2
$Array[2] = 3
$Array[3] = 0
$Array[4] = 5
_ArrayDisplay($array)
For $i = 0 To 4
If String($array[$i]) = "" Then MsgBox(0,$i & " is blank", $array[$i])
Next
Exit

[PsaltyDS]

Interesting never heard of that one. Learn a little more of the increased level of my stupidity everyday lol

I wanted to smash my had against the wall with this lastnight lol

Thanks

Before you make bloody forehead prints on the wall, think about where this comes from.

AutoIt is meant to be an easy to use scripting language for people (like me) who are not "real" programmers. So the Devs have spent much effort keeping you from having to worry about one of the central headaches of "real" programming: strict variable typing.

In many (most!) languages, what you did will actually fail to compile or run at all or crash the executable because you compared an integer type to a string type without converting to matching types first. AutoIt tries to keep you from worrying too much about variable types by performing automated type conversions. You are seeing a (documented, if you look for it) side effect of that automatic type conversion in AutoIt.

[Spiff59]

I went throught the same grief as the OP a couple months ago trying to get Autoit to distinguish between an ASCII "0" and a NULL.

I still consider the feature undocumented, since I didn't find it when I went looking. I wanted to know how Autoit arithmetic/comparison operators behaved and went to the "Language Reference - Operators" page in the helpfile. The difference between the = and == operators is not described there. I'd think adding just a few words on that page would make the helpfile more accurate, and save a few forum questions a year.

While I'm on the subject of documentation <wink>: The "wildcards" topic under FileFindFirstFile needs a major rewrite. It is way off base!

(PS - I'm not trying to point out flaws as some sort of 'gotcha', I'm detail-oriented, and just wanting Autoit to be the best it can be.)

[PsaltyDS]

I went throught the same grief as the OP a couple months ago trying to get Autoit to distinguish between an ASCII "0" and a NULL.

I still consider the feature undocumented, since I didn't find it when I went looking. I wanted to know how Autoit arithmetic/comparison operators behaved and went to the "Language Reference - Operators" page in the helpfile. The difference between the = and == operators is not described there. I'd think adding just a few words on that page would make the helpfile more accurate, and save a few forum questions a year.

While I'm on the subject of documentation <wink>: The "wildcards" topic under FileFindFirstFile needs a major rewrite. It is way off base!

(PS - I'm not trying to point out flaws as some sort of 'gotcha', I'm detail-oriented, and just wanting Autoit to be the best it can be.)

Pointing out flaws, especially if they come with some thought and a proposed solution (like a proposed new verbiage for the help file entry) are not a problem. In fact, that would be good forum citizenship. You could best do that by creating a new ticket on Bug Trac, identifying the component as "Documentation".

Don't be too hurt if the change is rejected (not that it's inevitable). The Operators section now says:

== Tests if two values are equal (case sensitive if used with strings)

The behavior some users are not expecting is the automatic type conversion that occurs. If you use just '=' and a number is one of the values, then type conversion to a number is done the other value. If you use '==', which is only used for case-sensitive string compares, then it forces conversion of both values to strings for the compare. The confusion is not the operator, which does exactly what it says, but with AutoIt's automatic conversion of values. Perhaps that could use some more documentation.

Edit: Demo of the difference in conversion results:

; Numeric compares with '='
;   Treats each example like:  0 = Number($x)
ConsoleWrite((0 = 0) & @LF); True
ConsoleWrite((0 = "0.0") & @LF); True
ConsoleWrite((0 = "0") & @LF); True
ConsoleWrite((0 = "") & @LF); True 
ConsoleWrite((0 = ".") & @LF); True
ConsoleWrite((0 = "zero") & @LF); True
ConsoleWrite((0 = "") & @LF); True
ConsoleWrite((0 = Chr(0)) & @LF); True

ConsoleWrite(@LF)

; String compares with '=='
;   Treats each example like:  String($x) == String($y)
ConsoleWrite((0 == 0) & @LF); True
ConsoleWrite((0 == "0.0") & @LF); False
ConsoleWrite((0 == "0") & @LF); True
ConsoleWrite((0 == "") & @LF); False 
ConsoleWrite((0 == ".") & @LF); False
ConsoleWrite((0 == "zero") & @LF); False
ConsoleWrite((0 == "") & @LF); False
ConsoleWrite((0 == Chr(0)) & @LF); False

Note the second case in the second group, where 0 == "0.0" is FALSE.

Edit2: Added null examples to the demo.

Edited March 13, 2009 by PsaltyDS

[Richard Robertson]

I can't remember if AutoIt has this or not, but some languages like javascript, where variables are variants, have an operator ===. It is a type strict comparison.

[Spiff59]

Maybe I'll try a Bug Trac (if it will let me in) and suggest the "Language Reference - Operators" state the following:

= Tests if two values are equal (case insensitive, zero and null treated as equal).

== Tests if two values are equal (case sensitive, zero and null treated as not equal).

That page need not delve into explaining why operators work as they do, but it ought to describe what results to expect when you employ one of them.

[PhilRip]

I can't remember if AutoIt has this or not, but some languages like javascript, where variables are variants, have an operator ===. It is a type strict comparison.

no, there is no === in autoit

[Richard Robertson]

Ok. And for the reference, there is no null either. So stop saying null.

[ProgAndy]

no, there is no === in autoit

You can create a func for this:

Func TYPEEQUAL(ByRef $Var1, ByRef $Var2)
    ; Prog@ndy
    Switch (VarGetType($Var1) == VarGetType($Var2))
        Case True
            Return $Var1==$Var2
        Case Else
            Return False
    EndSwitch
EndFunc

[Spiff59]

Ok. And for the reference, there is no null either. So stop saying null.

Isn't there both a null character, Chr(0), and a null string (empty)?

$x = Chr(0) & Chr(0); 2-character string
$y = 0
$z = ""
If $x = $y then beep(500,1000)
Sleep(100)
If $x = $z then beep(500,1000)
Sleep(100)
If $y = $z then beep(500,1000)
Sleep(100)
If $x == $y then beep(1000,500)
Sleep(100)
If $x == $z then beep(1000,500)
Sleep(100)
If $y == $z then beep(1000,500)

Edit: All 3 variables test True with =, and all 3 false with ==

Edited March 13, 2009 by Spiff59

[GEOSoft]

0 is not a NUL character. NUL is the ascii code 0 not the number 0 which is actually ascii code 48.

[Spiff59]

0 is not a NUL character. NUL is the ascii code 0 not the number 0 which is actually ascii code 48.

I didn't say it was, but you agree there is a null character, Chr(0).

And Chr(0) equates to both a Chr(48) and an empty string when using the '=" operator.

All three values equate as True with =, and none of them equate via ==.

The "operators" documentation states the only difference between = and == is case-sensitivity.

That's all my argument is, that the documentation is not true, and that a few added words could clarify things.

Edit: typo

Edited March 13, 2009 by Spiff59

[Richard Robertson]

And "" is not a null string. It's an empty string. A null string doesn't even have "" in it.

[Spiff59]

And "" is not a null string. It's an empty string. A null string doesn't even have "" in it.

I'm not going to touch that one.