is there no TCPIPtoName() ?

[piccaso]

i miss the opposite of TCPNameToIp()

is there any?

[PaulIA]

i miss the opposite of TCPNameToIp()

is there any?

Many names can resolve to a single IP address. For example, if I'm running a web server, ftp server and email server, they can all have the same IP address. You can query ARIN and get information about who owns the IP if you want.

[piccaso]

i know that you can have multiple domains for a ip but one is allways primary...

[PaulIA]

i know that you can have multiple domains for a ip but one is allways primary...

Really? And in the example above, which one would be the primary? The web server, the ftp server or the mail server?

[piccaso]

like this...

TCPStartup() ; WSAStartup  inside...
 
 $sIp = TCPNameToIP("www.hiddensoft.com")
 $vIp = DllCall("Ws2_32.dll","long","inet_addr","str",$sIp)
 $vIp = $vIp[0]
 
 $vHostent = DllCall("Ws2_32.dll","ptr","gethostbyaddr","long_ptr",$vIp,"int",4,"int",2) ; 2= AF_INET
 If @error Then ConsoleWrite(@error & @CR)
 $vHostent = $vHostent[0]
 
 $vzStrptr = DllStructCreate("ptr",$vHostent)
 $vzStr = DllStructCreate("char[256]",DllStructGetData($vzStrptr,1))
 ConsoleWrite(DllStructGetData($vzStr,1) & @LF)

hiddensoft.com -> (some numeric ip) -> autoitscript.com

[PaulIA]

like this...

TCPStartup() ; WSAStartup  inside...
 
 $sIp = TCPNameToIP("www.hiddensoft.com")
 $vIp = DllCall("Ws2_32.dll","long","inet_addr","str",$sIp)
 $vIp = $vIp[0]
 
 $vHostent = DllCall("Ws2_32.dll","ptr","gethostbyaddr","long_ptr",$vIp,"int",4,"int",2) ; 2= AF_INET
 If @error Then ConsoleWrite(@error & @CR)
 $vHostent = $vHostent[0]
 
 $vzStrptr = DllStructCreate("ptr",$vHostent)
 $vzStr = DllStructCreate("char[256]",DllStructGetData($vzStrptr,1))
 ConsoleWrite(DllStructGetData($vzStr,1) & @LF)

hiddensoft.com -> (some numeric ip) -> autoitscript.com

You started off with one name, resolved to an address and ended up with a totally different name. See what I mean about IP addresses can resolve to different names? Primary has no meaning when you resolve IP -> name, only from name -> IP.

[piccaso]

i didnt expect something else...

thats how that dns thing works

i was just missing an autoit function that does resolving but the dllcall method is good for me...

just need to wrap it up as function...

[piccaso]

Really? And in the example above, which one would be the primary? The web server, the ftp server or the mail server?

depends on dns configuration

normaly if you have:

www.host.tld

smtp.host.tld

pop.host.tld

it resolves to host.tld but this realy differs throu the web...

[piccaso]

if your behind a router you have multiple hostnames yourself but thats a diffrerent story

and i have answered my support request myself, how nice

expandcollapse popup

Func _TCPIpToName($sIp,$hDll_Ws2_32 = "Ws2_32.dll")
    Local $vbinIP,$vaDllCall,$vptrHostent,$vzptrName
    Local $INADDR_NONE = 0xffffffff
    $vaDllCall = DllCall($hDll_Ws2_32,"long","inet_addr","str",$sIp)
    If @error Then Return SetError(1,0,"") ; inet_addr DllCall Failed
    $vbinIP = $vaDllCall[0]
    If $vbinIP = $INADDR_NONE Then Return SetError(2,0,"") ; inet_addr Failed
    $vaDllCall = DllCall($hDll_Ws2_32,"ptr","gethostbyaddr","long_ptr",$vbinIP,"int",4,"int",2) ; 2 = AF_INET
    If @error Then Return SetError(3,0,"") ; gethostbyaddr DllCall Failed
    $vptrHostent = $vaDllCall[0]
    If $vptrHostent = 0 Then
        $vaDllCall = DllCall($hDll_Ws2_32,"int","WSAGetLastError")
        If @error Then Return SetError(5,0,"") ; gethostbyaddr Failed, WSAGetLastError Failed
        Return SetError (4,$vaDllCall[0],"") ; gethostbyaddr Failed, WSAGetLastError = @Extended
    EndIf
    $vzptrName = DllStructCreate("ptr",$vptrHostent)
    Return __TCPIpToName_szStringRead(DllStructGetData($vzptrName,1))
