GUICtrlCreateInput - Disable copy/ paste, right click menu and balloon pop-up

[Anoop]

Hello All,

I am creating a simple GUI app, in which, I have an input box which is accepting DECIMAL values only.

I would like to block the following functionalities related to the input box (only this input box) -

• Copy paste functionality
• Prevent from displaying the menu when right clicking
• It displays a balloon pop-up when trying to enter non-decimal characters. I need to block it also.

Are these possible ? Can someone give pointers for doing this? Thanks for helping.

 

[LarsJ]

The explanations are much more complicated than the code. Here's the code:

expandcollapse popup

#include <GUIConstants.au3>
#include <WinAPIShellEx.au3>
#include <GuiEdit.au3>

Opt( "MustDeclareVars", 1 )

Example()


Func Example()
  Local $hGui = GUICreate( "Input (numbers only)", 300, 118 )
  Local $idInput = GUICtrlCreateInput( "", 50, 50, 200, 18, $GUI_SS_DEFAULT_INPUT+$ES_NUMBER )
  Local $hInput = GUICtrlGetHandle( $idInput )

  GUICtrlCreateLabel( "No context menu, no paste, no balloontip", 50, 70, 200, 18 )

  ; Register callback function to subclass Input control
  Local $pInputProc = DllCallbackGetPtr( DllCallbackRegister( "InputProc", "lresult", "hwnd;uint;wparam;lparam;uint_ptr;dword_ptr" ) )
  _WinAPI_SetWindowSubclass( $hInput, $pInputProc, 9999, 0 ) ; SubclassId = 9999, $pData = 0

  GUISetState()

  While 1
    Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE
        ExitLoop
    EndSwitch
  WEnd

  ; Cleanup
  _WinAPI_RemoveWindowSubclass( $hInput, $pInputProc, 9999 )
  GUIDelete( $hGui )
  Exit
EndFunc

; InputProc callback function
Func InputProc( $hWnd, $iMsg, $wParam, $lParam, $iSubclassId, $pData )
  Switch $iMsg
    Case $WM_CONTEXTMENU, $WM_PASTE, $EM_SHOWBALLOONTIP
      Return 0
  EndSwitch
  ; Call next function in subclass chain
  Return DllCall( "comctl32.dll", "lresult", "DefSubclassProc", "hwnd", $hWnd, "uint", $iMsg, "wparam", $wParam, "lparam", $lParam )[0] ; _WinAPI_DefSubclassProc
EndFunc

 

Edited December 4, 2015 by LarsJ

[mLipok]

@LarsJ is it possible to get the handle to the POPup MENU and read all items , and more specifically: I'm asking especially about positions of each MenuElement in relation to Desktop LeftBottom corner ?
and ... is it possible to make it happend to other app window ?

 

[LarsJ]

It's possible for a normal "#32768" class popup menu. Here the menu item rectangles are specified relative to upper left screen corner:

expandcollapse popup

#include <GuiMenu.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
  ConsoleWrite( "5 seconds to open a popup menu ..." & @CRLF )
  Sleep( 5000 ) ; 5 seconds to open a popup menu
  Local $aWM = GetPopupWinMenuHandles()
  If Not IsArray( $aWM ) Then Return
  Local $hWnd = $aWM[0], $hMenu = $aWM[1]
  Local $aPos = WinGetPos( $hWnd )
  ConsoleWrite( "Menu pos = (" & $aPos[0] & "," & $aPos[1] & ")" & @CRLF )
  Local $hDesktop = _WinAPI_GetDesktopWindow()
  Local $iCount = _GUICtrlMenu_GetItemCount( $hMenu ), $sText, $aRect
  For $i = 0 To $iCount - 1
    $sText = _GUICtrlMenu_GetItemText( $hMenu, $i )
    ConsoleWrite( $sText ? $sText & @CRLF : "Separator" & @CRLF )
    $aRect = _GUICtrlMenu_GetItemRect( $hDesktop, $hMenu, $i )
    ConsoleWrite( "    Rect: UL = (" & $aPos[0]+$aRect[0] & "," & $aPos[1]+$aRect[1] & _
                         "), LR = (" & $aPos[0]+$aRect[2] & "," & $aPos[1]+$aRect[3] & ")" & @CRLF )
  Next
EndFunc

Func GetPopupWinMenuHandles()
  Local $hDesktop = _WinAPI_GetDesktopWindow(), $i = 0
  Local $hChild = _WinAPI_GetWindow( $hDesktop, $GW_CHILD )
  While $hChild And $i < 3
    If _WinAPI_GetClassName( $hChild ) = "#32768" Then ExitLoop
    $hChild = _WinAPI_GetWindow( $hChild, $GW_HWNDNEXT )
    $i += 1
  WEnd
  If $i = 3 Then Return 0
  Local $hMenu = _SendMessage( $hChild, $MN_GETHMENU )
  If $hMenu > 0 Then
    Local $aWM = [ $hChild, $hMenu ]
    Return $aWM
  EndIf
  Return 0
