Enforce Single Instance of Program via WM_COPYDATA

[KaFu]

For an example on how to send and receive data between different instances of the same script and which passes commandline parameters to the first instance via WM_COPYDATA take a look at post 2.

Just a short snippet which came to my mind as the _Singleton() standard UDF failed on my work-notebook for me (CreateMutexW returns winapi-error 126 - "The specified module could not be found" , I just assume it interferes with one of the 72 processes running).

#cs ----------------------------------------------------------------------------

    AutoIt Version: 3.3.0.0
    Author:         KaFu

    Script Function:
    _EnforceSingleInstance() function, Standard _Singleton() UDF failed on some machines for me

#ce ----------------------------------------------------------------------------

_EnforceSingleInstance('e15ff08b-84ac-472a-89bf-5f92db683165') ; any 'unique' string; created with http://www.guidgen.com/Index.aspx

MsgBox(0, "", "Test")

Func _EnforceSingleInstance($GUID_Program)
    If $GUID_Program = "" Then Return SetError(1,'',1)
    if IsHWnd(WinGetHandle($GUID_Program)) then
        MsgBox(0,"Test","Second instance, will exit now...")
        Exit
    EndIf
    AutoItWinSetTitle($GUID_Program)
    Return WinGetHandle($GUID_Program)
EndFunc   ;==>_EnforceSingleInstance