EndFunc
; Internal
Func __TCPIpToName_szStringRead($iszPtr, $iLen = -1)
    Local $aStrLen, $vszString
    If $iszPtr < 1 Then Return ""
    If $iLen < 0 Then
        $aStrLen = DllCall("msvcrt.dll", "int", "strlen", "ptr", $iszPtr)
        If @error Then Return SetError(1, 0, "")
        $iLen = $aStrLen[0] + 1
    EndIf
    $vszString = DllStructCreate("char[" & $iLen & "]", $iszPtr)
    If @error Then Return SetError(2, 0, "")
    Return SetError(0, $iLen, DllStructGetData($vszString, 1))
EndFunc 

#include <inet.au3>
ConsoleWrite("Public hostname:" & _TCPIpToName(_GetIP()) & @LF)
ConsoleWrite("Local hostname:" & _TCPIpToName("127.0.0.1") & @LF)
ConsoleWrite("@IPAddress1 hostname:" & _TCPIpToName(@IPAddress1) & @LF)
;~ Public hostname:85-124-175-2.dynamic.xdsl-line.inode.at
;~ Local hostname:localhost
;~ @IPAddress1 hostname:Kunibert

[PaulIA]

depends on dns configuration

normaly if you have:

www.host.tld

smtp.host.tld

pop.host.tld

it resolves to host.tld but this realy differs throu the web...

Not wanting to pick a fight. Glad that you found something to resolve IP to DNS, but I stand by my statement that there is no such thing as a "primary" name when resolving IP -> Name.

[dv8]

Hi,

I was looking for this function for a long time!

Until now I was parsing the output of NBTSTAT.EXE.

Thank you for creating it!!!

I have one question:

I need it for resolving the local network names and I tried to remove the first two ConsoleWrite lines from your example, and it stopped working.

It seams that it needs to first call:

ConsoleWrite("Public hostname:" & _TCPIpToName(_GetIP()) & @LF)

and then:

ConsoleWrite("@IPAddress1 hostname:" & _TCPIpToName(@IPAddress1) & @LF)

to work.

But this is a bit slow.

Can you please explain why is that, and is there a way to call only _TCPIpToName(<IPAddress>)?

[/dev/null]

Can you please explain why is that, and is there a way to call only _TCPIpToName(<IPAddress>)?

the problem is not the ConsoleWrite, but the missing TCPStartup() call before _TCPIpToName. With that it works for me.

#include <inet.au3>
TCPStartup()
ConsoleWrite("Public hostname:" & _TCPIpToName("64.111.104.70") & @LF)

Cheers

Kurt

[dv8]

the problem is not the ConsoleWrite, but the missing TCPStartup() call before _TCPIpToName. With that it works for me.

#include <inet.au3>
TCPStartup()
ConsoleWrite("Public hostname:" & _TCPIpToName("64.111.104.70") & @LF)

Cheers

Kurt

Thank you VERY MUCH !!!

[piccaso]

the above version in not complete, it doesent read out the aliases stroed in hostent struct.

i sent a complete version to jos and if he wants to it will be in the next beta...

pn me if you cant wait

[Jos]

the above version in not complete, it doesent read out the aliases stroed in hostent struct.

i sent a complete version to jos and if he wants to it will be in the next beta...

pn me if you cant wait

I haven't worked much on UDF submissions lately... motivation is down a bit the last week or so doing this stuff, but no worries, it will come back and I will pick up all submissions.

This one does sound useful to put in .......