Set Drag & Drop items for your ListBox'es

[MrCreatoR]

Hi,

This script was inspired by the example of PaulIA here.

I made it easy to set dragable items for specific ListBox control, you can unset them to

Here is an example:

#include <GuiConstantsEx.au3>
#include <DragList_UDF.au3>

$hGUI = GUICreate("_DragList_... Demo", 400, 200)

$nList1 = GUICtrlCreateList("", 20, 10, 160, 140, $WS_BORDER+$WS_VSCROLL)
GUICtrlSetData($nList1, "Hi,|How|Are|You?")

$nList2 = GUICtrlCreateList("", 220, 10, 160, 140, $WS_BORDER+$WS_VSCROLL)
GUICtrlSetData($nList2, "AutoIt|Is|The|Best!")

$SetList1_CheckBox = GUICtrlCreateCheckBox("Set List 1", 60, 160, 70, 20)
$SetList2_CheckBox = GUICtrlCreateCheckBox("Set List 2", 260, 160, 70, 20)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $SetList1_CheckBox
            If GUICtrlRead($SetList1_CheckBox) = $GUI_CHECKED Then
                _DragList_SetList($nList1, $hGUI)
            Else
                _DragList_SetList($nList1)
            EndIf
        Case $SetList2_CheckBox
            If GUICtrlRead($SetList2_CheckBox) = $GUI_CHECKED Then
                _DragList_SetList($nList2, $hGUI)
            Else
                _DragList_SetList($nList2)
            EndIf
    EndSwitch
Wend

Just set the checkboxes, and try to drag the items .

This example + DragList_UDF.au3 (functions and the main handler) attached as zip file:

_DragList_UDF.zip

Enjoy!

Edited October 5, 2008 by MrCreatoR

[Andreik]

Yeah, very good example. I like that arrow . Good work MrCreatoR.

[ludocus]

Good job!!..

works fine.

[ken82m]

Exactly what I was looking for. As always thank you

[ken82m]

is it possible to select lets say a group of 5 items and move them all at once?

[xeroTechnologiesLLC]

Masterful - very well done.

[BrewManNH]

You shouldn't be commenting on every ancient topic that helps you. Necroposting is a big no-no.

[Spenhouet]

Does this work with ListView? When i use it...my list is frozen...

[Melba23]

Spenhouet,

No, this UDF deals with ListBoxes - ListViews are a very different beast. If you want to drag items within a ListView, take a look at the GUIListViewEx UDF in my sig.

M23

[Leo1906]

This doens't work if you compile the script for x64 Systems ..
Does anyone knows a solution?

[LarsJ]

Replace the old version of _DragList_GetItemFromPoint with this new version:

#cs
Func _DragList_GetItemFromPoint($hList, $stPoint, $iAutoscroll = 0)
  ;The return value contains the index of the nearest item in the low-order word.
  ;The high-order word is zero if the specified point is in the client area of the list box,
  ;or one if it is outside the client area.>>>Note. this call to sendmessage always results in the same number<<<
  Local $iX = DllStructGetData($stPoint, 1)
  Local $iY = DllStructGetData($stPoint, 2)
  
  Local $aRet = DllCall("comctl32.dll", "int", "LBItemFromPt", "hwnd", $hList, "int", $iX, "int", $iY,  "int", $iAutoscroll)
  Return $aRet[0]
EndFunc
#ce

Func _DragList_GetItemFromPoint($hList, $stPoint, $iAutoscroll = 0)
  ;The return value contains the index of the nearest item in the low-order word.
  ;The high-order word is zero if the specified point is in the client area of the list box,
  ;or one if it is outside the client area.>>>Note. this call to sendmessage always results in the same number<<<
  Local $tPOINT64 = DllStructCreate( "int64", DllStructGetPtr( $stPoint ) )
  
  Local $aRet = DllCall("comctl32.dll", "int", "LBItemFromPt", "hwnd", $hList, "int64", DllStructGetData( $tPOINT64, 1 ), "int", $iAutoscroll)
  Return $aRet[0]
EndFunc

