_DirGetSizeEx

[KaFu]

Did this for use with SMF. UDF _DirGetSizeEx() is using AU native functions only...

expandcollapse popup

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.0.0
 Author:         KaFu
 Script Name, Version and Date: _DirGetSizeEx v04 (09-Jan-22)

 Script Function:
    _DirGetSizeEx, a replacement for DirGetSize()
    UDF using AU native functions only. Faster than DirGetSize() in the inital run on XP, slower in a repeated run, DirGetSize seems to cache the result.
    Change $Path between tests to seem what I mean.
   
    DirGetSize can not be interrupted / stopped, that's the main reason I coded this UDF

    Function returns an array
    $array[0] = Bytes
    $array[1] = File Count
    $array[2] = Folder Count

    On Vista DirGetSize seems to be much faster than on XP, thus if you're only into speed use something like:
    
    if @OSVersion <> "WIN_VISTA" Then
        $aResult = _DirGetSizeEx($Path)
    Else
        $aResult = DirGetSize($Path)
    EndIf
    
    But keep in mind, main advantage of _DirGetSizeEx is that during runtime you can easily implement a progress count or interrupt the function with
    a global variable (like I do in SMF, just define a bool something like $running = true and switch it with WM_COMMAND)

#ce ----------------------------------------------------------------------------

Dim $Path = @AppDataDir

$begin = TimerInit()
$a_DirGetSize = DirGetSize($Path, 1)
$dif_DirGetSize = round(TimerDiff($begin),0)

$begin = TimerInit()
$a_DirGetSizeEx = _DirGetSizeEx($Path)  ; <= recommended
$dif_DirGetSizeEx = round(TimerDiff($begin),0)

MsgBox(0, 'Comparison DirGetSize() vs _DirGetSizeEx', '' _
        & 'DirGetSize()' & @crlf & 'Time: ' & $dif_DirGetSize & @crlf &  'Bytes: ' & $a_DirGetSize[0] & @crlf & 'File Count: ' & $a_DirGetSize[1] & @CRLF & 'Folder Count: ' & $a_DirGetSize[2] & @CRLF & @CRLF _
        & '_DirGetSizeEx()' & @crlf & 'Time: ' & $dif_DirGetSizeEx & @crlf & 'Bytes: ' & $a_DirGetSizeEx[0] & @crlf & 'File Count: ' & $a_DirGetSizeEx[1] & @CRLF & 'Folder Count: ' & $a_DirGetSizeEx[2])

Func _DirGetSizeEx($sPath = @ScriptDir)
    Local $sSearch, $aResult[3], $aResult_sub[3]
    If StringRight($sPath, 1) <> "\" Then $sPath &= "\" ; Ensure $sPath has a trailing slash
    $sSearch = FileFindFirstFile($sPath & "*.*")
    While 1
        $sNext = FileFindNextFile($sSearch) ; check if next file can be found, otherwise exit loop
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sNext), "D") Then
            $aResult[2] += 1            
            $aResult_sub = _DirGetSizeEx($sPath & $sNext)
            $aResult[0] += $aResult_sub[0]
            $aResult[1] += $aResult_sub[1]
            $aResult[2] += $aResult_sub[2]
        Else
            $aResult[1] += 1
            $aResult[0] += FileGetSize($sPath & $sNext)
        EndIf
    WEnd
    FileClose($sSearch)
    Return $aResult
EndFunc   ;==>_DirGetSizeEx

Best Regards

Edited January 22, 2009 by KaFu

[KaFu]

Updated first post, added function using AU native functions only...

Best Regards

Edit:

Hu, DirGetSize() seems to cache the results somehow. Repeating it on a folder it will return the result much, much faster. But invoked on a directory not analyzed before, _DirGetSizeEx() is by far the fastest method of those three...

Benchmark:

DirGetSize()

Time: 21,360 ms

Filecount: 30611

Foldercount: 353

Bytes: 7,468,535,738 (6.95GB)

_DirGetSizeEx()

Time: 7,340 ms

_DirGetSizeEx_SFSO()

Time: 11,035 ms

Edited January 21, 2009 by KaFu

