Translator

[thelex]

I need just a little help. i wan't to make a script that translates the text i write, while im writing it. EXAMPLE:

i press down "i" and on the screen(for example in MSN) the "i" becomes "1".

(Y34H, 1M M4K1NG 4 1337SP33K TR4NSL4T0R)

Just need a little example or what to do, as this is a very simple thing.

[martin]

I need just a little help. i wan't to make a script that translates the text i write, while im writing it. EXAMPLE:

i press down "i" and on the screen(for example in MSN) the "i" becomes "1".

(Y34H, 1M M4K1NG 4 1337SP33K TR4NSL4T0R)

Just need a little example or what to do, as this is a very simple thing.

Well it's a very simple thing to walk up stairs but getting a computer to do it is very difficult.

A simple way to do it would be to set a hot key for the characters you want to change, and the function for the hotkey can just Send the replacement character.

[thelex]

<br />Well it's a very simple thing to walk up stairs but getting a computer to do it is very difficult.<br /><br />A simple way to do it would be to set a hot key for the characters you want to change, and the function for the hotkey can just Send the replacement character.<br />

<br /><br /><br />

How?

[martin]

<br /><br /><br />

How?

Like this

1. Look in help for HotKeySet. Study the examples and try them.

2. Look in the help file for Send. Study again.

3.Write your own version.

4. If you write something and after trying a few things you are stuck then come back for help.

[d4rk]

#include <Misc.au3>
select
     case _ispressed("69") then;for the letter "i"
     sleep(100)
     send("1")

case [for other key]
endselect

don't know if the result is "i1", if this happen, send a {delete} before sleep()

[covaks]

I modified the _WinAPI_SetWindowsHookEx function help example in the beta to do this.

You would have to install the beta, and "Run beta" to get it to work. You can do it with the current release too though, if you just fix up the _WinAPI functions to their matching DllCalls.

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>

Opt('MustDeclareVars', 1)

Global $hHook, $hStub_KeyProc, $buffer = ""

_Main()

Func _Main()
    Local $hmod

    $hStub_KeyProc = DllCallbackRegister("_KeyProc", "long", "int;wparam;lparam")
    $hmod = _WinAPI_GetModuleHandle(0)
    $hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hStub_KeyProc), $hmod)

    MsgBox(4096, "", "Click OK, then in notepad type away.. " & @LF & @LF & "Press Esc to exit script")

    Run("Notepad")
    WinWait("Untitled -")
    WinActivate("Untitled -")

    While 1
        Sleep(10)
    WEnd
EndFunc   ;==>_Main

Func EvaluateKey($keycode)
    If (($keycode > 64) And ($keycode < 91)) _ ; a - z
            Or (($keycode > 96) And ($keycode < 123)) _ ; A - Z
            Or (($keycode > 47) And ($keycode < 58)) Then ; 0 - 9
        $buffer = Chr($keycode)
        Switch $buffer
            Case "e"
                Send("3")
                Return 1
            Case "i"
                Send("1")
                Return 1
            Case "t"
                Send("7")
                Return 1
            Case "a"
                Send("4")
                Return 1
            Case "o"
                Send("0")
                Return 1
        EndSwitch
    ElseIf ($keycode > 159) And ($keycode < 164) Then
        Return
    ElseIf ($keycode = 27) Then ; esc key
        Exit
    Else
        $buffer = ""
    EndIf
EndFunc   ;==>EvaluateKey

;===========================================================
; callback function
;===========================================================
Func _KeyProc($nCode, $wParam, $lParam)
    Local $tKEYHOOKS
    $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
    If $nCode < 0 Then
        Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
    EndIf
    If $wParam = $WM_KEYDOWN Then
        If EvaluateKey(DllStructGetData($tKEYHOOKS, "vkCode")) = 1 Then
            Return 1
        EndIf
    Else
        Local $flags = DllStructGetData($tKEYHOOKS, "flags")
        Switch $flags
            Case $LLKHF_ALTDOWN
                ConsoleWrite("$LLKHF_ALTDOWN" & @LF)
            Case $LLKHF_EXTENDED
                ConsoleWrite("$LLKHF_EXTENDED" & @LF)
            Case $LLKHF_INJECTED
                ConsoleWrite("$LLKHF_INJECTED" & @LF)
            Case $LLKHF_UP
                ConsoleWrite("$LLKHF_UP: scanCode - " & DllStructGetData($tKEYHOOKS, "scanCode") & @TAB & "vkCode - " & DllStructGetData($tKEYHOOKS, "vkCode") & @LF)
        EndSwitch
    EndIf
    Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc

Func OnAutoItExit()
    _WinAPI_UnhookWindowsHookEx($hHook)
    DllCallbackFree($hStub_KeyProc)
EndFunc   ;==>OnAutoItExit

Edited April 2, 2008 by covaks