EndFunc

 

[Anoop]

Thank you very much.

It was real help and will definitely guide me for more self learning.

Edited December 5, 2015 by Anoop

[mLipok]

@LarsJ I just used your code and after F5 I press RightMouseButton on SciTE window.

After that I wait but nothing more happen.

Windows 8.1

 

[LarsJ]

I have tested on XP 32 bit (script runs as 32 bit) and Win 7 64 bit (script runs as 64 bit). On both systems I have tested with SciTE and Windows Explorer context menues. It works in all situations.

You can insert some ConsoleWrites in GetPopupWinMenuHandles() to figure out where it fails.

I'm using AutoIt 3.3.10 but I don't think this has anything to do with the problem.

Edited December 5, 2015 by LarsJ

[mLipok]

I'll do more test.
I think this is because in Win8.1 TaskBar is transparent and because of this is on the top of Z order.

 $GW_CHILD - The retrieved handle identifies the child window at the top of the Z order, if the specified

[LarsJ]

mLipok, Try this code instead. There is no limit to the number of windows. The code continues until the popup window is found or there are no more windows.

expandcollapse popup

#include <GuiMenu.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
  ConsoleWrite( "5 seconds to open a popup menu ..." & @CRLF )
  Sleep( 5000 ) ; 5 seconds to open a popup menu
  Local $aWM = GetPopupWinMenuHandles()
  If Not IsArray( $aWM ) Then Return
  Local $hWnd = $aWM[0], $hMenu = $aWM[1]
  Local $aPos = WinGetPos( $hWnd )
  ConsoleWrite( "Menu pos = (" & $aPos[0] & "," & $aPos[1] & ")" & @CRLF )
  Local $hDesktop = _WinAPI_GetDesktopWindow()
  Local $iCount = _GUICtrlMenu_GetItemCount( $hMenu ), $sText, $aRect
  For $i = 0 To $iCount - 1
    $sText = _GUICtrlMenu_GetItemText( $hMenu, $i )
    ConsoleWrite( $sText ? $sText & @CRLF : "Separator" & @CRLF )
    $aRect = _GUICtrlMenu_GetItemRect( $hDesktop, $hMenu, $i )
    ConsoleWrite( "    Rect: UL = (" & $aPos[0]+$aRect[0] & "," & $aPos[1]+$aRect[1] & _
                         "), LR = (" & $aPos[0]+$aRect[2] & "," & $aPos[1]+$aRect[3] & ")" & @CRLF )
  Next
EndFunc

Func GetPopupWinMenuHandles()
  Local $hDesktop = _WinAPI_GetDesktopWindow(), $i = 0
  Local $hChild = _WinAPI_GetWindow( $hDesktop, $GW_CHILD )
  While $hChild
    ConsoleWrite( $i & ": Handle = " & $hChild & _
                       ", Class = """ & _WinAPI_GetClassName( $hChild ) & """" & _
                       """, Title = """ & _WinAPI_GetWindowText( $hChild ) & """" & @CRLF )
    If _WinAPI_GetClassName( $hChild ) = "#32768" Then ExitLoop
    $hChild = _WinAPI_GetWindow( $hChild, $GW_HWNDNEXT )
    $i += 1
  WEnd
  If Not $hChild Then Return 0
  Local $hMenu = _SendMessage( $hChild, $MN_GETHMENU )
  If $hMenu > 0 Then
    Local $aWM = [ $hChild, $hMenu ]
    Return $aWM
  EndIf
  Return 0
EndFunc

 

[mLipok]

Thanks for this little demonstration.

This works very nice for SciTE and some other APP but not for all menus in all APP.
I'll go deeper in MSDN doc and try to learn more ..... of course when I finish some my other projects

mLipok

Edited December 6, 2015 by mLipok

[LarsJ]

That's true. It only works for standard "#32768" class menus. The context menus in eg. Chrome and Firefox with class
names something like "Chrome_WidgetWin_2" and "MozillaDropShadowWindowClass" are not standard menus and the code doesn't work.

These menus can be handled by UI Automation code. The example in the zip is an UI Automation event handler which looks for menu open events. It looks for popup menus, main menus and submenus. The zip contains Example.au3, CUIAutomation2.au3 by junkew and ObjectFromTag.au3 by trancexx.

Run Example.au3 in SciTE. It prints information in console. The script keeps running until you stop it. Now you can try to test some of your menus. It would be interesting to hear the results.

Menus.7z

Edited December 7, 2015 by LarsJ

[mLipok]

This is another great example.
Ultimately, in the end, it will be a solution for it to automate clicking on PopUpMenu, based on the text of an item in the menu.