[Melba23]

KaFu,

Sorry to tell you , but it is not working well for me. Vista Home Premium 32 SP1.

Firstly, SciTE claims that $oScriptingFileSystemObject is not declared - fixed by putting it as Global at start.

Then the script ususally goes into some form of endless loop while running your UDFs. I did try changing the order but to no avail.

Got it to run twice in about 10 attempts giving the following results:

DirGetSize = 629 and 758

DirGetSizeEx = 41198 and 39146

DirGetSize_SFSO = 16075 and 12096

I think I will stick with DirGetSize for the moment :-)

M23

Edit: Got it to work better with other paths (smaller sizes?) - but timings still favour DirGetSize -> 2 - 139 - 21 and 509 - 2887 - 1026

Edited January 21, 2009 by Melba23

[KaFu]

Sorry to tell you , but it is not working well for me. Vista Home Premium 32 SP1.

Thanks for the feedback ...

Firstly, SciTE claims that $oScriptingFileSystemObject is not declared - fixed by putting it as Global at start.

Yeah, that's what I feared. I guess the Scripting.FileSystemObject is part of the NET framework and thus not installed on every machine. That's also why I wrote the second UDF using AU native functions only.

Then the script ususally goes into some form of endless loop while running your UDFs. I did try changing the order but to no avail.

Can't reproduce as I only have XP with NET 3.0 available...

Got it to run twice in about 10 attempts giving the following results:

Would you be so kind to test the attached script? I cut the Scripting.FileSystemObject part, only AU native functions...

Edit: Got it to work better with other paths (smaller sizes?) - but timings still favour DirGetSize -> 2 - 139 - 21 and 509 - 2887 - 1026

Yep, I guess you tested it on the same dir twice , that's what I meant with 'DirGetSize seems to cache the results somehow', as mine seems to be faster on every initial run to a new dir... try too run the scripts on different dirs and you'll see what I mean, run it a second time and DirGetSize will always be faster...

Here's the UDF with native functions only (guess I'll kick the SFSO version, sorry rasim ).

*Updated first post

Best Regards

Edited January 21, 2009 by KaFu

[gseller]

I am running WinXP SP2 and it works well for me.. Thanks! Nice li'l tidbit...

[torels]

nice udf

I like the recursion

[Melba23]

KaFu,

New version works without problems, but I still find your UDF slower (sorry!):

All tests done on previously untested folders, repeated 4 times in quick succession.

Size 2330 files - 617 folders: DirGetSize = 288 - 260 - 340 - 301, DirGetSizeEx = 1782 - 1828 - 1737 - 1796

Size 5686 files - 750 folders: DirGetSize = 203 - 203 - 178 - 191, DirGetSizeEx = 2019 - 2053 - 2137 - 2009

Size 163 files - 6 folders: DirGetSize = 31 - 3 - 3 - 3, DirGetSizeEx = 105 - 69 - 75 - 75

As far as I know I have nothing which should cause your UDF to be so slow - perhaps something in Vista? Anyone else with Vista prepared to run it and see?

I am more than happy to run more tests/versions if it will help - I feel guilty about finding the problem!

M23

[KaFu]

New version works without problems, but I still find your UDF slower (sorry!):

As far as I know I have nothing which should cause your UDF to be so slow - perhaps something in Vista? Anyone else with Vista prepared to run it and see?

Thanks for testing ... interesting, at least an advantage of vista ? On XP my script always runs faster on initial run and slower on repeated ones. Maybe Vista has a more advanced indexing service of some kind? I don't know how DirGetSize works internally / which API's called, but I guess that's what makes the difference in runtime XP<>Vista.

Best Regards

[Melba23]

KaFu,

Ran the tests again this morning on the newly booted box of tricks:

DirGetSize      DirgetSizeEx

 Internal HD (C: partition) 63911 files/12129 folders

21667           41484
 4012           37333
 3830           37562
 3841           37528

 Internal HD (M: partition)163/6

76              162
 2              120
 3               65
 2               66

 Internal HD (N: partition)2645/98

352         1275
 26         1275
 27         1062
 46         1050

 Ext USB HD5 686/750

