Set minimum of resizing?

[PantZ4]

Can I set the minimum of resizing on my GUI window?

Like Skype chat windows. They can't go below 300x400 pixels. The mouse just stops if you try.

Is this possible?

Thank you

[MrCreatoR]

Hi,

A while ago, a has write a function that do that, here it is:

#include <GuiConstants.au3>

$Title = "Resize Limit GUI Demo"
GUICreate($Title, 300, 250, -1, -1, $WS_SIZEBOX)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_RESIZED
            _ResizeLimit($Title, "", 200, 200, 600, 500)
    EndSwitch
WEnd

Func _ResizeLimit($Title, $Text="", $MinWidth=150, $MinHeight=100, $MaxWidth=@DesktopWidth, $MaxHeight=@DesktopHeight)
    If Not WinExists($Title, $Text) Then Return SetError(1, 0, -1)
    Local $PosArr = WinGetPos($Title, $Text), $xPos, $yPos, $wPos, $hPos
    If IsArray($PosArr) Then
        $xPos = $PosArr[0]
        $yPos = $PosArr[1]
        $wPos = $PosArr[2]
        $hPos = $PosArr[3]
        If ($wPos <> $MinWidth And $hPos <> $MinHeight) Or ($wPos <> $MaxWidth And $hPos <> $MaxHeight) Then
            If $wPos < $MinWidth And $hPos < $MinHeight Then WinMove($Title, $Text, $xPos, $yPos, $MinWidth, $MinHeight)
            If $wPos < $MinWidth And $hPos >= $MinHeight Then WinMove($Title, $Text, $xPos, $yPos, $MinWidth, $hPos)    
            If $wPos >= $MinWidth And $hPos < $MinHeight Then WinMove($Title, $Text, $xPos, $yPos, $wPos, $MinHeight)
            
            If $wPos > $MaxWidth And $hPos > $MaxHeight Then WinMove($Title, $Text, $xPos, $yPos, $MaxWidth, $MaxHeight)
            If $wPos > $MaxWidth And $hPos <= $MaxHeight Then WinMove($Title, $Text, $xPos, $yPos, $MaxWidth, $hPos)    
            If $wPos <= $MaxWidth And $hPos > $MaxHeight Then WinMove($Title, $Text, $xPos, $yPos, $wPos, $MaxHeight)
        EndIf
    EndIf
EndFunc

This not will stop the mouse, but at the end the window not will be resized bellow the seted position (minimum and maximum).

Edited April 10, 2007 by MsCreatoR

[therks]

I was looking for something like the OP as well, so far I've been using functions like yours MsCreator. If anybody else could weigh in here to let me know if there's maybe a DllCall or something.

Edit:

I found a reference to a WM_GETMINMAXINFO message and found this on MSDN. Perhaps something with GUIRegisterMsg could solve this.

Edited April 12, 2007 by Saunders

[Zedna]

Here is example for WM_GETMINMAXINFO:

#include <GUIConstants.au3>
Const $WM_GETMINMAXINFO = 0x24

GUICreate("Test GUI",500,500,-1,-1,BitOR($GUI_SS_DEFAULT_GUI,$WS_SIZEBOX))
GUISetState (@SW_SHOW)
GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend
    
Func MY_WM_GETMINMAXINFO($hWnd, $Msg, $wParam, $lParam)
    $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int",$lParam)
    DllStructSetData($minmaxinfo,7,400) ; min X
    DllStructSetData($minmaxinfo,8,250) ; min Y
    DllStructSetData($minmaxinfo,9,600) ; max X
    DllStructSetData($minmaxinfo,10,700) ; max Y
    Return 0
EndFunc

#cs
typedef struct {
    POINT ptReserved;
    POINT ptMaxSize;
    POINT ptMaxPosition;
    POINT ptMinTrackSize;
    POINT ptMaxTrackSize;
} MINMAXINFO;
#ce

EDIT: search forum for more examples, I posted this long time ago already

Edited April 12, 2007 by Zedna

[MrCreatoR]

Zedna

Here is example for WM_GETMINMAXINFO

Wow man! it's great, i have been looking for this whole my life! thank you very mutch!

[big_daddy]

Added to the Snippets Database!