Re-sizable edit

[AustrianOak]

How can I make a resizeable edit where I can take the corner and drag it in or out to make it larger or smaller. I don't know if I saw the style or not in the helpfile so I need some help.

Edited July 10, 2008 by nowagain

[big_daddy]

You can use GUICtrlSetResizing to have it resize along with the GUI.

[AustrianOak]

But will this "manually" allow me to re-size it. I think I know what you're getting at but my situation is different and the gui size does not matter.

[MrCreatoR]

Ok, here is a prototype of resizable control (tested only with Edit control)...

expandcollapse popup

#include <GuiConstantsEx.au3>

$hGUI = GUICreate("Resizable GUI Ctrl - Example", 300, 200)

$Edit = GUICtrlCreateEdit("", 20, 40, 260, 120)

GUISetState(@SW_SHOW, $hGUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            _GUICtrl_SetResize($Edit, 5, 20, $hGUI)
    EndSwitch
WEnd

Func _GUICtrl_SetResize($nCtrlID, $iDefaultCurID, $iWait=10, $hWnd=0)
    Local $aCurInfo = GUIGetCursorInfo($hGUI)
    If @error Then Return
    
    Local $aCtrlInfo = ControlGetPos($hGUI, "", $nCtrlID)
    If @error Then Return
    
    Local $iCursorID, $iCheckFlag = -1
    
    If ($aCurInfo[0] > $aCtrlInfo[0]-2 And $aCurInfo[0] < $aCtrlInfo[0]+2) And _
        ($aCurInfo[1] >= $aCtrlInfo[1] And $aCurInfo[1] <= $aCtrlInfo[1]+$aCtrlInfo[3]) Then ;Left
        
        $iCheckFlag = 1
        $iCursorID = 13
    EndIf
    
    If ($aCurInfo[0] > ($aCtrlInfo[0]+$aCtrlInfo[2])-2 And $aCurInfo[0] < ($aCtrlInfo[0]+$aCtrlInfo[2])+2) And _
        ($aCurInfo[1] >= $aCtrlInfo[1] And $aCurInfo[1] <= $aCtrlInfo[1]+$aCtrlInfo[3]) Then ;Right
        
        $iCheckFlag = 2
        $iCursorID = 13
    EndIf
    
    If ($aCurInfo[1] > $aCtrlInfo[1]-2 And $aCurInfo[1] < $aCtrlInfo[1]+2) And _
        ($aCurInfo[0] >= $aCtrlInfo[0] And $aCurInfo[0] <= $aCtrlInfo[0]+$aCtrlInfo[2]) Then ;Top
        
        If $iCheckFlag = 1 Then ;Left+Top
            $iCheckFlag = 5
            $iCursorID = 12
        ElseIf $iCheckFlag = 2 Then ;Right+Top
            $iCheckFlag = 7
            $iCursorID = 10
        Else ;Just Top
            $iCheckFlag = 3
            $iCursorID = 11
        EndIf
    EndIf
    
    If ($aCurInfo[1] > ($aCtrlInfo[1]+$aCtrlInfo[3])-2 And $aCurInfo[1] < ($aCtrlInfo[1]+$aCtrlInfo[3])+2) And _
        ($aCurInfo[0] >= $aCtrlInfo[0] And $aCurInfo[0] <= $aCtrlInfo[0]+$aCtrlInfo[2]) Then ;Bottom
        
        If $iCheckFlag = 1 Then ;Left+Bottom
            $iCheckFlag = 6
            $iCursorID = 10
        ElseIf $iCheckFlag = 2 Then ;Right+Bottom
            $iCheckFlag = 8
            $iCursorID = 12
        Else ;Just Bottom
            $iCheckFlag = 4
            $iCursorID = 11
        EndIf
    EndIf
    
    If $iCheckFlag = -1 Then
        GUICtrlSetCursor($nCtrlID, $iDefaultCurID)
        GUISetCursor(-1, 1, $hGUI)
        
        Return
    Else
        GUICtrlSetCursor($nCtrlID, $iCursorID)
        GUISetCursor($iCursorID, 1, $hGUI)
    EndIf
    
    While $aCurInfo[2] = 1
        $aCurInfo = GUIGetCursorInfo($hGUI)
        If @error Then ExitLoop
        
        $aCtrlInfo = ControlGetPos($hGUI, "", $nCtrlID)
        If @error Then ExitLoop
        
        GUISetState(@SW_LOCK)
        
        If $iCheckFlag = 1 Or $iCheckFlag = 5 Or $iCheckFlag = 6 Then ;Left
            If $aCtrlInfo[2] - ($aCurInfo[0]-$aCtrlInfo[0]) > 20 Then _
                GUICtrlSetPos($nCtrlID, $aCurInfo[0], -1, $aCtrlInfo[2] - ($aCurInfo[0]-$aCtrlInfo[0]))
        EndIf
        
        If $iCheckFlag = 2 Or $iCheckFlag = 7 Or $iCheckFlag = 8 Then ;Right
            If $aCurInfo[0] - $aCtrlInfo[0] > 20 Then _
                GUICtrlSetPos($nCtrlID, -1, -1, $aCurInfo[0]-$aCtrlInfo[0])
        EndIf
        
        If $iCheckFlag = 3 Or $iCheckFlag = 5 Or $iCheckFlag = 7 Then ;Top
            If $aCtrlInfo[3] - ($aCurInfo[1]-$aCtrlInfo[1]) > 20 Then _
                GUICtrlSetPos($nCtrlID, -1, $aCurInfo[1], -1, $aCtrlInfo[3] - ($aCurInfo[1]-$aCtrlInfo[1]))
        EndIf
        
        If $iCheckFlag = 4 Or $iCheckFlag = 6 Or $iCheckFlag = 8 Then ;Bottom
            If $aCurInfo[1] - $aCtrlInfo[1] > 20 Then _
                GUICtrlSetPos($nCtrlID, -1, -1, -1, $aCurInfo[1]-$aCtrlInfo[1])
        EndIf
        
        GUISetState(@SW_UNLOCK)
        
        Sleep($iWait)
    WEnd
EndFunc

Needs more polishing, for example if you resize the control to out of the GUI borders and leave it there, you will not be able to resize back muttley - there is need to add some type of limit control... But it works

Edited April 7, 2011 by MrCreatoR

[AustrianOak]

Thank you MsCreator!

i will try to make it re-sizeable at the corner

[MrCreatoR]

i will try to make it re-sizeable at the corner

It is already muttley

And i made a UDF from it: GUICtrl_SetResizing - UDF!

[AustrianOak]

This is great! I posted on your UDF topic.

Thanks for all your help.

Edited July 12, 2008 by nowagain