The new version works on both 32 and 64 bit.

[Leo1906]

2 hours ago, LarsJ said:

Replace the old version of _DragList_GetItemFromPoint with this new version:

#cs
Func _DragList_GetItemFromPoint($hList, $stPoint, $iAutoscroll = 0)
  ;The return value contains the index of the nearest item in the low-order word.
  ;The high-order word is zero if the specified point is in the client area of the list box,
  ;or one if it is outside the client area.>>>Note. this call to sendmessage always results in the same number<<<
  Local $iX = DllStructGetData($stPoint, 1)
  Local $iY = DllStructGetData($stPoint, 2)
  
  Local $aRet = DllCall("comctl32.dll", "int", "LBItemFromPt", "hwnd", $hList, "int", $iX, "int", $iY,  "int", $iAutoscroll)
  Return $aRet[0]
EndFunc
#ce

Func _DragList_GetItemFromPoint($hList, $stPoint, $iAutoscroll = 0)
  ;The return value contains the index of the nearest item in the low-order word.
  ;The high-order word is zero if the specified point is in the client area of the list box,
  ;or one if it is outside the client area.>>>Note. this call to sendmessage always results in the same number<<<
  Local $tPOINT64 = DllStructCreate( "int64", DllStructGetPtr( $stPoint ) )
  
  Local $aRet = DllCall("comctl32.dll", "int", "LBItemFromPt", "hwnd", $hList, "int64", DllStructGetData( $tPOINT64, 1 ), "int", $iAutoscroll)
  Return $aRet[0]
EndFunc

The new version works on both 32 and 64 bit.

Wow! Thanks for that

But now I have a different kind of problem.
When using this UDF it seems like the style $LBS_EXTENDEDSEL has to be turned off in order to see what item is selected. (blue highlighted)

But I need to create the ListBox with this style: 

$List = GUICtrlCreateList("", 40, 104, 193, 227, BitOR($WS_BORDER, $WS_VSCROLL, $LBS_EXTENDEDSEL))

to use some functions like "_GUICtrlListBox_GetSelItems($List)"

Any suggestions on this one?

[x_bennY]

why i cant move the item to the last position?

[JLogan3o13]

@x_bennY do you honestly believe this is enough information for someone to help you?? How about providing your code, rather than asking us to guess?

[x_bennY]

@JLogan3o13 sorry... i'm using the script posted here, and it works very well, but when i try do move some of the items in the listbox to the last position it doesn't move!

[LarsJ]

This is not an error. The code is designed to work that way.

When you move items in a listbox with the mouse, you can either drop items above or below the target item. Here it's chosen to drop items above the target item with the consequence that you cannot drop items below last item (only above last item).

You could also have chosen to drop items below the target item. Then there would have been a similar problem with the first item.

Solution. Drop your item just above the last item. Move the last item one item up.

[x_bennY]

I found a solution searching here on autoit forum.

 

expandcollapse popup

#include <Constants.au3>
#include <GUIListBox.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $gnDRAGLISTMSGSTRING = _WinAPI_RegisterWindowMessage("commctrl_DragListMsg")
Global $DL_BEGINDRAG = $WM_USER + 133
Global $DL_DRAGGING = $WM_USER + 134
Global $DL_DROPPED = $WM_USER + 135
Global $DL_CANCELDRAG = $WM_USER + 136
Global Enum $DL_STOPCURSOR = 1, $DL_COPYCURSOR, $DL_MOVECURSOR
Global $gtDRAGLISTINFO = "long uNotification;long hWnd;long x;long y"
Global $gfItemAdded = False

Global $hMain = GUICreate("DragList", 200, 400)
Global $cListbox = GUICtrlCreateList("", 16, 16, 168, 368, $WS_BORDER + $WS_VSCROLL)
GUICtrlSetFont($cListbox, 10, Default, Default, "Tahoma")
Global $hListbox = GUICtrlGetHandle($cListbox)
GUICtrlSetData($cListbox, "Apples|Oranges|Bananas|Pears|Grapefruits|Limes|Lemons|Strawberries|Plums|Melons|Grapes|")
GUISetState()