5315            1937
 188            1923
 146            1976
 153            1894

USB Stick 104/7

17              189
 9              196
 7              209
 7              217

Looks like you win for the first try on BIG external drives.

Seriously, Vista does do some serious indexing behind the scenes (it is even user configurable for Search) and it might well be that "feature" which is making the difference here.

Sorry to have been the bringer of bad news :-(

M23

[KaFu]

Seriously, Vista does do some serious indexing behind the scenes (it is even user configurable for Search) and it might well be that "feature" which is making the difference here.

Sorry to have been the bringer of bad news :-(

No bad news, any testing result is just good news ... so, that means DirGetSize seems to win on Vista any time. If you're just into speed, you can use something like this:

if @OSVersion <> "WIN_VISTA" Then
        $aResult = _DirGetSizeEx($Path)
    Else
        $aResult = DirGetSize($Path)
    EndIf

I adjusted the UDF in the first post, so that now the returned array structure is the same as for DirGetSize. Nevertheless I still favor my solution, it might be slower, depending on the OS and if the folder has been scanned before, but the main advantage I still see and why I coded the UDF is still valid. DirGetSize() pauses the script and can not be interrupted during runtime. You can do this easily with _DirGetSizeEx() by defining a Global Bool like $bRunning = true and switch it with WM_COMMAND.

Thanks for testing and Best Regards

Edited January 22, 2009 by KaFu

[FireFox]

@KaFu

Nice one works great when folder keep changing

Cheers, FireFox.

[MrCreatoR]

Nice, but it will fail on large subfolders structure (due to limitations of recursive function calls).

+ The files/folders count is wrong...

Edited June 23, 2009 by MrCreatoR

[SmOke_N]

Nice, but it will fail on large subfolders structure (due to limitations of recursive function calls).

+ The files/folders count is wrong...

6 months later

My test errored at 4710 recursive calls ( hell of a lot better than the previous 380+ I remember ).

[MrCreatoR]

Here is a remake (a significant modificated my old version and this one):

expandcollapse popup

#cs ----------------------------------------------------------------------------
    AutoIt Version: 3.3.0.0
    Author:         KaFu, MrCreatoR
    Script Name, Version and Date: _DirGetSizeEx v05 (09-Jun-24)
#ce ----------------------------------------------------------------------------

_Example(@AppDataDir)

Func _Example($sPath)
    $i_TimerInit = TimerInit()
    $a_DirGetSize = DirGetSize($sPath, 1)
    $i_dif_DirGetSize = Round(TimerDiff($i_TimerInit), 0)
    
    $i_TimerInit = TimerInit()
    $a_DirGetSizeEx = _DirGetSizeEx($sPath, 1) ; <= recommended
    $i_dif_DirGetSizeEx = Round(TimerDiff($i_TimerInit), 0)
    
    $s_Results = StringFormat('[DirGetSize()]\n\nTime (ms):\t%s\nBytes:\t\t%s\nFile Count:\t%s\nFolder Count:\t%s', _
            $i_dif_DirGetSize, $a_DirGetSize[0], $a_DirGetSize[1], $a_DirGetSize[2])
    
    $s_ResultsEx = _
        StringFormat('[DirGetSizeEx()]\n\nTime (ms):\t%s\nBytes:\t\t%s\nFile Count:\t%s\nFolder Count:\t%s', _
            $i_dif_DirGetSizeEx, $a_DirGetSizeEx[0], $a_DirGetSizeEx[1], $a_DirGetSizeEx[2])
    
    MsgBox(64, 'Comparison DirGetSize() vs _DirGetSizeEx', _
        StringFormat($s_Results & '\n\n===============================\n\n' & $s_ResultsEx))
EndFunc

; #FUNCTION# ====================================================================================================
; Name...........:  _DirGetSizeEx
; Description....:  Returns the size in bytes of a given directory.
; Syntax.........:  _DirGetSizeEx($sPath, $iFlag=0, $iRecurse_Level=-1)
; Parameters.....:  $sPath          - The directory path to get the size from, e.g. "C:\Windows".
;                   $iFlag          - [Optional] This flag determines the behaviour and result of the function,
;                                       and can be a combination of the following:
;                                               0 = (Default)
;                                               1 = Extended mode is On -> returns an array that contains extended information
;                                                   (see Remarks for native DirGetSize() function).
;                                               2 = Don't get the size of files in subdirectories (recursive mode is Off)
;                   $iRecurse_Level - [Optional] Determines the recursion level of subfolders to check (only if $iFlag < 2).
;                   
; Return values..:  Success         - Returns an array:
;                                                       $aRet_Array[0] = Bytes
;                                                       $aRet_Array[1] = File Count
;                                                       $aRet_Array[2] = Folder Count
;                   Failure         - Returns -1 and sets @error to 1 if the path doesn't exist.
;
; Author.........:  Initial Idea by KaFu, ReCoded by G.Sandler (a.k.a MrCreatoR).
; Modified.......:  
; Remarks........:  * Faster than DirGetSize() in the inital run on XP, slower in a repeated run,
;                       DirGetSize() seems to cache the result.
;                   * DirGetSize() can not be interrupted / stopped, that's the main reason for this UDF.
;                   * On Vista DirGetSize seems to be much faster than on XP, thus if you're only into speed use something like:
;                       ================== Code =========================
;                           If @OSVersion <> "WIN_VISTA" Then
;                               $aRet_Array = _DirGetSizeEx($sPath)
;                           Else
;                               $aRet_Array = DirGetSize($sPath)
;                           EndIf
;                       ================== Code =========================
;
;                   * Main advantage of _DirGetSizeEx() is that during runtime you can easily implement a progress count
;                      or interrupt the function with a global variable
;                      (just define a bool something like $iRunning = True and switch it with WM_COMMAND)
;
; Related........:  DirGetSize()?
; Link...........:  http://www.autoitscript.com/forum/index.php?showtopic=88094
; Example........:  Yes.
; ===============================================================================================================
Func _DirGetSizeEx($sPath, $iFlag=0, $iRecurse_Level=-1)
    If Not StringInStr(FileGetAttrib($sPath & "\"), "D") Then Return SetError(1, 0, -1)
    
    Local $aRet_Array[3], $hSearch, $sNextFile, $sFilePath, $i = 0
    Local $iMax_Ret_Paths = 10000
    Local $aPathes[$iMax_Ret_Paths+1] = [1, $sPath]
    
    While $i < $aPathes[0]
        $i += 1
        
        If $iFlag < 2 And $iRecurse_Level <> -1 And $i = $iRecurse_Level+1 Then ExitLoop
        
        $hSearch = FileFindFirstFile($aPathes[$i] & "\*")
        If $hSearch = -1 Then ContinueLoop
        
        While 1
            $sNextFile = FileFindNextFile($hSearch)
            If @error Then ExitLoop
            
            $sFilePath = $aPathes[$i] & "\" & $sNextFile
            
            If StringInStr(FileGetAttrib($sFilePath & "\"), "D") Then
                If $aPathes[0] >= $iMax_Ret_Paths Then
                    $iMax_Ret_Paths *= 2
                    ReDim $aPathes[$iMax_Ret_Paths+1]
                EndIf
                
                $aPathes[0] += 1
                $aPathes[$aPathes[0]] = $sFilePath
            Else
                $aRet_Array[1] += 1
                $aRet_Array[0] += FileGetSize($sFilePath)
            EndIf
        WEnd
        
        FileClose($hSearch)
        
        If $iFlag > 1 Then ExitLoop
    Wend
    
    If $iFlag > 0 And $iFlag <> 2 Then ;1 or 1 + 2 (3) - wich is mean that Extended mode is On.
        $aRet_Array[2] = $aPathes[0] - 1
        Return $aRet_Array
    EndIf
    
    Return $aRet_Array[0]
EndFunc ;==>_DirGetSizeEx

* No recursion limits + recursion level control + exactly the same options as in original DirGetSize function

Edited June 24, 2009 by MrCreatoR

[MrCreatoR]

6 months later

My test errored at 4710 recursive calls ( hell of a lot better than the previous 380+ I remember ).

Yep, i must look at the date first (on all of it, not just the year), before posting

P.S

And BTW; signatures are really rules, i came here to this thread following by one of them (of KaFu's actualy ).

Edited June 24, 2009 by MrCreatoR

[KaFu]

It does error out and do a false count? Hmmm, I can't reproduce that, this works fine for me:

expandcollapse popup

#cs ----------------------------------------------------------------------------
    AutoIt Version: 3.3.0.0
    Author:         KaFu, MrCreatoR
    Script Name, Version and Date: _DirGetSizeEx v05 (09-Jun-24)
#ce ----------------------------------------------------------------------------

_Example(@AppDataDir)

Func _Example($sPath)
    $i_TimerInit = TimerInit()
    $a_DirGetSize = DirGetSize($sPath, 1)
    $i_dif_DirGetSize = Round(TimerDiff($i_TimerInit), 0)

    $i_TimerInit = TimerInit()
    $a_DirGetSizeEx = _DirGetSizeEx($sPath, 1) ; <= recommended
    $i_dif_DirGetSizeEx = Round(TimerDiff($i_TimerInit), 0)

    $i_TimerInit = TimerInit()
    $a_DirGetSizeExKaFu = _DirGetSizeExKaFu($sPath)
    $i_dif_DirGetSizeExKaFu = Round(TimerDiff($i_TimerInit), 0)

    $s_Results = StringFormat('[DirGetSize()]\n\nTime (ms):\t%s\nBytes:\t\t%s\nFile Count:\t%s\nFolder Count:\t%s', _
            $i_dif_DirGetSize, $a_DirGetSize[0], $a_DirGetSize[1], $a_DirGetSize[2])

    $s_ResultsEx = _
        StringFormat('[DirGetSizeEx()]\n\nTime (ms):\t%s\nBytes:\t\t%s\nFile Count:\t%s\nFolder Count:\t%s', _
            $i_dif_DirGetSizeEx, $a_DirGetSizeEx[0], $a_DirGetSizeEx[1], $a_DirGetSizeEx[2])

    $s_ResultsExKaFu = _
        StringFormat('[DirGetSizeExKaFu()]\n\nTime (ms):\t%s\nBytes:\t\t%s\nFile Count:\t%s\nFolder Count:\t%s', _
            $i_dif_DirGetSizeExKaFu, $a_DirGetSizeExKaFu[0], $a_DirGetSizeExKaFu[1], $a_DirGetSizeExKaFu[2])

    MsgBox(64, 'Comparison DirGetSize() vs _DirGetSizeEx', _
        StringFormat($s_Results & '\n\n===============================\n\n' & $s_ResultsEx & '\n\n===============================\n\n' & $s_ResultsExKaFu))
EndFunc

; #FUNCTION# ====================================================================================================

; Name...........:  _DirGetSizeEx
; Description....:  Returns the size in bytes of a given directory.
; Syntax.........:  _DirGetSizeEx($sPath, $iFlag=0, $iRecurse_Level=-1)
; Parameters.....:  $sPath          - The directory path to get the size from, e.g. "C:\Windows".
;                   $iFlag          - [Optional] This flag determines the behaviour and result of the function,
;                                       and can be a combination of the following:
;                                               0 = (Default)
;                                               1 = Extended mode is On -> returns an array that contains extended information
;                                                   (see Remarks for native DirGetSize() function).
;                                               2 = Don't get the size of files in subdirectories (recursive mode is Off)
;                   $iRecurse_Level - [Optional] Determines the recursion level of subfolders to check (only if $iFlag < 2).
;
; Return values..:  Success         - Returns an array:
;                                                       $aRet_Array[0] = Bytes
;                                                       $aRet_Array[1] = File Count
;                                                       $aRet_Array[2] = Folder Count
;                   Failure         - Returns -1 and sets @error to 1 if the path doesn't exist.
;
; Author.........:  Initial Idea by KaFu, ReCoded by G.Sandler (a.k.a MrCreatoR).
; Modified.......:
; Remarks........:  * Faster than DirGetSize() in the inital run on XP, slower in a repeated run,
;                       DirGetSize() seems to cache the result.
;                   * DirGetSize() can not be interrupted / stopped, that's the main reason for this UDF.
;                   * On Vista DirGetSize seems to be much faster than on XP, thus if you're only into speed use something like:
;                       ================== Code =========================
;                           If @OSVersion <> "WIN_VISTA" Then
;                               $aRet_Array = _DirGetSizeEx($sPath)
;                           Else
;                               $aRet_Array = DirGetSize($sPath)
;                           EndIf
;                       ================== Code =========================
;
;                   * Main advantage of _DirGetSizeEx() is that during runtime you can easily implement a progress count
;                      or interrupt the function with a global variable
;                      (just define a bool something like $iRunning = True and switch it with WM_COMMAND)
;
; Related........:  DirGetSize()?
; Link...........:  http://www.autoitscript.com/forum/index.php?showtopic=88094
; Example........:  Yes.
; ====================================================================================================
Func _DirGetSizeEx($sPath, $iFlag=0, $iRecurse_Level=-1)
    If Not StringInStr(FileGetAttrib($sPath & "\"), "D") Then Return SetError(1, 0, -1)

    Local $aRet_Array[3], $hSearch, $sNextFile, $sFilePath, $i = 0
    Local $iMax_Ret_Paths = 10000
    Local $aPathes[$iMax_Ret_Paths+1] = [1, $sPath]

    While $i < $aPathes[0]
        $i += 1

        If $iFlag < 2 And $iRecurse_Level <> -1 And $i = $iRecurse_Level+1 Then ExitLoop

        $hSearch = FileFindFirstFile($aPathes[$i] & "\*")
        If $hSearch = -1 Then ContinueLoop

        While 1
            $sNextFile = FileFindNextFile($hSearch)
            If @error Then ExitLoop

            $sFilePath = $aPathes[$i] & "\" & $sNextFile

            If StringInStr(FileGetAttrib($sFilePath & "\"), "D") Then
                If $aPathes[0] >= $iMax_Ret_Paths Then
                    $iMax_Ret_Paths *= 2
                    ReDim $aPathes[$iMax_Ret_Paths+1]
                EndIf

                $aPathes[0] += 1
                $aPathes[$aPathes[0]] = $sFilePath
            Else
                $aRet_Array[1] += 1
                $aRet_Array[0] += FileGetSize($sFilePath)
            EndIf
        WEnd

        FileClose($hSearch)

        If $iFlag > 1 Then ExitLoop
    Wend

    If $iFlag > 0 And $iFlag <> 2 Then ;1 or 1 + 2 (3) - wich is mean that Extended mode is On.
        $aRet_Array[2] = $aPathes[0] - 1
        Return $aRet_Array
    EndIf

    Return $aRet_Array[0]
EndFunc ;==>_DirGetSizeEx


Func _DirGetSizeExKaFu($sPath = @ScriptDir)
    Local $sSearch, $aResult[3], $aResult_sub[3]
    If StringRight($sPath, 1) <> "\" Then $sPath &= "\" ; Ensure $sPath has a trailing slash
    $sSearch = FileFindFirstFile($sPath & "*.*")
    While 1
        $sNext = FileFindNextFile($sSearch) ; check if next file can be found, otherwise exit loop
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sNext), "D") Then
            $aResult[2] += 1
            $aResult_sub = _DirGetSizeExKaFu($sPath & $sNext)
            $aResult[0] += $aResult_sub[0]
            $aResult[1] += $aResult_sub[1]
            $aResult[2] += $aResult_sub[2]
        Else
            $aResult[1] += 1
            $aResult[0] += FileGetSize($sPath & $sNext)
        EndIf
    WEnd
    FileClose($sSearch)
    Return $aResult
EndFunc   ;==>_DirGetSizeEx

In theory I could hit the max. recursion level, but for that someone would have to have a directory structure 4710 steps deep , or did I miss something?

[Michel Claveau]

Hi, All!

Perso, for my scripts in AutoIt, I use often the DIR command, who is powerfull, fast, and easy.

Example(s):

expandcollapse popup

#include <Constants.au3>

Const $clef="fichier(s)"
;Const $clef="file(s)"

MsgBox(0,"Dir Size",dirsize("C:\temp"))
MsgBox(0,"Dir Size",dirsize2("D:\Dev\Autoit"))
MsgBox(0,"Dir Size",dirsize3("C:\_trsfr"))
Exit


Func dirsize($dir)
    Local $f,$line
    $f=FileOpen("temp.bat",2)
    FileWriteLine($f,"@echo off")
    FileWriteLine($f,"setlocal")
    FileWriteLine($f,'CD /D"'& $dir &'"')
    FileWriteLine($f,"FOR /F ""tokens=*"" %%i IN ('dir /S /W /-C ^| find """&$clef&"""') DO SET SIZE=%%i")
    FileWriteLine($f,"echo %SIZE%")
    FileWriteLine($f,"endlocal")
    FileWriteLine($f,"exit")
    FileClose($f)

    Local $pip=Run(@ComSpec &" /c"& @ScriptDir &"\temp.bat",$dir, @SW_HIDE, $STDOUT_CHILD)
    $vret=""
    While 1
        $line = StdoutRead($pip)
        If @error Then ExitLoop
        If StringLen($line)>0 Then   ExitLoop
      ;MsgBox(0, StringLen($line), $line)
    Wend
    Return $line
EndFunc


Func dirsize2($dir)
    Local $f,$line,$vret
    $f=FileOpen("temp.bat",2)
    FileWriteLine($f,"@echo off")
    FileWriteLine($f,'CD /D"'& $dir &'"')
    FileWriteLine($f,"dir /S /W /-C")
    FileWriteLine($f,"exit")
    FileClose($f)

    Local $pip=Run(@ComSpec &" /c"& @ScriptDir &"\temp.bat",$dir, @SW_HIDE, $STDOUT_CHILD)
    $vret=""
    While 1
        $line = StdoutRead($pip)
        If @error Then ExitLoop
        If StringInStr($line,$clef)>0 Then   $vret=$line
    Wend
    Return $vret
EndFunc


Func dirsize3($dir)
    Local $line,$vret
    $cde='dir "'& $dir &'" /S /W /-C'
    Local $pip=Run(@ComSpec &" /c"& $cde,$dir, @SW_HIDE, $STDOUT_CHILD)
    $vret=""
    While 1
        $line = StdoutRead($pip)
        If @error Then ExitLoop
        If StringInStr($line,$clef)>0 Then   $vret=$line
    Wend
    Return $vret
EndFunc

WARNING: Do not forget to change the "clef" for your (computer) language (french, in these examples), ans set your directory(ies) choice.

Edited June 24, 2009 by Michel Claveau

[MrCreatoR]

In theory I could hit the max. recursion level, but for that someone would have to have a directory structure 4710 steps deep

Yes, and we should reproduce it by creating this level:

$sInit_Dir = @TempDir & "\~Recursion_Test"

For $i = 1 To 4710 + 1
    $sInit_Dir &= "\" & $i
Next

DirCreate($sInit_Dir)

But it seems that my system (FAT32 file system?) does not allow such long recursion level of subfolders, so i personaly can't reproduce it. But it's can crash, so better way is to use loop, as i did .

[KaFu]

But it seems that my system (FAT32 file system?) does not allow such long recursion level of subfolders, so i personaly can't reproduce it. But it's can crash, so better way is to use loop, as i did .

Normally filelength is restricted to 260 characters, even on NTFS.

"The operating system API puts a limit (called MAX_PATH) of 260 characters for the complete name with the path included."

http://vlaurie.com/computers2/Articles/filenames.htm

http://www.ntfs.com/ntfs_vs_fat.htm

There are ways around it in NTFS (pre-prending \\?\ to the dir letter) and I think the theoratical max is 65536 letters, but imho a directory depth of > 10 or lets say > 20 is very ununsual. Personally i think theres NO directory structure in the world going down 4710 steps .

You mentioned that the files/folders count is wrong? Couldn't verfify that, what did you do test assume this?

[Michel Claveau]

Hi!

NTFS max-length-filename are: 255 with "code-page" & 32767 with Unicode file's name.

@+

--

MCI