Should work as long as the key is really 'unique' (as unique as it gets ), and script is not complied as CUI (I'm not sure but I assume then there is no default AutoItWin).

Edited April 10, 2010 by KaFu

[KaFu]

And while playing around... here is a version which passes commandline parameters to first instance via WM_COPYDATA before exiting...

Compile and start multiple times with different commandline parameters to see whats happening...

expandcollapse popup

#NoTrayIcon
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hwnd_AutoIt = _EnforceSingleInstance('e15ff08b-84ac-472a-89bf-5f92db683165') ; any 'unique' string; created with http://www.guidgen.com/Index.aspx
Opt("TrayIconHide", 1)

$hGUI = GUICreate("My GUI " & $hwnd_AutoIt,300,300,Default,Default) ; will create a dialog box that when displayed is centered
$label = GUICtrlCreateLabel($CmdLineRaw,10,10,300,100)
GUISetState(@SW_SHOW) ; will display an empty dialog box

ControlSetText($hwnd_AutoIt,'',ControlGetHandle($hwnd_AutoIt,'','Edit1'),$hGUI) ; to pass hWnd of main GUI to AutoIt default GUI
GUIRegisterMsg($WM_COPYDATA, "WM_COPYDATA")

While 1
    sleep(10)
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
GUIDelete()

Func _EnforceSingleInstance($GUID_Program = "")
    If $GUID_Program = "" Then Return
    $hwnd = WinGetHandle($GUID_Program)
    If IsHWnd($hwnd) Then
        $hwnd_Target = ControlGetText($hwnd,'',ControlGetHandle($hwnd,'','Edit1'))
        WM_COPYDATA_SendData(HWnd($hwnd_Target), $CmdLineRaw)
        Exit
    EndIf
    AutoItWinSetTitle($GUID_Program)
    Return WinGetHandle($GUID_Program)
EndFunc   ;==>_EnforceSingleInstance

Func WM_COPYDATA($hWnd, $MsgID, $wParam, $lParam)
    ; http://www.autoitscript.com/forum/index.php?showtopic=105861&view=findpost&p=747887
    ; Melba23, based on code from Yashied
    Local $tCOPYDATA = DllStructCreate("ulong_ptr;dword;ptr", $lParam)
    Local $tMsg = DllStructCreate("char[" & DllStructGetData($tCOPYDATA, 2) & "]", DllStructGetData($tCOPYDATA, 3))
    $msg = DllStructGetData($tMsg, 1)
    if $msg = " " then
        GUICtrlSetData($label, "")
    else
        GUICtrlSetData($label, DllStructGetData($tMsg, 1))
    endif
    Return 0
EndFunc   ;==>WM_COPYDATA

Func WM_COPYDATA_SendData($hWnd, $sData)
    If Not IsHWnd($hWnd) Then Return 0
    if $sData = "" then $sData = " "
    Local $tCOPYDATA, $tMsg
    $tMsg = DllStructCreate("char[" & StringLen($sData) + 1 & "]")
    DllStructSetData($tMsg, 1, $sData)
    $tCOPYDATA = DllStructCreate("ulong_ptr;dword;ptr")
    DllStructSetData($tCOPYDATA, 2, StringLen($sData) + 1)
    DllStructSetData($tCOPYDATA, 3, DllStructGetPtr($tMsg))
    $Ret = DllCall("user32.dll", "lparam", "SendMessage", "hwnd", $hWnd, "int", $WM_COPYDATA, "wparam", 0, "lparam", DllStructGetPtr($tCOPYDATA))
    If (@error) Or ($Ret[0] = -1) Then Return 0
    Return 1
EndFunc   ;==>WM_COPYDATA_SendData

Edited November 23, 2011 by KaFu

[jvanegmond]

Why do you set a default parameter when in the next line you are enforcing the user not to enter a use the default parameter anyway?

Edited December 15, 2009 by Manadar

[KaFu]

Why do you set a default parameter when in the next line you are enforcing the user not to enter a use the default parameter anyway?

Lazyness, copy&paste... corrected...

[jvanegmond]

I really like your second implementation. Good job.

[Ascend4nt]

Hey, this is a pretty neat workaround. I didn't even know about the 'AutoItWinSetTitle' function! Go figure. I like the WM_COPYDATA use too - I had intended on writing something that would pass parameters to an already-running program in the future. Now i don't have to do the work

[KaFu]

Hey, this is a pretty neat workaround.

Thanks for the praise , nice to hear, especially from you .

This is how I balance the access to the Sqlite DB between searching and reporting instance in SMF (two instances of smf.exe running at the same time to give instant access to results).

And btw, a 4 star rating for this post? Someone didn't seem understand what's going on here ...

Edited April 10, 2010 by KaFu

[guinness]

I posted on the General Help and Support about getting your example of WM_COPYDATA to work in x64 and Yashied kindly replied with a solution, replace the following instances of "dword;dword;ptr" to "ulong_ptr;dword;ptr".

Here is the post.

[KaFu]

Followed that post, thanks for the addition .

[dexto]

Very interesting! WM_COPYDATA implementation should be a part of standard includes and documented in a help file.

[mikell]

On 12/15/2009 at 5:31 PM, KaFu said:

here is a version which passes commandline parameters to first instance via WM_COPYDATA before exiting

I'm really a bit late  , but...
This 2nd code is a true gift. Still working, clever, extremely easy to implement and use in an existing script
Thanks 

[Trong]

Test Script:

For $i=1 to 200
    Run(@ScriptDir&"\EnforceSingleInstance_86.exe")
    ConsoleWrite($i&@CRLF)

Next

 

Main script to compile:

expandcollapse popup

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=EnforceSingleInstance_86.exe
#AutoIt3Wrapper_Outfile_x64=EnforceSingleInstance_64.exe
#AutoIt3Wrapper_Compile_Both=y
#AutoIt3Wrapper_UseX64=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>

Opt("MustDeclareVars", 1)
Global $sGUID = 'e15ff08b-84ac-472a-89bf-5f92db683165'
Global $gMsg, $hwnd_AutoIt = _EnforceSingleInstance($sGUID) ; any 'unique' string; created with http://www.guidgen.com/Index.aspx
Opt("TrayIconHide", 1)

Global $hGUI = GUICreate("My GUI " & $hwnd_AutoIt, 550, 150, -1, -1, -1, BitOR($WS_EX_TOPMOST, $WS_EX_WINDOWEDGE))
GUICtrlCreateLabel("CmdLineRaw:", 5, 60, 79, 60, BitOR($SS_RIGHT, $SS_CENTERIMAGE), $GUI_WS_EX_PARENTDRAG)
GUICtrlCreateLabel("Process PID:", 5, 5, 79, 17, BitOR($SS_RIGHT, $SS_CENTERIMAGE), $GUI_WS_EX_PARENTDRAG)
GUICtrlCreateLabel("GUID:", 6, 32, 79, 17, BitOR($SS_RIGHT, $SS_CENTERIMAGE), $GUI_WS_EX_PARENTDRAG)
GUICtrlCreateLabel(StringInStr(@OSArch, '64') ? "OS x64" : "OS x86", 192, 5, 52, 17, $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
GUICtrlCreateLabel(@AutoItX64 ? "Exe x64" : "EXE x86", 249, 5, 54, 17, $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
GUICtrlCreateLabel(@AutoItPID, 94, 5, 86, 17, $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
GUICtrlCreateLabel(IsAdmin() ? "Runing on Admin" : "Not Run as Admin", 318, 5, 94, 17, $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)

Global $Label_CmdLineRaw = GUICtrlCreateLabel($CmdLineRaw, 94, 60, 450, 60, $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
Global $Label_GUID = GUICtrlCreateLabel($sGUID, 94, 32, 450, 17, $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
Global $Label_Time = GUICtrlCreateLabel("", 448, 5, 100, 17, BitOR($SS_CENTER, $SS_CENTERIMAGE), $GUI_WS_EX_PARENTDRAG)
Global $Label_Status = GUICtrlCreateLabel("", 5, 128, 535, 17, BitOR($SS_CENTER, $SS_CENTERIMAGE), $GUI_WS_EX_PARENTDRAG)

GUISetState(@SW_SHOW)

ControlSetText($hwnd_AutoIt, '', ControlGetHandle($hwnd_AutoIt, '', 'Edit1'), $hGUI) ; to pass hWnd of main GUI to AutoIt default GUI
GUIRegisterMsg($WM_COPYDATA, "WM_COPYDATA")
AdlibRegister("_Check_Process_Same_Name", 1000)

While 1
    Sleep(10)
    $gMsg = GUIGetMsg()
    If $gMsg = $GUI_EVENT_CLOSE Then ExitLoop
    GUICtrlSetData($Label_Time, @HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC)
WEnd

GUIDelete()
Exit

Func _Check_Process_Same_Name()
    Local $ScriptName = @ScriptName
    If Not @Compiled Then $ScriptName = StringRegExpReplace(@AutoItExe, "^.*\\", "")
    ;ConsoleWrite("- Script Name: "&$ScriptName&@CRLF)
    Local $ProcessList = '', $aProc = ProcessList($ScriptName)
    For $i = 1 To $aProc[0][0]
        If $aProc[$i][1] <> @AutoItPID Then $ProcessList &= $aProc[$i][1] & " / "
    Next
    If $ProcessList <> "" Then
        GUICtrlSetData($Label_Status, "Process Same Name: " & $ProcessList)
    Else
        GUICtrlSetData($Label_Status, "")
    EndIf
    $ProcessList = ''
EndFunc   ;==>_Check_Process_Same_Name

Func _EnforceSingleInstance($GUID_Program = "")
    If $GUID_Program = "" Then Return
    Local $hwnd = WinGetHandle($GUID_Program)
    If IsHWnd($hwnd) Then
        Local $hwnd_Target = ControlGetText($hwnd, '', ControlGetHandle($hwnd, '', 'Edit1'))
        WM_COPYDATA_SendData(HWnd($hwnd_Target), $CmdLineRaw)
        Exit
    EndIf
    AutoItWinSetTitle($GUID_Program)
    Return WinGetHandle($GUID_Program)
EndFunc   ;==>_EnforceSingleInstance

Func WM_COPYDATA($hwnd, $MsgID, $wParam, $lParam)
    ; http://www.autoitscript.com/forum/index.php?showtopic=105861&view=findpost&p=747887
    ; Melba23, based on code from Yashied
    Local $tCOPYDATA = DllStructCreate("ulong_ptr;dword;ptr", $lParam)
    Local $tMsg = DllStructCreate("char[" & DllStructGetData($tCOPYDATA, 2) & "]", DllStructGetData($tCOPYDATA, 3))
    Local $xMsg = DllStructGetData($tMsg, 1)
    If StringStripWS($xMsg, 8) = "" Then
        GUICtrlSetData($Label_CmdLineRaw, "")
    Else
        GUICtrlSetData($Label_CmdLineRaw, $xMsg)
    EndIf
    Return 0
EndFunc   ;==>WM_COPYDATA

Func WM_COPYDATA_SendData($hwnd, $sData)
    If Not IsHWnd($hwnd) Then Return 0
    If $sData = "" Then $sData = " "
    Local $tMsg = DllStructCreate("char[" & StringLen($sData) + 1 & "]")
    DllStructSetData($tMsg, 1, $sData)
    Local $tCOPYDATA = DllStructCreate("ulong_ptr;dword;ptr")
    DllStructSetData($tCOPYDATA, 2, StringLen($sData) + 1)
    DllStructSetData($tCOPYDATA, 3, DllStructGetPtr($tMsg))
    Local $aRet = DllCall("user32.dll", "lparam", "SendMessage", "hwnd", $hwnd, "int", $WM_COPYDATA, "wparam", 0, "lparam", DllStructGetPtr($tCOPYDATA))
    If (@error) Or ($aRet[0] = -1) Then Return 0
    Return 1
EndFunc   ;==>WM_COPYDATA_SendData

 

Result:

 

 

I want to find a solution to "Execute a single instance" but the new session closes the old instance or the old one exits on its own.

[Jardz]

Hi VIP

Does Opt(WinWaitDelay,'1') improve this?

edit: Not sure what I was thinking!! Ran it a few times with delay reduced and it behaved, just a coincidence.

edit2: I can't see how this method can truly work in VIP's test, the way I see it multiple CPU cycles are required to look for a window and rename it's own window if not found. Because of the process queue multiple processes can be taking turns to complete that task.

Need to use a mutex or semaphore (semaphore if you want to set max nth of running)

BTW. Singleton() (mutex method) has always worked for me.

Regards

Sjardz

Edited August 19, 2021 by Jardz

[Trong]

Yes, using singleton does not subject to application repetition.
 I found the solution to my problem:

 

Edited August 19, 2021 by VIP
Problem solved