_ComCtl32_MakeDragList($hListbox)

Global $wProcNew = DllCallbackRegister("_MyWndProc", "int", "hwnd;int;wparam;lparam")
Global $wProcOld = _WinAPI_SetWindowLong($hMain, $GWL_WNDPROC, DllCallbackGetPtr($wProcNew))


While GUIGetMsg() <> -3
    Sleep(10)
Wend

_WinAPI_SetWindowLong($hMain, $GWL_WNDPROC, DllCallbackGetPtr($wProcOld))
Exit

Func _MyWndProc($hWnd, $nMsg, $wParam, $lParam)
    Local $aRet, $nOldIndex, $sItemText
    If $nMsg = $gnDRAGLISTMSGSTRING Then
        Local $tDRAGLISTINFO = DllStructCreate($gtDRAGLISTINFO, $lParam)
        Local $uNotification = DllStructGetData($tDRAGLISTINFO, "uNotification")
        Local $x = DllStructGetData($tDRAGLISTINFO, "x"), $y = DllStructGetData($tDRAGLISTINFO, "y")
        Local $nItem = _ComCtl32_LBItemFromPt($hListbox, $x, $y)
        Switch $uNotification
            Case $DL_BEGINDRAG
                If $nItem < (_GUICtrlListBox_GetCount($hListbox) - 1) Then
                    _GUICtrlListBox_AddString($hListbox, "")
                    $gfItemAdded = True
                EndIf
                Return 1
            Case $DL_DRAGGING
                _ComCtl32_DrawInsert($hMain, $hListbox, $nItem)
                If $nItem = _GUICtrlListBox_GetCurSel($hListbox) Then Return $DL_STOPCURSOR
                Return $DL_MOVECURSOR
            Case $DL_DROPPED
                If $nItem > -1 Then
                    $nOldIndex = _GUICtrlListBox_GetCurSel($hListbox)
                    If $nItem <> $nOldIndex Then
                        $sItemText = _GUICtrlListBox_GetText($hListbox, $nOldIndex)
                        If $nItem < $nOldIndex Then $nOldIndex += 1
                        _GUICtrlListBox_InsertString($hListbox, $sItemText, $nItem)
                        _GUICtrlListBox_DeleteString($hListbox, $nOldIndex)
                        If $nItem > $nOldIndex Then $nItem -= 1
                        _GUICtrlListBox_SetCurSel($hListbox, $nItem)
                    EndIf
                EndIf
                If $gfItemAdded Then
                    _GUICtrlListBox_DeleteString($hListbox, _GUICtrlListBox_GetCount($hListbox) - 1)
                    $gfItemAdded = False
                EndIF
                _ComCtl32_DrawInsert($hMain, $hListbox, -1)
                Return 0
            Case $DL_CANCELDRAG
                If $gfItemAdded Then
                    _GUICtrlListBox_DeleteString($hListbox, _GUICtrlListBox_GetCount($hListbox) - 1)
                    $gfItemAdded = False
                EndIF
                _ComCtl32_DrawInsert($hMain, $hListbox, -1)
                Return 0
        EndSwitch
    EndIf
    Return _WinAPI_CallWindowProc($wProcOld, $hWnd, $nMsg, $wParam, $lParam)
EndFunc

Func _ComCtl32_MakeDragList($hWnd)
    Local $aRet = DllCall("comctl32.dll", "int", "MakeDragList", "hwnd", $hWnd)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aRet[0]
EndFunc

Func _ComCtl32_LBItemFromPt($hWnd, $x, $y)
    Local $aRet = DllCall("comctl32.dll", "long", "LBItemFromPt", "hwnd", $hWnd, "long", $x, "long", $y, "long", 1)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aRet[0]
EndFunc

Func _ComCtl32_DrawInsert($hWndParent, $hWnd, $nItem)
    DllCall("comctl32.dll", "none", "DrawInsert", "hwnd", $hWndParent, "hwnd", $hWnd, "long", $nItem)
    If @error Then Return SetError(@error, @extended, 0)
    Return
EndFunc